cStr1 = "把一串截为3段,如果含有不定长双字节字符就不能随便截断, 既然用到备注字段,为何还要截断来保存?" + ;
        "先把文本导入到备注字段,在按长度分别导出这三个字段内容,能行不?" + ;
        "人发可个方和方经品他三方登1山泛水多福多寿辅导费对方01234567890" + ;
        "不明白楼主说的文本内容超长是什么意思,vfp字符型字段最多导入254个字符,共有294个字符"
         
         
 
?LEN(cStr1)
DIMENSION MyAry[4]
 
=CutStr(cStr1,@MyAry,4,99)
?MyAry[1]
?MyAry[2]
?MyAry[3]
?MyAry[4]
 
FUNCTION CutStr(cStr,aMyAry,nAry,nMaxLen)
LOCAL cStr1,nLen,nLen1,nStart,i
 nLen = LEN(cStr)
 IF nMaxLen * nAry < nLen &&不够长度
    RETURN .f.
 ELSE
 nStart = 1
 FOR i=1 TO nAry
     cStr1 = SUBSTRC(SUBSTR(cStr,nStart,nMaxLen),1,nMaxLen)  &&这句是最主要的.
     nLen1 = LEN(cStr1)
     nStart = nStart + nLen1
     aMyAry[i] = cStr1
     nLen = nLen - nLen1
 ENDFOR  
 RETURN Iif(nLen = 0,.t.,.f.) && 正常情况，最后 nLen=0
 ENDIF
ENDFUNC  

[此贴子已经被作者于2018-4-11 21:08编辑过]

结尾为C的函数安全性得不到保证。如：SUBSTRC()

这样应该也可以：SUBSTRC(SUBSTR(cStr,nStart,nLen),1)
Str1 = "人发可个方和方经品他三方登1山泛水多福多寿辅导费对方01234567890"
nStart = 1
nLen = 10
DO WHILE nStart<=LEN(str1) AND nLen>1
    ? CutStr(str1, @nStart, nLen)
ENDDO

FUNCTION CutStr(cStr, nStart, nLen)
    LOCAL cRet
    cRet = SUBSTRC(SUBSTR(cStr, nStart, nLen), 1)
    nStart = nStart + LEN(cRet)
    RETURN cRet
ENDFUNC

=ALINES(aa,FILETOSTR("测试.txt"))
CREATE CURSOR tt (列1 c(234),列2 c(99),列3 m)
FOR i=1 TO ALEN(aa,1)
    INSERT INTO tt VALUES (SUBSTR(aa[i],1,234),SUBSTR(aa[i],235,99),SUBSTR(aa[i],334))
ENDFOR
BROWSE

每行内容超过800字节

cStr1 = "把一串截为3段,如果含有不定长双字节字符就不能随便截断, 既然用到备注字段,为何还要截断来保存?先把文本导" + ;
        "入到备注字段,在按长度分别导出这三个字段内容,能行不?真可以,人发可个方和方经品他三方登山泛水多福多寿辅" + ;
        "导费对方,不明白楼主说的文本内容超长是什么意思,vfp字符型字段最多导入254个字符,共有300个字符0123456789"

cStr2 = "把一串截为3段,如果含有不定长双字节字符就不能随便截断, 既然用到备注字段,为何还要截断来保存?先把文本0导" + ;
        "入到备注字段,在按长度分别导出这三个字段内容,能行不?真可以,人发可个方和方经品他三方登山泛水多福多寿辅" + ;
        "导费对方,不明白楼主说的文本内容超长是什么意思,vfp字符型字段最多导入254个字符,共有300个字符123456789"
         
 ** cStr1刚好是每行100个字符,测试结构完全正确的. 返回 .t.
 ** cStr2第1行是101,第2行是100,第3行是99,分段结果是不正确的,所以返回 .f.,针对这个情况,把每行设置为 每行nMaxLen * 行数nAry - 行数nAry > 字符数,就完整正确
 ** 也就是说,根据返回值,如果是 .T.的,就正确
 ?LEN(cStr1)
 DIMENSION MyAry[4]
  
 ?CutStr(cStr1,@MyAry,3,100)
 ?MyAry[1]
 ?MyAry[2]
 ?MyAry[3]

  
 FUNCTION CutStr(cStr,aMyAry,nAry,nMaxLen)
 LOCAL cStr1,nLen,nLen1,nStart,i
  nLen = LEN(cStr)
  IF nMaxLen * nAry < nLen &&不够长度
    RETURN .f.
  ELSE
  nStart = 1
  FOR i=1 TO nAry
      cStr1 = SUBSTRC(SUBSTR(cStr,nStart,nMaxLen),1)  &&这句是最主要的.
      nLen1 = LEN(cStr1)
      nStart = nStart + nLen1
      aMyAry[i] = cStr1
      nLen = nLen - nLen1
  ENDFOR  
  RETURN Iif(nLen = 0,.t.,.f.) && 正常情况，最后 nLen=0
  ENDIF
 ENDFUNC

[此贴子已经被作者于2018-4-12 09:11编辑过]

帮看下，是否可行？ 有需改动的地方没？

这个是平均截取的？ 按
,1,234)
,235,100)
,335)  呢？

*按你指定的长度,如果你3段的长度不一样的话,你就这样吧.

cStr="按你指定的长度,如果你3段的长度不一样的话,你就这样吧"
local nLen,nLen1,nLen2,nLen3,cStr1,cStr2,cStr3,nStart
nLen1 = 15
nLen2 = 26
nLen3 = 10
nStart = 1
cStr1 = SUBSTRC(SUBSTR(cStr,nStart,nLen1),1)
nStart = nStart + LEN(cStr1)
cStr2 = SUBSTRC(SUBSTR(cStr,nStart,nLen2),1)
nStart = nStart + LEN(cStr2)
cStr3 = SUBSTRC(SUBSTR(cStr,nStart,nLen3),1)

?cStr1
?cStr2
?cStr3

15楼的代码看了吗