我现在就是想知道转录过去的方法，谢谢

楼主你弄得出来不

我现在没时间把所有的结构都做出来，就以53.txt作个吧。现在的东东是可以做的。

谁是楼主？我已经糊涂了！

没有40楼所说的那个数据字典，我也不想动手写代码。

要按你原先的做法，就设计表的字段为Memo类型，用：
REPLACE 字段名 WITH FGETS(文件句柄)
把41行数据引入到表中即可。

使用低级文件流的方法：

nHandle = FOPEN("53.TXT")
cText = FGETS(nHandle)        && 从当前位置开始读入一整行到字符串cText中，如此重复读每一行，字符数不限长度
&& 将读入的cText抄到表中记录的Memo字段中
FCLOSE(nHandle)

还是你有耐心，看样子又是一个不眠之夜啊

我晚上才不弄那个哩，干自己的活。

把你53.TXT中的数据导入下图的表中了，看看是不是这样？



[ 本帖最后由 TonyDeng 于 2012-8-19 02:59 编辑 ]

CLEAR ALL
CLOSE DATABASES ALL
CLEAR 

SET DECIMALS TO 4

* CreateDataDictionary()
Import_Table("53.TXT", "53")

CLOSE DATABASES ALL
CLEAR ALL
RETURN 

* 导入数据
FUNCTION Import_Table(tcDataFileName, tcTableName)
    LOCAL lnHandle, lnLine, lcFieldName, lnIndex, lnValue
    LOCAL lnFields, lnRecords
    LOCAL llSuccess
   
    OPEN DATABASE DATA1 EXCLUSIVE
   
    * 打开数据文件
    lnHandle = FOPEN(tcDataFileName)
    IF lnHandle < 0
        MESSAGEBOX("数据文件" + tcDataFileName + "打开失败！", 16)
        RETURN
    ENDIF
    * 跳过前面9行
    FOR lnLine = 1 TO 9
        FGETS(lnHandle)
    NEXT
    * 获取字段数
    lnFields = INT(VAL(FGETS(lnHandle)))
    * 创建数据表结构
    SET SAFETY OFF
    USE Dictionary EXCLUSIVE IN 0
    IF INDBC("_" + tcTableName, "TABLE")
        REMOVE TABLE ("_" + tcTableName)
    ENDIF
    COPY STRUCTURE EXTENDED TO ("_" + tcTableName) DATABASE Data1
    USE ("_" + tcTableName) ALIAS _Structure EXCLUSIVE IN 0
    ZAP IN _Structure
    llSuccess = .T.
    FOR lnLine = 1 TO lnFields
        lcFieldName = ALLTRIM(FGETS(lnHandle))
        SELECT Dictionary
        LOCATE ALL FOR ALLTRIM(Dictionary.Field_Name) == lcFieldName
        IF !FOUND("Dictionary")
            MESSAGEBOX("发现数据字典中没有的字段：" + lcFieldName, 16)
            llSuccess = .F.
            EXIT
        ENDIF
        SELECT _Structure
        APPEND BLANK
        REPLACE _Structure.Field_Name WITH Dictionary.Field_Name
        REPLACE _Structure.Field_Type WITH Dictionary.Field_Type
        REPLACE _Structure.Field_Len  WITH Dictionary.Field_Len
        REPLACE _Structure.Field_Dec  WITH Dictionary.Field_Dec
    NEXT
    USE IN _Structure
    USE IN Dictionary
   
    * 创建导入数据表
    SET SAFETY OFF
    IF INDBC(tcTableName, "TABLE")
        REMOVE TABLE (tcTableName)
    ENDIF
    SELECT 0
    CREATE (tcTableName) DATABASE Data1 FROM ("_" + tcTableName)
    USE
   
    * 导入数据
    USE (tcTableName) ALIAS _Data EXCLUSIVE IN 0
    USE ("_" + tcTableName) ALIAS _Structure EXCLUSIVE IN 0
    * 获取记录数
    lnRecords = INT(VAL(FGETS(lnHandle)))
    FOR lnLine = 1 TO lnRecords
        SELECT _Data
        APPEND BLANK
        lcLineContent = FGETS(lnHandle, RECSIZE("_Data"))
        FOR lnIndex = 1 TO lnFields
            lcField = FIELD(lnIndex, "_Data")
            SELECT _Structure
            LOCATE ALL FOR UPPER(ALLTRIM(_Structure.Field_Name)) == lcField
            SELECT _Data
            DO CASE
                CASE _Structure.Field_Type == 'C'
                    REPLACE (lcField) WITH LEFT(lcLineContent, _Structure.Field_Len)
                CASE _Structure.Field_Type == 'N'
                    lnValue = VAL(LEFT(lcLineContent, _Structure.Field_Len)) / (10 ^ _Structure.Field_Dec)
                    REPLACE (lcField) WITH lnValue
            ENDCASE
            lcLineContent = SUBSTR(lcLineContent, _Structure.Field_Len + 1)
        NEXT
    NEXT
   
    USE IN _Structure
    SELECT _Data
    BROWSE
   
    * 关闭数据文件句柄
    FCLOSE(lnHandle)

    RETURN llSuccess
   
ENDFUNC

* 创建数据字典
PROCEDURE CreateDataDictionary()
    LOCAL lnHandle, lcLineContent
   
    LOCAL lcDelimiter
    lcDelimiter = ' '    && 界定符是空格
   
    USE Dictionary_Structure EXCLUSIVE IN 0
    SET SAFETY OFF
    ZAP IN Dictionary_Structure
    lnHandle = FOPEN("格式.TXT")
    DO WHILE !FEOF(lnHandle)
        lcLineContent = CHRTRAN(FGETS(lnHandle), CHR(9), lcDelimiter)
        IF !EMPTY(lcLineContent)
            APPEND BLANK IN Dictionary_Structure
            REPLACE Dictionary_Structure.Field_Name WITH GETWORDNUM(lcLineContent, 1, lcDelimiter) IN Dictionary_Structure
            REPLACE Dictionary_Structure.Field_Type WITH GETWORDNUM(lcLineContent, 2, lcDelimiter) IN Dictionary_Structure
            REPLACE Dictionary_Structure.Field_Len  WITH INT(VAL(GETWORDNUM(lcLineContent, 3, lcDelimiter))) IN Dictionary_Structure
            REPLACE Dictionary_Structure.Table_Cmt  WITH GETWORDNUM(lcLineContent, 4, lcDelimiter) IN Dictionary_Structure
            IF Dictionary_Structure.Field_Type == 'A'
                REPLACE Dictionary_Structure.Field_Type WITH 'C'
            ENDIF
        ENDIF
    ENDDO
    FCLOSE(lnHandle)
    USE IN Dictionary_Structure
   
ENDPROC