40000000以内耗时173s，破电脑就这速度。
用数组应该可以算到超过1亿内，每个数组中元素的最大数目 一般: 2G 字节、成员数组: 2G 字节

t = SECONDS()
N = 40000000
DIMENSION arr[N,1]
arr = .T.
i = 2
DO WHILE i<=N
    FOR j=i+i TO N STEP i
        arr[j] = .F.
    ENDFOR 
    j = i+1
    DO WHILE j<=N AND !arr[j]
        j = j+1
    ENDDO
    i = j
ENDDO
CREATE CURSOR tt (bol L, num I)
INSERT INTO tt FROM ARRAY arr   
REPLACE ALL num WITH RECNO()
SELECT num FROM tt WHERE bol AND RECNO()>1 INTO TABLE 素数表
? SECONDS()-t  && N=20000000 - 87s, N=40000000 - 173s

t=SECONDS()
N=20000000
DIMENSION arr[N,1]
arr=.T.
i=2
DO WHILE i<=N
    FOR j=i+i TO N STEP i
    arr[j]=.F.
    ENDFOR
    j=i+1
    DO WHILE j<=N AND !arr[j]
    j=j+1
    ENDDO
    i=j
 ENDDO
 CREATE CURSOR tt(bol L,num I)
 INSERT INTO tt FROM ARRAY arr
 REPLACE ALL num WITH RECNO()
 SELECT num FROM tt WHERE bol AND RECNO()>1 INTO TABLE 素数表
 ?SECONDS()-t &&N=20000000-38.754s ,N=40000000-78.142s
我按照您的程序手工抄录了一遍。用时较少，结果存盘到：C:\program files(X86)\vfp9\素数表.dbf 中了

输出文件可以设置默认路径或指定路径

你这是什么算法，没看到你运算，就判断了。

* 改造了31楼的程序，结果表记录1234399，用时350秒
CLEAR
CLOSE DATABASES

LOCAL kkk

SELECT 1
USE 数据源.DBF ALIAS 数据源
SELECT 2
USE 素数表.DBF ALIAS 素数表参

SELECT 5
USE 素数结果.DBF ALIAS 素数表果
DELETE ALL
PACK

SELECT 素数 数据1 FROM 素数表果 WHERE 1=2 INTO CURSOR 数据a READWRITE

kssj = DATETIME()
FOR i=1 TO 2
    SELECT 素数式+(i-1)*9699690 数据1,CAST(1 as INT) 数据mod FROM 数据源 INTO CURSOR 数据a READWRITE

    SELECT 数据a
    GO BOTTOM     &&1658880
    Kf=INT(SQRT(数据1))

    SELECT 2
    kkk = 0
    SCAN FOR RECNO()>8 AND 素数<=kf
        IF RECNO()>kkk
            WAIT TRANSFORM(RECNO()) WINDOW NOWAIT NOCLEAR
            kkk = kkk + 10
        ENDIF
        
        UPDATE 数据a SET 数据mod=MOD(数据1,素数表参.素数) WHERE 数据mod>0

        SELECT 2
    ENDSCAN
   
    INSERT INTO 素数表果 (素数) SELECT 数据1 FROM 数据a WHERE 数据mod>0
   
 ENDFOR
 USE IN 数据a
 
 MESSAGEBOX( DATETIME()-kssj)
 SELECT 素数表果
 MESSAGEBOX( RECCOUNT())
 BROWSE
 

确实没看懂吹版的程序，好像没用到数据源表和素数表，明白的给说明一下下

首先多谢先生的回答。我还没有运行。那也比我原来的提速不少。

两楼都提到吹水佬算法问题，我有点喧宾夺主了，本不该回答的，只知道大概的意思，我把程序抄写到程序中，第一次运算结果出来后，竟然连素数表也没有找到，无奈之下运行了第二次，这是出现提示信息，说那个路径之下已经存在了，是否替换，这时我才找到存放素数表的路径。
扯多了，扯远了，回到正题，他的算法就像体育课老师让学生报数那样，从开头报数，报偶数者出列（第一个报的不出列），接着报3的倍数的出列，报5的倍数出列（当然他是把它们标记为假，false，开始都标记为真，true），这样直到小于等于N为止，然后把所有标记为真的存放到素数表中（当然第一条记录排除在外，它是1）

[此贴子已经被作者于2021-9-15 16:34编辑过]

    筛选法求素数
    如：有10个数............ 2，3，4，5，6，7，8，9，10，11
    先假设都是素数标记为1 .. 1，1，1，1，1，1，1，1， 1， 1
    将不是素数的标记为0 .... 1，1，0，1，0，1，0，0， 0， 1
    剩下标记为1的是素数 .... 2，3， ，5，， 7， ， ，  ，11


DIMENSION arr[N,1]
arr = .T.
i = 2  筛选起始数
DO WHILE i<=N
    FOR j=i+i TO N STEP i  && 是自身倍数的不是素数
        arr[j] = .F.
    ENDFOR 
    j = i+1
    DO WHILE j<=N AND !arr[j] && 跳过连续的非素数
        j = j+1
    ENDDO
    i = j  && 下次筛选的起始数
ENDDO

用当前PRG文件路径作为默认路径，开头加几句：
CLEAR
SET TALK OFF
SET SAFETY OFF
CLOSE TABLES ALL
cDefPath = ADDBS(JUSTPATH(SYS(16)))
SET DEFAULT TO (cDefPath)