我来拿个回帖分

不成熟，只是另一种思路，楼主看快不快：
SET COMPATIBLE ON
SET safety off
n=FILETOSTR("e:\1.htm")
n123=CHRTRAN(n,"1234567890->","")
ntel=CHRTRAN(n,n123,"")
ntel=CHRTRAN(ntel,">"," ")
STRTOFILE(ntel,"e:\1.txt")
xz=""

FOR i= 1 to FSIZE("e:\1.txt")
    xn=    SUBSTR(ntel,i,1)
    IF BETWEEN(ASC(xn),45,57)
        xz=xz+xn
    ELSE
        IF LEN(xz)=7.or.len(xz)=11 .or.len(xz)=12
            ?xz
        ENDIF
        xz=""
    ENDIF
NEXT

学习

我在提取11位手机号的时候把营业执照和机构代码号都提出来了 还得处理一下。
还有一种是flash的clsid是疑似电话号码的东西

[ 本帖最后由 TonyDeng 于 2012-10-21 13:50 编辑 ]

向高手学习

CLEAR
DIMENSION aTemplets[4]
aTemplets[1] = "19999999999"
aTemplets[2] = "99-999-99999999"
aTemplets[3] = "999-99999999"
aTemplets[4] = "9999999"
nFile = FOPEN("2.htm")
DO WHILE !FEOF(nFile)
    cText = FGETS(nFile)
    FOR nIndex = 1 TO ALEN(aTemplets,1)
        cBuffer = cText
        cResult = ""
        nPos = FindAs(aTemplets[nIndex], cBuffer, @cResult)
        DO WHILE nPos > 0
            ? cResult
            cBuffer = SUBSTR(cBuffer, nPos + LEN(aTemplets[nIndex]))
            nPos = FindAs(aTemplets[nIndex], cBuffer, @cResult)
        ENDDO
    NEXT
ENDDO
FCLOSE(nFile)
RETURN 

FUNCTION FindAs(tcTemplet, tcString, tcResult)
    LOCAL lnIndex, lnCount, llFound
    LOCAL lnPos, lcCharacter
   
    lnPos = 0
    tcResult = ""
   
    IF LEN(tcTemplet) > LEN(tcString)
        RETURN lnPos
    ENDIF
   
    FOR lnIndex = 1 TO LEN(tcString)
        IF ISDIGIT(SUBSTR(tcString, lnIndex, 1))
            lnPos = lnIndex
            llFound = .T.
            FOR lnCount = 1 TO LEN(tcTemplet)
                lcCharacter = SUBSTR(tcString, lnIndex + lnCount - 1, 1)
                IF (SUBSTR(tcTemplet, lnCount, 1) == '9') .AND. ISDIGIT(lcCharacter)
                    tcResult = tcResult + lcCharacter
                ELSE
                    IF lcCharacter == SUBSTR(tcTemplet, lnCount, 1)
                        tcResult = tcResult + lcCharacter
                    ELSE
                        llFound = .F.
                        lnPos = 0
                        tcResult = ""
                        EXIT
                    ENDIF
                ENDIF
            NEXT
            IF llFound
                EXIT
            ENDIF
            lnIndex = lnIndex + lnCount - 1
        ENDIF
    NEXT
   
    RETURN lnPos
   
ENDFUNC

第二个网页没有识别出flash的clsid，第一个电话是错的。得看看有什么办法。
现在对同一行扫描了4次（模板数组的元素数目），要优化的话，应在查找函数中一次扫完。晚上再看看。

[ 本帖最后由 TonyDeng 于 2012-10-21 14:32 编辑 ]

CLEAR
CSTR=[]
FOR I=1 TO 30
URL =[http://shuma.]+TRANSFORM(I)+[.html]
HTTP = CREATEOBJECT("MICROSOFT.XMLHTTP")
HTTP.OPEN("GET", URL,.F.)
HTTP.SEND
MSG = HTTP.RESPONSETEXT
MSG=STRCONV(STRCONV(MSG,11),2)
FOR J=1 TO OCCURS([<li class="ot"><span>???],MSG)
    CSTR=CSTR+STREXTRACT(MSG,[<li class="ot"><span>???],[</span><span>],J)+CHR(13)+CHR(10)
ENDFOR
ENDFOR
=STRTOFILE(CSTR,[TT.TXT])
MODIFY FILE TT.TXT

代码不是太完善（提取的网页内容为UTF-8格式，没转换到位），但能达到楼主的要求。

这是提取的电话号码