应该不算。
5个独立单号码来的，其中任选3个。

我再理顺一下思路，有点复杂。

[此贴子已经被作者于2015-10-27 22:03编辑过]

楼主真相信自己能中大奖？知道彩票是怎么开的奖吗？

不算，他要的是表2的每个数都在表1中，包括重复的，如果是重复的，就你当他不是重复的来处理。
吹版主，在处理的时候，用了个很巧妙的方法，对于表1，不管你重不重复，先按顺序排起来，同样，表2，也是按顺序排起来。
但对于表2，你不能简单的按顺序排起来的。比如
表1=03584，表2=805，我们用眼看就知道，表2在表1中，表1排序后=03458，表2排序后=058，
?LIKE('058','03458') && .F.
吹版，就在058中间，插入通配符“*”，为什么不用“?”，用“*”表示0以5之间可以是多个其他字符，而用“?”只能是1个字符
也就是说
?LIKE('?0?5?8?','03458') && .F.
?LIKE('*0*5*8*','03458') && .T.

不知道对不对，最好样本数据多一些，可以测试速度和正确率。
应该可以用一句 Select-SQL 语句的，但效率不一定快。
下面的试试看：

*!*    表3 : 包含，Query : 不包含：
Clear
Create Cursor 表1 (序号 I, 结果 V(5))
Insert Into 表1 Values(1, "05601")
Insert Into 表1 Values(2, "47896")
Insert Into 表1 Values(3, "81222")
Insert Into 表1 Values(4, "48068")
Insert Into 表1 Values(5, "54969")
*!*    Insert Into 表1 Values(1, "05621")
Create Cursor 表2 (序号 I, 结果 V(3))
Insert Into 表2 Values(1, "005")
Insert Into 表2 Values(2, "048")
Insert Into 表2 Values(3, "128")
Insert Into 表2 Values(4, "379")
Insert Into 表2 Values(5, "468")

Select *, 00000 As 序号2, "   " As 包含 From 表1 Readwrite Into Cursor 表3

Select 表2
Scan
    Select 表3
    Replace All 表3.序号2 With 表2.序号, 表3.包含 With 表2.结果 For (;
        Occurs(Substr(表2.结果, 1, 1), 表3.结果) >= Occurs(Substr(表2.结果, 1, 1), 表2.结果) And ;
        Occurs(Substr(表2.结果, 2, 1), 表3.结果) >= Occurs(Substr(表2.结果, 2, 1), 表2.结果) And ;
        Occurs(Substr(表2.结果, 3, 1), 表3.结果) >= Occurs(Substr(表2.结果, 3, 1), 表2.结果) ) And ;
        Empty(表3.包含)
    Select 表2
Endscan
Select 表3
Go Top
Browse Last Nowait
Select 序号, 结果 As 不包含 From 表2 Where 结果 Not In (Select 包含 From 表3)

occurs()查询最耗时间，特别是用在SQL命令中

都是大神啊！！厉害。

回33楼taifu945：我不是为了中大奖，双色球和大乐透我计算过，1千7百多万种的组合，每年就开152-154期，这是大海捞针，不用去计算了，没意义。中这样的大奖，靠的是命。命里有终须有。随便买几注，不换号，中了就是命。要计算，只能用其他方法，比如多个蓝球+多个红球的组合，这里就不累述了。我现在研究这个时时彩也不是中最大奖的那个，选择的是适中的玩法，奖金也适中，像之前说的，不贪心，每天赚点菜钱还是有一定可能的。

大家都考虑到号码里有重复的问题，我已经剔除了0-9组成的3位数的重复情况（在27楼有数据），就是想简化这个过程，那么，开奖结果里有重复是没关系的，反而是好事，比如：开奖结果是
08065，如果买的号码是058，那么，相当于中了个2倍的奖，08065里含有2个058，多的1倍就是额外收获。同理，这注里有2个056、068。但是只有1个568。

所以，开奖结果是否有重复不重要，重要的是开奖结果里是否包含有表2（0-9组成的不重复的3位数（120个号））。如果在一定期数里，还有没开出来的3位数，那么我就可以考虑买这个3位数，按照一定的比例追着买一定的期数。出了，就中奖了。

测试了一下，用OCCURS()比用LIKE()快好多，这样更快些。
Clear
Create Cursor 表1 (序号 I, 结果 V(5))
FOR i = 1 TO 1000
Insert Into 表1 Values(1, "05601")
Insert Into 表1 Values(2, "47896")
Insert Into 表1 Values(3, "81222")
Insert Into 表1 Values(4, "48068")
Insert Into 表1 Values(5, "54969")
ENDFOR

Create Cursor 表2 (序号 I, 结果 V(3), 不包含 L)
FOR i = 1 TO 100
Insert Into 表2 Values(1, "005", .F.)
Insert Into 表2 Values(2, "048", .F.)
Insert Into 表2 Values(3, "128", .F.)
Insert Into 表2 Values(4, "379", .F.)
Insert Into 表2 Values(5, "468", .F.)
ENDFOR

t1=DATETIME()
SELECT 表2
SCAN
    不包含 = .T.
    SELECT 表1
    SCAN
        IF OCCURS(SUBSTR(表2.结果,1,1), 表1.结果) >= OCCURS(SUBSTR(表2.结果,1,1), 表2.结果) AND;
           OCCURS(SUBSTR(表2.结果,2,1), 表1.结果) >= OCCURS(SUBSTR(表2.结果,2,1), 表2.结果) AND;
           OCCURS(SUBSTR(表2.结果,3,1), 表1.结果) >= OCCURS(SUBSTR(表2.结果,3,1), 表2.结果)
            不包含 = .F.
            EXIT
        ENDIF
    ENDSCAN
    IF 不包含
        REPLACE 不包含 WITH .T. IN "表2"
    ENDIF
ENDSCAN
?DATETIME()-t1
SELECT 表2
BROWSE FOR 不包含

不知道AT()的速度怎么样。
1.表1，表2全连接
2.取表2 第一位 AT()比较 表1,存在返回1，不存在返回0，判断3次。
3.取重复出现3次的结果表与表2比较，输出结果。

clear
 *表1
 CREATE CURSOR T1(xh INT,jg C(10))
 INSERT INTO T1(xh,jg) VALUES(1,'05601')
 INSERT INTO T1(xh,jg) VALUES(2,'47896')
 INSERT INTO T1(xh,jg) VALUES(3,'81222')
 INSERT INTO T1(xh,jg) VALUES(4,'48068')
 INSERT INTO T1(xh,jg) VALUES(5,'54969')

 *表2
 CREATE CURSOR T2(xh INT,jg C(10))
 INSERT INTO T2(xh,jg) VALUES(1,'005')
 INSERT INTO T2(xh,jg) VALUES(2,'048')
 INSERT INTO T2(xh,jg) VALUES(3,'128')
 INSERT INTO T2(xh,jg) VALUES(4,'379')
 INSERT INTO T2(xh,jg) VALUES(5,'468')

 
SELECT T2.jg FROM T2 WHERE T2.jg NOT in (SELECT b.jg FROM T1 A,T2 B WHERE IIF(AT(SUBSTR(b.jg,1,1),a.jg)>0,1,0)+IIF(AT(SUBSTR(b.jg,2,1),a.jg)>0,1,0)+IIF(AT(SUBSTR(b.jg,3,1),a.jg)>0,1,0)=3)

用AT(SUBSTR(b.jg,1,1),a.jg)>0,1,0)会出现重复计算问题。
如：将表1的'05601'改为'05611'，这时表2的'005'没找出来。