以下是引用sdta在2017-8-25 12:10:33的发言：

课程不固定用VFP代码方便，可以以逸待劳，代码可以重复使用，不用修改
create cursor t2 (学号 c(4),姓名 c(8),课目 c(10),成绩 n(3))
insert into t2 values ("1001","张三","数学",102)
insert into t2 values ("1001","张三","语文",120)
insert into t2 values ("1002","李四","数学",119)
insert into t2 values ("1002","李四","语文",108)
insert into t2 values ("1003","王五","政治",101)
insert into t2 values ("1003","王五","历史",105)  
select distinct 课目 from t2 into array ajg
  
* 创建临时表结构及索引
lcstr=""
for lnI=1 to alen(ajg,1)
    lcstr=lcstr+iif(empty(lcstr),"",",")+alltrim(ajg[lnI,1])+" N(3)"
endfor
create cursor t4 (学号 c(4),姓名 c(8),&lcstr)
index on 学号+姓名 tag xhxm
* 结束 *
  
* 数据处理
select t2
set relation to 学号+姓名 into "t4"
scan
    km=alltrim(t2.课目)
    if found("t4")
        replace (km) with t2.成绩 in "t4"
    else
        insert into t4 (学号,姓名,&km) values (t2.学号,t2.姓名,t2.成绩)
    endif
endscan
set relation to
select t4
set filter to alltrim(学号)=="1002" && 根据情况，这行代码可有可无
browse

以下是引用sdta在2017-8-28 11:32:43的发言：

没有学号或者姓名你如何替换成绩

以下是引用吹水佬在2017-8-27 10:23:15的发言：

 
 
CREATE CURSOR tt (学号 C(4), 课程 C(10), 成绩 N(3))
INSERT INTO tt VALUES ("2001", "化学", 80)
INSERT INTO tt VALUES ("2001", "物理", 85)
INSERT INTO tt VALUES ("2002", "化学", 90)
INSERT INTO tt VALUES ("2002", "物理", 95)
INSERT INTO tt VALUES ("2002", "政治", 100)
SELECT DISTINCT 课程 FROM tt INTO CURSOR tmp
cmd = "CREATE CURSOR tj (学号 C(4)"
SCAN
    cmd = cmd + ","+ALLTRIM(tmp.课程)+" N(3)"
ENDSCAN
cmd = cmd + ")"
EXECSCRIPT(cmd)
SELECT DISTINCT 学号 FROM tt INTO CURSOR tmp
SELECT tj
APPEND FROM DBF("tmp")
INDEX on 学号 TAG 学号
SELECT tt
SET RELATION TO 学号 INTO "tj"
SCAN  
    REPLACE ("tj."+ALLTRIM(tt.课程)) WITH tt.成绩
ENDSCAN
SET RELATION TO
SELECT tj
BROWSE