主要研究一下算法哈，确实数据量偏少。

请问如何优化结构，使之更合理？谢谢！

上传的这点数据，最多1秒

测试数据： (虚拟数据中包含30个地市、每个地市包含20个县、每个县包含13所学校，有9个学科，共计70200条记录)
其中，地市名称dsmc、县区名称xqmc、学校名称xxmc、学科xk(拼音代替汉字)、均分jf、联考排序lkpx(按学科均分通排)、本市排序bspx(以学科均分按地市排序)、本县排序(以学科均分按县排序)。谢谢！

[此贴子已经被作者于2023-3-19 18:06编辑过]

是排序还是排名次，具体要求是什么

排名哈(现在一般不说排名，改为排序，哈哈^_^)，我没有说清楚，相同分数相同名次，联考排序lkpx(按学科均分通排)、本市排序bspx(以学科均分按地市排序)、本县排序(以学科均分按县排序)谢谢！

[此贴子已经被作者于2023-3-19 18:09编辑过]

排名规则是：12225 还是12223？

排名规则是：12225，谢谢！

CLOSE DATABASES 
SET COLLATE TO "MACHINE" 
* 联考名次
SELECT * FROM xqpx ORDER BY xk, jf DESC INTO CURSOR temp READWRITE 
BLANK FIELDS lkpx ALL 
lcxk = SPACE(0) && 学科
lnjf = 0 && 均分
lnmc = 1 && 名次
lnrs = 0 && 记录全部同科人数
SCAN 
    lnrs = lnrs + 1
    IF xk == lcxk
        IF jf = lnjf
        ELSE 
            lnmc = lnrs
        ENDIF 
    ELSE 
        lnmc = 1
        lnrs = 1
    ENDIF 
    REPLACE lkpx WITH lnmc
    lcxk = xk
    lnjf = jf
    lnmc = lkpx
ENDSCAN
* 同市同科名次
SELECT * FROM temp ORDER BY dsmc,xk, jf DESC INTO CURSOR temp READWRITE
BLANK FIELDS bspx ALL 
lcxk = SPACE(0) && 学科
lnjf = 0 && 均分
lnmc = 1 && 名次
lnrs = 0 && 记录本市同科人数
lcbs = SPACE(0) && 地市名称
SCAN 
    lnrs = lnrs + 1
    IF dsmc == lcbs AND xk == lcxk
        IF jf = lnjf
        ELSE 
            lnmc = lnrs
        ENDIF 
    ELSE 
        lnmc = 1
        lnrs = 1
    ENDIF 
    REPLACE bspx WITH lnmc
    lcxk = xk
    lnjf = jf
    lnmc = bspx
    lcbs = dsmc
ENDSCAN
* 同县同科名次
SELECT * FROM temp ORDER BY xqmc,xk, jf DESC INTO CURSOR temp READWRITE
BLANK FIELDS bxpx ALL 
lcxk = SPACE(0) && 学科
lnjf = 0 && 均分
lnmc = 1 && 名次
lnrs = 0 && 记录本县同科人数
lcbx = SPACE(0) && 县名称
SCAN 
    lnrs = lnrs + 1
    IF xqmc == lcbx AND xk == lcxk
        IF jf = lnjf
        ELSE 
            lnmc = lnrs
        ENDIF 
    ELSE 
        lnmc = 1
        lnrs = 1
    ENDIF 
    REPLACE bxpx WITH lnmc
    lcxk = xk
    lnjf = jf
    lnmc = bxpx
    lcbx = xqmc
ENDSCAN
BROWSE 

[此贴子已经被作者于2023-3-19 22:36编辑过]

运行时间 <1.5s