谢谢楼上各位。指点。

我意识到了这个问题已有一段时间，只是以前不好意思指出，最近几次回复中我就一直在向提问者指出这个问题。其实，我在自己写的《入门手册》改版中为什么要加上表的设计这一章节，就是因为在坛子里发现了这个现象，想写在书里供大家下载后纠正。只是可惜，正如你所言，好像新手都对表文件的设计重要性不以为然。所以，我现在对于表文件有严重缺陷的也采取提出问题，不直接给代码的方式了。

楼主遇到的问题在实际应用中有一定的代表性，如果使用代码，逻辑上非常简单，但代码稍长（假设三个表分别是 T1，T2，T3）：

CLOSE TABLES ALL
SELECT * FROM t1 INTO CURSOR curResult READWRITE
DIMENSION aTables[2]
aTables[1] = 't2'
aTables[2] = 't3'
SELECT 0
FOR EACH cTable IN aTables
    USE (cTable)
    SCAN
        SCATTER NAME oRec
        SELECT curResult
        LOCATE FOR 编号 = oRec.编号
        IF FOUND()
            IF oRec.高血压
                REPLACE 高血压 WITH .t.
            ENDIF
            IF oRec.糖尿病
                REPLACE 糖尿病 WITH .t.
            ENDIF
            IF oRec.精神病
                REPLACE 精神病 WITH .t.
            ENDIF
        ELSE
            INSERT INTO curResult FROM NAME oRec
        ENDIF
    ENDSCAN
NEXT
USE
SELECT curResult
GO TOP
BROWSE

运行结果如下：

如果使用一个 SQL 语句，确实有一定难度，如果作者不介意结果中的.T.显示为 1，.F. 显示为 0的话，则代码相对较简单：

SELECT 编号,姓名,SUM(IIF(高血压,1,0)) 高血压,SUM(IIF(糖尿病,1,0)) 糖尿病,SUM(IIF(精神病,1,0)) 精神病 ;
    FROM (SELECT * FROM t1 UNION SELECT * FROM t2 UNION SELECT * FROM t3) t4 ;
    GROUP BY 编号,姓名

查询结果如下：