我只想保留一段字符串的中英文和数字。其它去掉。用什么函数？

MyFll函数：
FTrim(cStr,nMode|cChar)
删除除指定字符以外的字符。此函数类似LTrim() RTrim() AllTrim()，但区别是只保留指定的字符，而不是删除指定字符
返回值：
删除后的字符
参数：
•    cStr：字符型，待处理的字符串
•    nMode:数值型，1-只保留数字，2-只保留小写字母，3-只保留大写字母，4-只保留大小写字母，5只保留大小写字母和数字
cChar：字符型，限定字符串中允许出现的字母
示例代码
Set Library To myfll
cStr="abc123-DEF..99测试"
?FTrim(cStr,1)  &&只有数字 12399
?FTrim(cStr,2)  &&只有小写字母 abc
?FTrim(cStr,3)  &&只有大写字母 DEF
?FTrim(cStr,4)  &&只有大小写字母 abcDEF
?FTrim(cStr,5)  &&只有数字和字母 abc123DEF99
?FTrim(cStr,"1234567890ABCDEF") &&只保留限定的字符    123DEF99
Set Library To

汉字怎么保留？？？

数字字母:  CHRTRAN(str,CHRTRAN(str,chs,""),"")
chs = "1234567890AaBbCcDdEdFfGgHhIiJjKkLlMmNnOoPpQqRrSsTtUuVvWwXxYyZz"

str = "abc123-DEF..99测试"
ch1 = "1234567890AaBbCcDdEdFfGgHhIiJjKkLlMmNnOoPpQqRrSsTtUuVvWwXxYyZz"
ch2  = 0h000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F3A3B3C3D3E3F405B5C5D5E5F607B7C7D7E7F
? "数字字母：",CHRTRAN(str,CHRTRAN(str,ch1,""),"")
? "符号：",CHRTRAN(str,CHRTRAN(str,ch2,""),"")
? "汉字：",CHRTRAN(str,ch1+ch2,"")

全角字符都是中文吗

想保留的就是 英文大小写 中文 其它所有符号去掉。

CLEAR 

?regReplace('/[^\u4e00-\u9fa5a-zA-Z0-9]+/g',"今天aassss上午    上了_@#QQ一个课程，收---%^&获颇丰！123",'**')

** 正则表达式替换字符串
** 
** 参数1:正则表达式
** 参数2:替换字符串
** 参数3:匹配替换新字符

FUNCTION regReplace
PARAMETERS para1,para2,para3
IF EMPTY(para1) .OR. EMPTY(para2)
RETURN ''
ENDIF 

LOCAL retustr as String 
retustr=''

TRY
** JS定义
TEXT TO lcJs TEXTMERGE PRETEXT 1+2 NOSHOW
function regReplace(inputStr){
    var regExp = <<para1>>; // 匹配非中文、非字母、非数字的字符
    return inputStr.replace(regExp,'<<para3>>');
}
ENDTEXT
STRTOFILE(lcJs,"c:\js.txt")
oJs=Createobject("ScriptControl")
oJs.Language="JavaScript"
oJs.AddCode(lcJs)
retustr=oJs.run("regReplace",para2)

CATCH TO err
RETURN para1
FINALLY 
IF VARTYPE(oJs)='O'
RELEASE oJs
ENDIF 
ENDTRY

RETURN retustr

最后这样干了，请大家多指点

可以按需要编码分类替换

str = "abc123-DEF..99测试"
ch1 = "1234567890"
ch2 = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
ch3 = "abcdefghijklmnopqrstuvwxyz"
ch4  = 0h000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F3A3B3C3D3E3F405B5C5D5E5F607B7C7D7E7F
? "只有数字：",CHRTRAN(str,CHRTRAN(str,ch1,""),"")
? "只有字母：",CHRTRAN(str,CHRTRAN(str,ch2+ch3,""),"")
? "大写字母：",CHRTRAN(str,CHRTRAN(str,ch2,""),"")
? "小写字母：",CHRTRAN(str,CHRTRAN(str,ch3,""),"")
? "数字字母：",CHRTRAN(str,CHRTRAN(str,ch1+ch2+ch3,""),"")
? "汉字编码：",CHRTRAN(str,ch1+ch2+ch3+ch4,"")
? "符号编码：",CHRTRAN(str,CHRTRAN(str,ch4,""),"")
? "非符号码：",CHRTRAN(str,ch4,"")
? "字母汉字：",CHRTRAN(str,ch1+ch4,"")

 Ａ，、算中文吗