grid表格第一列是check，我想做个批量删除，点击按钮后所有勾选的数据都删除。

我的想法是在表中天加一个 “标记”字段，在表格中，当勾选check的时候，标记的值改为1，取消勾选后，标记的值为0

然后用delete  for  来删除所有标记为1的数据。

请问下，如何勾选后，将这个行数据 标记的值改为1呢？

check绑定grid数据表一字段

可以直接绑定逻辑型字段

可以
参考示例


CREATE CURSOR tt (f1 L, f2 I)
FOR i=1 TO 10
    INSERT INTO tt VALUES (i%2==0, i)
ENDFOR
GO TOP
of = CREATEOBJECT("form1")
of.Show(1)
RETURN

DEFINE CLASS form1 as Form
    AutoCenter = .T.

    ADD OBJECT cmd1 as commandbutton WITH top=10,left=10,height=22,caption="Delete"
    ADD OBJECT grid1 as Grid WITH top=40,left=10,RecordSource="tt"
        
    PROCEDURE grid1.Init
        this.Column1.ControlSource = "tt.f1"
        this.Column1.Sparse = .F.
        this.Column1.RemoveObject("Text1")
        this.Column1.AddObject("Check1", "CheckBox")
        this.Column1.Check1.Visible = .T.
    ENDPROC
   
    PROCEDURE cmd1.click
        SELECT * FROM tt WHERE !tt.f1 INTO CURSOR tmp
        SELECT tt
        ZAP
        APPEND FROM DBF("tmp")
        GO TOP
        thisform.grid1.setfocus
    ENDPROC
ENDDEFINE

[此贴子已经被作者于2020-4-1 16:04编辑过]

好！

这样果然可以实现，十分感谢。
不过我还想请问下，如何让点击按钮全部打钩和点击按钮按钮全部打钩的都取消打钩呢。

REPLACE f1 WITH .T. ALL IN "tt"    && .T.全打钩，.F.全不打钩
thisform.grid1.setfocus

正是这样的效果，很感谢。