本人使用"hide windows 常用"，
确实是实现了“隐藏常用工具栏”的功能；
创建PROJECT，编译成EXE文件都正常
但运行EXE文件时，提醒：没有定义窗口“常用”？


麻烦给点拨一下？

没有定义，说明这个窗口不存在

编译成EXE好象是没系统工具栏。

VFP环境可以这样试试：
CLEAR
DIMENSION aSysToolbars[12,2]
aSysToolbars[1,1] = "表单设计器"
aSysToolbars[2,1] = "常用"
aSysToolbars[3,1] = "布局"
aSysToolbars[4,1] = "查询设计器"
aSysToolbars[5,1] = "视图设计器"
aSysToolbars[6,1] = "调色板"
aSysToolbars[7,1] = "表单控件"
aSysToolbars[8,1] = "数据库设计器"
aSysToolbars[9,1] = "报表设计器"
aSysToolbars[10,1] = "报表控件"
aSysToolbars[11,1] = "打印预览"
aSysToolbars[12,1] = "维护精灵"
? "隐藏"
_HideSysToolbars(@aSysToolbars)
? "2秒后显示"
INKEY(2)
? "显示"
_ShowSysToolbars(@aSysToolbars)
? "按任一键结束"
INKEY(0)
RETURN

FUNCTION _HideSysToolbars(aSysToolbars)
    LOCAL i
    FOR i=1 TO ALEN(aSysToolbars,1)
        IF WEXIST(aSysToolbars[i,1]) AND WVISIBLE(aSysToolbars[i,1])
            aSysToolbars[i,2] = .T.
            HIDE WINDOW (aSysToolbars[i,1])
        ENDIF
    ENDFOR
ENDFUNC

FUNCTION _ShowSysToolbars(aSysToolbars)
    LOCAL i
    FOR i=1 TO ALEN(aSysToolbars,1)
        IF WEXIST(aSysToolbars[i,1]) AND aSysToolbars[i,2]
            SHOW WINDOW (aSysToolbars[i,1])
        ENDIF
    ENDFOR
ENDFUNC

版主就是牛！牛版！
问题已解决！

简单就是：
hide windows 常用
改成：
IF WEXIST("常用") AND WVISIBLE("常用")
   HIDE WINDOW ("常用")
ENDIF

向吹水佬致敬