在网络上共享的DBF表，如果某人装了VFP9.0以独占模式打开看，则其他人用VFP软件就无法存取该表，如何解决？

SET EXCLUSIVE OFF
USE Temp.Dbf SHARED

SET EXCLUSIVE OFF  &&设置当前系统自由表打开方式为共享，即非独占打开。在此命令后，打开的自由表均为共享方式打开，无需在use命令后用shared的子句。
USE Temp.Dbf SHARED  &&用共享方式打开temp.dbf，只有锁定后才能修改。

如果文件确实存在（可预先探测），再使用 ON ERROR 看看如何？
   aa=.f.
   on error tt()
   use (带路径的 dbf)
   if aa
      MESSAGEBOX('文件已经被占用')  
      return
   endif
      
  function tt
   aa=.t.
  endfunc  

可否把自己的数据升级为DBC格式，对外则只提供一个视图给他？这也是一个思路。

某人某某人都可以随便用USE打开共享的DBF表？先解决共享DBF表管理方面的问题。

吹水佬：把DBF读入SQL？还是其他方法，请指点。我也是觉得文件夹共享，然后 用 “USE +服务器IP+文件夹+文件”这种方法比较低端 ，只要知道文件夹共享密码的人除了不能改文件，谁都可以独占打开

简单的中小型数据库应用，用共享文件（F/S）架构也是可行的选择。
特点是投入小（现成的），设置维护简单方便。
但要做得好就要花点心思，视实际情况，选择一种搞好的方案。
通常的做法：
1、设置共享文件夹时，设置的共享名尾部加“$”字符，如：data$，连接时\\192.168.0.1\data$
2、将代码文件（如EXE等）与数据文件（如DBF等）分开，放在不同的共享文件夹，最好放在不同的主机上。
3、代码文件（如EXE等）的共享连接的用户名和密码可以公开，方便客户端管理。
4、数据文件（如DBF等）的共享连接的用户名和密码要保密，程序运行时，需要使用数据文件时，由程序自动连接数据文件的共享文件夹，不需要时及时关闭连接。

建议收精，吹版给出了较为详细，可行。

程序中自动连接或断开共享文件夹连接的参考示例：
**
** 连接共享文件夹()
** 参数: szLocalName,szRemoteName,szUserName,szPassWord,ddFlags
** szLocalName ... 影射到本地设备，如 X:，为空时不映射为盘符，空连接。
** szRemoteName .. 连接的远程设备，如 \\server\共享文件夹$
** szUserName .... 用户名
** szPassWord .... 密码
** ddFlags ....... 1连接，0断开
**    例：建立空连接
**        连接共享文件夹(",\\192.168.0.1\data$,admin,12349798,1")
**
FUNCTION 连接共享文件夹(sz连接参数)
    LOCAL a连接参数[1]

    IF ALINES(a连接参数, sz连接参数, ",") != 5
        RETURN .F.
    ENDIF

    DECLARE LONG StrDup IN Shlwapi STRING@
    DECLARE LONG WNetAddConnection2 IN Mpr.dll STRING@, STRING@, STRING@, LONG
    DECLARE LONG WNetCancelConnection2 IN Mpr.dll STRING@, LONG, LONG
   
    LOCAL szLocalName, szRemoteName, szUserName, szPassWord, ddFlags
    LOCAL stNR, ddRet, szMsg
   
    szLocalName  = a连接参数[1]
    szRemoteName = a连接参数[2]
    szUserName   = a连接参数[3]
    szPassWord   = a连接参数[4]
    ddFlags      = a连接参数[5]

    IF ddFlags == "0"
        ddRet = WNetCancelConnection2(@szRemoteName, 0, 1)
        RETURN (ddRet == 0)
    ENDIF
   
        * NETRESOURCEA 结构
    stNR = REPLICATE(0h00, 4);
         + BINTOC(1,  "4RS");
         + REPLICATE(0h00, 8);
         + BINTOC(StrDup(@szLocalName),  "4RS");
         + BINTOC(StrDup(@szRemoteName), "4RS");
         + REPLICATE(0h00, 8)

    ddRet = WNetAddConnection2(@stNR, @szPassWord, @szUserName, 1)
   
    IF ddRet == 1219    && 已经有连接，断开再连接。
        WNetCancelConnection2(@szRemoteName, 0, 1)
        ddRet = WNetAddConnection2(@stNR, @szPassWord, @szUserName, 1)
    ENDIF

    IF ddRet != 0
        szMsg = ICASE(ddRet == 5,    "找不到 "     + szRemoteName + " 设备",;
                      ddRet == 85,   "本地设备 "   + szLocalName  + " 已经连接",;
                      ddRet == 66,   "本地设备 "   + szLocalName  + " 类型不匹配",;
                      ddRet == 1200, "指定的设备 " + szLocalName  + " 名称无效",;
                      ddRet == 67,   "找不到 "     + szRemoteName + " 网络名称",;
                      ddRet == 1206, "调用WNetAddConnection2()的配置文件格式不正确",;
                      ddRet == 1204, "网络设备 "   + szRemoteName + " 名称无效",;
                      ddRet == 2202, "网络设备 "   + szUserName   + " 用户名无效",;
                      ddRet == 170,  "网络忙，请重试",;
                      ddRet == 1223, "连接被取消",;
                      ddRet == 1205, "调用WNetAddConnection2()无法打开用户配置文件",;
                      ddRet == 1202, "本地设备 "   + szLocalName  + " 与其他网络资源已经连接",;
                      ddRet == 1208, "发生网络错误，可用WNetGetLastError()函数获得错误信息。",;
                      ddRet == 487,  "资源结构的lpLocalName成员未指定 " + szLocalName,;
                      ddRet == 87,   "资源结构的dwtype成员参数不正确",;
                      ddRet == 86,   "用户名或密码无效",;
                      ddRet == 1326, "用户名或密码无效",;
                      ddRet == 1203, "网络设备 "   + szRemoteName + " 不被接受",;
                      ddRet == 1222, "网络不可用", "登录连接异常")
        MESSAGEBOX(szMsg, "提示")
    ENDIF

    RETURN (ddRet == 0)
ENDFUNC

[此贴子已经被作者于2017-2-24 19:36编辑过]