因数据量很大，常规方法很慢，想用快速方法，不知道哪位大侠能实现或提供思路，不胜感激。

个人愚见，用正则表达式不过没有写过正则表达式。

这是一个同学的数据大约12000名同学数据

数据表结构不规范，无法快速。一再强调，这类表文件的设计应该是“学号、姓名、课程名称、成绩”这样的结构。只有这种结构，才能用很简洁的命令达到你的目的，现在的结构只能编程解决。但是，编程解决也不见得就不“快速”，至少程序代码正确的情况下，出结果的速度应该不会太慢。

猜一下，结果是否这样？

CREATE CURSOR 成绩表 (成绩 C(1), 分数 I)
INSERT INTO 成绩表 VALUES ("A", 10)
INSERT INTO 成绩表 VALUES ("B", 8)
INSERT INTO 成绩表 VALUES ("C", 6)
INDEX on 成绩 TAG 成绩
USE 快速统计 ALIAS tt IN 0
FOR i = 1 TO FCOUNT("tt")
    cFieldName = FIELD(i, "tt")
    cmd = [SET RELATION TO ALLTRIM(] + cFieldName + [) INTO "成绩表"]
    SELECT tt
    EXECSCRIPT(cmd)
    CALCULATE SUM(成绩表.分数) FOR !EMPTY(EVALUATE(cFieldName)) TO n分数 IN "tt"
    ? cFieldName, n分数
ENDFOR
CLOSE DATABASES ALL

Select Sum(Icase(语文 = "A", 10, 语文 = "B", 8, 6)) As 语文, ;
       Sum(Icase(数学 = "A", 10, 数学 = "B", 8, 6)) As 数学, ;
       Sum(Icase(英语 = "A", 10, 英语 = "B", 8, 6)) As 英语, ;
       Sum(Icase(物理 = "A", 10, 物理 = "B", 8, 6)) As 物理, ;
       Sum(Icase(化学 = "A", 10, 化学 = "B", 8, 6)) As 化学, ;
       Sum(Icase(生物 = "A", 10, 生物 = "B", 8, 6)) As 生物, ;
       Sum(Icase(政治 = "A", 10, 政治 = "B", 8, 6)) As 政治, ;
       Sum(Icase(历史 = "A", 10, 历史 = "B", 8, 6)) As 历史, ;
       Sum(Icase(地理 = "A", 10, 地理 = "B", 8, 6)) As 地理, ;
       Sum(Icase(体育 = "A", 10, 体育 = "B", 8, 6)) As 体育, ;
       Sum(Icase(美术 = "A", 10, 美术 = "B", 8, 6)) As 美术, ;
       Sum(Icase(音乐 = "A", 10, 音乐 = "B", 8, 6)) As 音乐, ;
       Sum(Icase(信技 = "A", 10, 信技 = "B", 8, 6)) As 信技, ;
       Sum(Icase(其它 = "A", 10, 其它 = "B", 8, 6)) As 其它  ;
  From 快速统计

*!*    12000名同学数据压力测试：

Clear
Set Talk Off
Close Databases All

*!*    构造12000名同学x9=108000条记录的测试数据：
Select 000001 As 学号, * From 快速统计 Where .F. Into Cursor Test Readwrite
For I = 1 To 12000
    Select I As 学号, * From 快速统计 Where Recno() < 10 Into Cursor Query
    Select Test
    Append From Dbf("Query")
Endfor


*!*    压力测试：约 6秒
T1 = Seconds( )
Select 学号, ;
       Sum(Icase(语文 = "A", 10, 语文 = "B", 8, 6)) As 语文, ;
       Sum(Icase(数学 = "A", 10, 数学 = "B", 8, 6)) As 数学, ;
       Sum(Icase(英语 = "A", 10, 英语 = "B", 8, 6)) As 英语, ;
       Sum(Icase(物理 = "A", 10, 物理 = "B", 8, 6)) As 物理, ;
       Sum(Icase(化学 = "A", 10, 化学 = "B", 8, 6)) As 化学, ;
       Sum(Icase(生物 = "A", 10, 生物 = "B", 8, 6)) As 生物, ;
       Sum(Icase(政治 = "A", 10, 政治 = "B", 8, 6)) As 政治, ;
       Sum(Icase(历史 = "A", 10, 历史 = "B", 8, 6)) As 历史, ;
       Sum(Icase(地理 = "A", 10, 地理 = "B", 8, 6)) As 地理, ;
       Sum(Icase(体育 = "A", 10, 体育 = "B", 8, 6)) As 体育, ;
       Sum(Icase(美术 = "A", 10, 美术 = "B", 8, 6)) As 美术, ;
       Sum(Icase(音乐 = "A", 10, 音乐 = "B", 8, 6)) As 音乐, ;
       Sum(Icase(信技 = "A", 10, 信技 = "B", 8, 6)) As 信技, ;
       Sum(Icase(其它 = "A", 10, 其它 = "B", 8, 6)) As 其它  ;
  From Test Group By 学号 NOWAIT
  =Messagebox("耗时 : " + Transform(Seconds() - T1) + " 秒")
  Browse Last

*!*    方法二：算法：12 - 2n  (n = ASC("科目名称") - 64)
Select Sum(12 - 2*(Asc(语文) - 64)) As 语文, ;
       Sum(12 - 2*(Asc(数学) - 64)) As 数学, ;
       Sum(12 - 2*(Asc(英语) - 64)) As 英语, ;
       Sum(12 - 2*(Asc(物理) - 64)) As 物理, ;
       Sum(12 - 2*(Asc(化学) - 64)) As 化学, ;
       Sum(12 - 2*(Asc(生物) - 64)) As 生物, ;
       Sum(12 - 2*(Asc(政治) - 64)) As 政治, ;
       Sum(12 - 2*(Asc(历史) - 64)) As 历史, ;
       Sum(12 - 2*(Asc(地理) - 64)) As 地理, ;
       Sum(12 - 2*(Asc(体育) - 64)) As 体育, ;
       Sum(12 - 2*(Asc(美术) - 64)) As 美术, ;
       Sum(12 - 2*(Asc(音乐) - 64)) As 音乐, ;
       Sum(12 - 2*(Asc(信技) - 64)) As 信技, ;
       Sum(12 - 2*(Asc(其它) - 64)) As 其它 ;
  From 快速统计

浙江省的高中生学业水平考试成绩反馈回来就是这种ABCDE的。数据转换必须写代码。速度应该也是可以的

5楼的代码附合要求