现有带CAN口上位机，拟用2个8路CAN直接与上位机通讯，厂家提供了dll链接库，弄了好几天还是不会读取/发送数据。请各位帮忙。[local]2[/local]资料见附件

[此贴子已经被作者于2016-3-19 14:02编辑过]

用vfp?

是的

使用手册有详细说明
主要参考两个文件
UISimCanFunc.h
UISimCanFunc.dll
一些常量或数据结构等定义在 UISimCanFunc.h 文件，主要的内容使用手册也有说明。
如果 API 库文件 UISimCanFunc.dll 支持 VFP，可以这样使用 API 的导出函数：
如：
函数 SearchDevice(dwDevType) 查找所有连接的网关设备，参数 dwDevType 设备类型，0x0D为所有类型、0x01为RS232CAN、0x08为PCICAN、0x04为USBCAN
假设 UISimCanFunc.dll 文件在当前默认目录
DECLARE LONG SearchDevice IN UISimCanFunc.dll LONG  && 声明
dwDevType = 0x0D  && 调用，查找所有类型设备
dwDevs = SearchDevice(dwDevType)
IF dwDevs > 0
    ? "找到的设备数量", dwDevs
ELSE
    ? "没有找到设备", dwDevs
ENDIF

[此贴子已经被作者于2016-3-19 15:36编辑过]

因没有现场，测试不了。
如果调用那个函数有问题，可以将相关代码贴上来探讨一下。

谢谢版主提示，这两天没上网，回复晚了，见谅。我试试，有问题再请教。

我采用的是com口，始终找不到设备，运行结果为“0”。

ThisForm.Olecontrol1.Settings = "9600,n,8,1"
ThisForm. = 2
DECLARE LONG SearchDevice IN UISimCanFunc.dll LONG  && 声明
dwDevType = 0x01  && 调用，查找所有类型设备
dwDevs = SearchDevice(dwDevType)
IF dwDevs > 0
    ? "找到的设备数量", dwDevs
ELSE
    ? "没有找到设备", dwDevs
ENDIF

如果dwDevType = 0x0D  运行结果为“-1”
麻烦版主再给分析一下。

[此贴子已经被作者于2016-3-22 12:32编辑过]

1、在“设备管理--端口--COM1--属性--端口设置”看看波特率是否9600和其他参数设置是否符合要求。
2、CAN设备是否正常连接启动。

先不要用上位机通讯库做测试。用现成的、成熟的 API 或其他第三方的串口调试软件做测试你的串口状态。

和吹同志说的一样，首先检查你的PC机上是否有串口设备，即：在“设备管理--端口--COM1--属性--端口设置”，设备存在吗？有冲突吗？有黄色报警符号吗？

接下来测试串口的状态，其他第三方的串口调试软件网上太多了。
1. 用 MS 通讯库 MScomm32.ocx，参考：https://support.
或者 WMI 类库：https://msdn.

2. 用 API 方式：
可以用 API ：CreateFile() 函数：http://www.

Do Decl

Local nIndex, cPort
For nIndex = 1 To 8  && 枚举 1-8 的 COM 端口
    cPort = "COM" + Transform(nIndex)
    ? "正在测试串口 " + m.cPort + ":", TestPort(m.cPort)
Endfor
* End of main

Function TestPort(cPort)
    #Define FILE_SHARE_READ      1
    #Define FILE_SHARE_WRITE     2
    #Define OPEN_EXISTING        3
    #Define GENERIC_READ         0x80000000
    #Define GENERIC_WRITE        0x40000000
    #Define FILE_FLAG_OVERLAPPED 0x40000000
    #Define INVALID_HANDLE_VALUE -1
    #Define FILE_ATTRIBUTE_NORMAL 128

    Local hPort, lnErr

    * hPort = CreateFile(cPort, GENERIC_READ, 0,0,;
        OPEN_EXISTING, FILE_FLAG_OVERLAPPED, 0)

    hPort = CreateFile(cPort,;
        BITOR(GENERIC_READ,GENERIC_WRITE),;
        0,0, OPEN_EXISTING,;
        BITOR(FILE_FLAG_OVERLAPPED, FILE_ATTRIBUTE_NORMAL), 0)

    If hPort = INVALID_HANDLE_VALUE
        lnErr = GetLastError()
        Return "错误 " + Transform(lnErr) +;
            ". " + GetErrorMessage(lnErr)
    Else
        = CloseHandle(hPort)
        Return "Ok"
    Endif
Endfunc


Procedure Decl
    Declare Integer CreateFile In kernel32;
        STRING lpFileName, Integer dwAccess, Integer dwShareMode,;
        INTEGER lpSecurityAttr, Integer dwCreationDisp,;
        INTEGER dwFlagsAndAttr, Integer hTemplateFile

    Declare Integer CloseHandle In kernel32 Integer hObject
    Declare Integer GetLastError In kernel32

    Declare Integer FormatMessage In kernel32;
        INTEGER dwFlags, Integer lpSource, Integer dwMessageId,;
        INTEGER dwLanguageId, Integer @lpBuffer,;
        INTEGER nSize, Integer Arguments

    Declare RtlMoveMemory In kernel32 As CopyMemory;
        STRING @Destination, Integer Source, Integer nLength
Endproc


Function GetErrorMessage(lnErr)
    #Define FORMAT_MESSAGE_ALLOCATE_BUFFER 256
    #Define FORMAT_MESSAGE_FROM_SYSTEM     4096
    #Define FORMAT_MESSAGE_IGNORE_INSERTS  512

    Local dwFlags, lpBuffer, lnLength, lpResult
    dwFlags = FORMAT_MESSAGE_ALLOCATE_BUFFER +;
        FORMAT_MESSAGE_FROM_SYSTEM + FORMAT_MESSAGE_IGNORE_INSERTS

    lpBuffer = 0
    lnLength = FormatMessage(dwFlags, 0, lnErr, 0, @lpBuffer, 0,0)
    If lnLength <> 0
        lpResult = Repli(Chr(0), 500)
        = CopyMemory (@lpResult, lpBuffer, lnLength)
        Return Strtran(Left(lpResult, lnLength), Chr(13) + Chr(10), "")
    Else
        Return "[]"
    Endif
Endfunc