在表单中按下command命令按钮后软键盘可用，但总是跟随一个c:\window\system32\cmd.exe黑窗口，怎么办？
command的click中：!osk.exe

试试 ! /N7 osk.exe

楼上正解，楼主要仔细看帮助。 加 N7 开关可以隐藏DOS运行框。

隐藏DOS运行框

谢谢各位指导！

屏幕键盘



#Define MAX_PATH 260
#Define OSK_EXE "osk.exe"

Do Declare
= ShellExecute(0, "open", GetOskPath(), "", "", 1)
* end of main

Function GetOskPath() As String
    Local cPath

    cPath = PathCombine(;
        GETENV("windir"),;
        "sysnative",;
        OSK_EXE )

    If File(cPath)
        Return m.cPath
    Endif

    cPath = PathCombine(;
        GetSysDir(),;
        OSK_EXE )

    Return Iif(File(cPath), m.cPath, OSK_EXE)

Function GetSysDir
    Local cBuffer, nBufsize
    cBuffer=Replicate(Chr(0), MAX_PATH)
    nBufsize= GetSystemDirectory(@cBuffer, Len(cBuffer))
    Return Substr(cBuffer, 1, nBufsize)

Function PathCombine(p1, p2, p3, p4, p5) As String
    Local cBuffer, cPath1, cPath2, nIndex, nCount
    nCount = Pcount()

    Do Case
        Case nCount = 0
            Return ""
        Case nCount = 1
            Return p1
    Endcase

    cBuffer = m.p1

    For nIndex=2 To nCount
        cPath1 = Strtran(m.cBuffer, Chr(0), "")
        cPath2 = Evaluate("m.p" + Transform(m.nIndex))
        cBuffer = Replicate(Chr(0), MAX_PATH)
        PathCombineApi(@cBuffer, cPath1, cPath2)
    Next
    Return Strtran(m.cBuffer, Chr(0), "")

Procedure Declare
    Declare Integer GetSystemDirectory In kernel32;
        STRING @lpBuffer, Integer nSize

    Declare Integer ShellExecute In shell32;
        INTEGER hWindow, String lpOperation,;
        STRING lpFile, String lpParameters,;
        STRING lpDirectory, Integer nShowCmd

    Declare Integer PathCombine In shlwapi;
        AS PathCombineApi;
        STRING @lpszDest, String lpszDir,;
        STRING lpszFile

win7旗舰,vfp9 sp2 7423运行没反应.在系统运行框中输入OSK可以调出软键盘.

[此贴子已经被作者于2016-3-2 10:56编辑过]

6楼 的代码可以在 win7旗舰版 32位 + VFP 9 sp2 下运行。
如果是 64 位的 OS，这么做试试看：

DECLARE INTEGER ShellExecute IN shell32 INTEGER hWindow, STRING lpOperation, STRING lpFile, STRING lpParameters, STRING lpDirectory, INTEGER nShowCmd
DECLARE integer Wow64DisableWow64FsRedirection IN kernel32 Long @
DECLARE integer Wow64RevertWow64FsRedirection IN kernel32 Long @

DECLARE INTEGER SetParent IN User32 INTEGER HWND, INTEGER ParenthWnd
DECLARE INTEGER FindWindow IN user32 STRING lpClassName, STRING lpWindowName

DECLARE INTEGER GetWindowLong IN user32 INTEGER hWnd, INTEGER nIndex
DECLARE INTEGER SetWindowLong IN user32 INTEGER hWnd, INTEGER nIndex, INTEGER dwNewLong
 
DECLARE INTEGER GetLastError IN kernel32

CLEAR
PUBLIC ofrm
ofrm = CREATEOBJECT("MyForm")
ofrm.show()


DEFINE CLASS MyForm as Form
    width = 1000
    ShowWindow = 2
    desktop = .T.
    ADD OBJECT txt as textbox
    ADD OBJECT cmd as commandbutton WITH top = 50 , caption = "\Click"
    ADD OBJECT tmr as timer WITH interval = 200
    PROCEDURE load
        LOCAL lnVal
        IF LEN(GETENV("ProgramFiles(x86)"))>1
            xxx=Wow64DisableWow64FsRedirection(lnVal)
        ENDIF

        = ShellExecute(0, "open", "osk.exe", "", "", 1)

        IF LEN(GETENV("ProgramFiles(x86)"))>1
            xxx=Wow64RevertWow64FsRedirection(lnVal)
        ENDIF
    ENDPROC
    PROCEDURE tmr.timer
        * hOsk = FindWindow (.NULL., "On-Screen Keyboard")
        hOsk = FindWindow (.NULL., "屏幕键盘")
        nStyle = GetWindowLong (hOsk, -16)
        This.Enabled = .F.
        ACTIVATE SCREEN
        ?nStyle && 0x16CE0000               ,BITSET(nStyle,30)
        *- 0x80000000
        ?SetWindowLong (hOsk, -16, nStyle-0xCE0000) && tried to remove the title bar
        ?GetLastError() && Error 5 : ERROR_ACCESS_DENIED
        ?SetWindowLong (hOsk, -16, BITSET(nStyle,30)) && tried to set child
        ?GetLastError() && Error 5 : ERROR_ACCESS_DENIED
        ?SetWindowLong (hOsk, -16, nStyle+0x40000000) && tried to set child
        ?GetLastError() && Error 5 : ERROR_ACCESS_DENIED
        ?SetParent(hOsk, ThisForm.HWnd) && tried to change parent
        ?GetLastError() && Error 5 : ERROR_ACCESS_DENIED
    ENDPROC
ENDDEFINE

欧了

不就是这样
! /N7 osk.exe
为什么你要写这么多，你的有什么好处？？