如何把EXCEL表存进SQL的表的IMAGE或者TEXT类型里面，然后可以取出来改写后再存进去

没弄过

1.sql表用 TEXT类型
2.保存文件到 TEXT类型字段
  str1=FILETOSTR('文件') &&注意带路径全文件名
  SQLEXEC(句柄,"INSERT INTO 表 (TEXT类型字段,文件名） VALUES  （?str1,'文件名')")
3.读取文件
   SQLEXEC(句柄,"SELECT TEXT类型字段,文件名 FROM 表","tmp")
   STRTOFILE(tmp.TEXT类型字段,路径+文件名）

注意。我给出只是示意代码，明白消化就可以了









[ 本帖最后由 kiff 于 2014-10-10 10:59 编辑 ]

1. 将 Excel 文件写入数据表 Employee 的“附件”字段（数据类型为 Text），同时将文件名写入“文件名”（Character类型）字段。

* 指定来源文件
LOCAL cFile,cStr,cFileName,cSql
cFile = GETFILE("xls*")
IF EMPTY(cFile)
    RETURN
ENDIF
IF !FILE(cFile)
    MESSAGEBOX('指定的文件不存在！',48,'提示')
    RETURN
ENDIF

* 上传附件，并保存文件名
cStr = FILETOSTR(cFile)
cFileName = JUSTFNAME(cFile)
cSql = 'UPDATE employee SET 附件=?cStr,文件名=?cFileName WHERE id = 287'
IF SQLEXEC(gnHandle,cSql) < 0
    MESSAGEBOX('添加附件失败！')
ENDIF

2. 删除数据表中保存的 Excel 文件

* 确认删除
IF MESSAGEBOX('是否删除附件？',36+256,'提示') = 7
    RETURN
ENDIF

LOCAL cSql
cSql = 'UPDATE employee SET 附件=NULL,文件名=NULL WHERE id = 287'
IF SQLEXEC(gnHandle,cSql) < 0
    MESSAGEBOX('删除附件失败！')
ENDIF

3. 下载并打开 Excel 文件

* 下载附件到临时文件 cFile
LOCAL cFile,cSql
cSql = 'SELECT 文件名,附件 FROM employee WHERE id = 287'
IF SQLEXEC(gnHandle,cSql,'curTmp') < 0
    MESSAGEBOX('下载附件失败！',48,'提示')
    RETURN
ENDIF
cFile = ADDBS(SYS(2023)) + ALLT(curTmp.文件名)
= STRTOFILE(curTmp.附件,cFile)
USE IN curTmp

* 打开附件
DECLARE Integer ShellExecute IN "Shell32.dll" Integer hwnd,String lpVerb,String lpFile,String lpPara,String lpDir,Long lpShowCmd
= ShellExecute(0,"open",cFile,"","",1)

非常感谢

不慎感激啊，呵呵

请教一下高手，如果在VFP里面直接查看EXCEL表，例如用IMAGE型显示EXCEL,不慎感激