各位老师，请教个问题，学习贵论坛的一个关于treeviewde 贴子, 在这段代码里好像没有设置根目录，
This.LineStyle= 1  && tvwRootLines
This.Style= 7  && tvwTreelinesPlusMinusPictureText
This.ImageList=Thisform.Imagelist1   &&与Imagelist控件建立关联
*This.SingleSel=.t.
SELECT bm
SET DELETED ON
GO TOP
DO WHILE !EOF()
      This.Nodes.Add(,,ALLTRIM(bm.bmdm),ALLTRIM(bm.bm),1,3)
               
    SELECT wjmjs
   SET DELETED ON
   SET FILTER TO ALLTRIM(wjmjs.bmdm)==ALLTRIM(bm.bmdm)
   GO TOP

     DO WHILE !EOF()
     This.Nodes.Add(ALLTRIM(bm.bmdm),4,ALLTRIM(wjmjs.Key),ALLTRIM(wjmjs.lxr),3,3)     
 SKIP
   ENDDO

   SELECT bm
   SKIP
ENDDO
SELECT wjmjs
SET FILTER TO
GO TOP
SELECT bm
GO TOP
我如何在这段代码里加入根目录？如： .Nodes.Add(,,"Root","人员目录表",1)
  如何把人员目录表作为根目录，点其+或-，各部门能够伸缩呢？谢谢

VFP帮助文件中有示例

This.Nodes.Add(,,ALLTRIM(bm.bmdm),ALLTRIM(bm.bm),1,3) 是将各个部门作为根节点，也就是说树形控件有多个根节点。

若要使树形控件只有一个根节点，如：根节点是“公司”，公司下面是“部门”，部门下面是“人员”，则可以按如下步骤操作：
1. 添加根节点
THISFORM.oleTree.Nodes.Add( ,0 ,STR(0)+'_', [XX公司 < 根节点 >], 1,)
2. 在根节点下添加部门节点和人员节点
SET DELETE ON
cKey_Root = STR(0)+'_'         && 根节点key
Select bm
SCAN
    * 添加部门节点
    cKey_BM = allt(bm.bmdm)    && 部门节点key
    THISFORM.oleTree.Nodes.Add(cKey_Root,4,cKey_BM,ALLTRIM(bm.bm),1,3)
    * 添加该部门下的人员节点
    SELECT wjmjs
    SCAN FOR ALLTRIM(wjmjs.bmdm)==ALLTRIM(bm.bmdm)
        THISFORM.oleTree.Nodes.Add(cKey_BM,4,ALLTRIM(wjmjs.Key),ALLTRIM(wjmjs.lxr),3,3)     
    ENDSCAN
ENDSCAN

收到的鲜花

• yin710 于 2014-07-08 13:44 送鲜花  3朵  

谢谢泉城飞狐老师

学习了！