功能强大的SendMessage函数
Windows API（应用程序接口）是Windows系列软件为程序开发人员提供的火力强大的“武器库”，在这个武器库中，有很多极具威力的武器，SendMessage就是其中之一，它的功能非常丰富，灵活使用这个函数，会给编程工作带来很多便利。本文以Visual Basic为例，结合几个具体的例子介绍该函数的功能。
一、SendMeaasge函数简介
顾名思义，SendMessage函数的功能是“发送消息”，即将一条消息发送到指定对象（操作系统、窗口或控件等）上，以产生特定的动作（如滚屏、修改对象外观等）。
SendMessage函数在VB中的函数说明如下：
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (Byval hwnd As Long, Byval wMsg As Long,Byval wParam As Long,lParam As Any) As Long
其中四个自变量的含义和说明如下：
hWnd：对象的句柄。希望将消息传送给哪个对象，就把该对象的句柄作为实参传送，在VB中可以简单地用“对象.hWnd”获得某个对象的句柄，如Text1.hWnd和Form1.hWnd分别可以得到Text1和Form1的句柄。
wMsg：被发送的消息。根据具体需求和不同的对象，将不同的消息作为实参传送，以产生预期的动作。
wParam、lParam：附加的消息信息。这两个是可选的参数，用来提供关于wMsg消息更多的信息，不同的wMsg可能使用这两个参数中的0、1或2个，如果不需要哪个附加参数，则将实参赋为NULL（在VB中赋为0）。
在简单了解了SendMessage函数的格式和功能后，让我们以几个例子来看看它的威力。
二、SendMessage函数使用实例
例1 多行TextBox中的快速处理功能在处理多行TextBox时我们经常会碰到以下几种情况：
希望了解多行TextBox中目前共有多少行文字。
想快速返回第N行的文字。
对于上面的情况，如果用VB自身的语句或函数来实现的话，要写不短的代码，而且由于要采用顺序查找的办法来完成，因此代码的执行效率也很低。如果使用SendMessage函数则可以大大减少代码量，并大幅度的提高执行效率。
用SendMessage函数完成上面两个任务的方法非常简单，每个任务只需简单地发送一条消息给多行TextBox即可，两个消息分别为：EM_GETLINECOUNT、EM_GETLINE，其它参数和返回值见附表。
下面用一个简单的实例演示这两个功能：
新建工程，在Form1上添加三个TextBox（名称分别为Text1、txtLineCount、TxtString，将Text1的Multi
Line属性置为True）、三个标签和一个命令按钮。为工程添加一个模块Moudle1，在其中写如下声明（其中
SendMessage函数的声明可以从VB的“API浏览器”中复制）： 消息常量名 消息值 wParam lParam 返回值
EM_GETLINECOUNT &HBA 未用 未用 行数
EM_GETLINE &HC4 要找的行号 存结果的字节串 结果字节串的字节数

Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long,lParam As Any) As Long
Public Const EM_GETLINECOUNT=&HBA
Public Const EM_GETLINE=&HC4
在Form1的代码模块中写如下代码：
Private Sub Command1_Click()
Dim str(256) As Byte
str(1)=1 '最大允许存放256个字符
'获取总行数，结果显示在文本框txtLineCount中
txtlineCount=SendMessage(Text1.hwnd,EM_GETLINECOUNT,0,0)
'获取第3行的数据放在str中，转换为字符串后显示在文本框txtString中
SendMessage Text1.hwnd,EM_GETLINE,2,str(0)
txtString= StrConv(str,vbUnicode)
End Sub
之后，按F5运行程序，在多行文本框中随便键入几行文字，然后按下[确定]按钮，出现如图画面，说明程序正确统计出了总行数和第3行的文字。
两点补充说明：在调用SendMessage获取第N行字符串时，lParam需要说明为字节数组，在调用完成后，再将字节数组转换为字符串；另外，调用前必须在lParam的前两个字节指明允许存放的最大长度，其中第一个字节为低位，第二个字节为高位，本例将高位（即str(1)）置1．说明最大允许存放256个字符。
例2 程序控制拉下或收起组合框的下拉列来
一般情况下，为了拉下或收起组合框的下拉列表，需要用键盘或鼠标进行操作，而有时我们希望程序运行的某个时刻自动拉出下拉列表（比如在一些演示程序中），为了实现这个目的，我们也只有借助于SendMessage函数，方法是发一个CB_SHOWDROPDOWN(&H14F)消息给组合框。
在发CB_SHOWDROPDOWN消息时，wParam参数决定了是拉下列表（=True时）还是收起列表（＝False时），lParam无用（设为0）。
为说明具体的使用方法，下面提供简单的程序片段。首先在代码模块中做如下声明：
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long,ByVal wMsg As Long，ByVal wParam As Long,lParam As Any) As Long
Const CB_SHOWDROPDOWN=&H14F
当程序中某处需要拉下组合框Combol的列表时，写如下调用语句：
SendMessage Combol.hwnd,CB_SHOWDROPDOWN,True,0
当需要收起组合框Combol的列表时，写如下语句：
SendMessage Combol.hwnd,CB_SHOWDROPDOWNN,False,0
例3 在列表框中查找匹配的项目
在Win95风格的帮助系统中一般都有一个“索引”页，索引页含有一个文本框和一个列表框，当用户在文本框中输入文字时，下拉列表会动态地显示与文本框中文字最匹配的项目，为用户提供了最大的方便。这种效果在应用程序的帮助系统中很容易实现（只要按照Win95帮助系统的正常制作过程制作就可以实现），如果想在应用程序的其它地方实现这种特性就需费一番心思了。
而使用SendMessage函数实现上述特性则非常简单，甚至只需一条语句就足够了，那就是在文本框的Change事件中给列表框发一条LB_FINDSTRING(&H18F）消息，该消息告诉列表框在列表中查找匹配的项目。
在发LB_FINDSTRING消息时，wParam参数代表从列表框的哪一个项目后面开始查找，一般情况下该参数可定为-1，表示从List1(0)即第一项开始向后循环查找，lParam则传进欲搜索的字符串（必须采用值传递）。
具体的代码和运行画面与后面的例4合并在一起演示。
例4 为ListBox添加水平滚动条
在VB中，列表框控件仅提供垂直滚动条，没有设置水平滚动条的能力，当某些项目的文本宽度较长时，超出列表框宽度部分的文本就无法显示出来，因此，很有必要为ListBox添加一个水平滚动条来方便操作。
为添加水平滚动条，只需发一条LB_SETHORIZONTALEXTENT(&H194)消息给列表框即可。发送消息时，wParam为滚动条的长度（以像素为单位，可通过计算得出准确的长度，也可随便给一个大于最大文本宽度的数字，如本例的250），lParam无用。下面是例3和例4合并在一起的代码和运行画面
Declare Function SendMessage Lib "user32" Alias "SendMessageA"(ByVal hwnd As Long,ByVal wMsg As Long,ByVal wParam As Long,lParam As Any) As Long
Public Const LB_FINDSTRING=&H18F
Public Const LB_SETHORIZONTALEXTENT=&H194
Private Sub Form_Load()
List1.AddItem "软件"
List1.AddItem "电脑游戏"
List1.AddItem "电视机"
List1.AddItem "电视台"
List1.AddItem "电脑"
List1.AddItem "电脑游戏软件"
'下一句为列表框添加水平滚动条
SendMessage List1.hwnd,LB_SETHORIZONTALEXTENT,250,0
End Sub
Private Sub Text1_Change()
'注意！当lParam传入的是字符串时，必须用ByVal传递
List1.ListIndex ＝ SendMessage(List1.hwnd,LB_FINDSTRING,-1,ByVal Text1.Text)
End Sub
通过上面几个例子，想必您已经对SendMessage函数的强大功能有了初步的了解。事实上利用该函数我们还可以完成更多更好的任务，如控制文本框的自动滚屏、实现文字编辑过程中的Undo功能、操纵应用程序的窗体控制菜单等等，感兴趣的读者请参阅有关Windows API的资料。
本文程序均用Visual Basic 5.0企业版编写，在Pwin95环境下运行正常。

判断应用程序是否仍在运行并设置焦点

下面的程序将利用VB程序的一个独有的特点：隐藏的父窗口。每一个VB应用程序都有一个隐藏的父窗口。该父窗口的标题（Caption） 就是你在“生成EXE”文件时所提供的应用程序的名称。 这就是为什么当你按下Ctl+Alt+Del查看时，任务列表中显示的总是应用程序的名称，而不是程序主窗口窗口的标题。

既然父窗口是隐藏的，那我们就没有必要去改变父窗口的标题。结果是，几乎所有的VB程序都可以用下面的小程序。

请注意，有一类程序不能应用下面这段小程序：如果你在“生成EXE”文件时，将应用程序的名称设置成为零字符，那么这段程序就无效 了。这是因为很多很多窗口都将其标题设为零字符。

另一个需要注意的地方就是：该程序用到了App.Previnstance来检查程序的另一个实例正在运行。这样做可以提高程序的效率， 但代价是你不能同时运行两个或以上的要检查的程序。如果你想这样做的话，请将有App.Previnstance的那一行语句注释掉。

请将下面的代码放置在模块中：

Declare Function GetWindowWord% Lib "User" (ByVal hWnd%, ByVal nIndex%)
Declare Function GetWindowText% Lib "User" (ByVal hWnd%, ByVal lpString$, ByVal aint%)
Declare Function GetWindowTextLength% Lib "User" (ByVal hWnd%)
Declare Function GetWindow% Lib "User" (ByVal hWnd%, ByVal wCmd%)
Declare Function SetFocusAPI% Lib "User" Alias "SetFocus" (ByVal hWnd%)

' get window word constants
Const GWW_HWNDPARENT = (-8)

' get window constants
Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

'------------------------------------------------------------------------------------
' 函数: Get_Other_Instance:布尔型, 参数( inhwnd Inputonly, outhwnd Outputonly)
' 目的: 获得要检测程序的另一个实例的窗口句柄。
'
' 描述: 同其它例子不同的是：该程序能检测哪些在运行时改变主窗口标题的程序，如MS WORD
' 实现的方法是利用VB程序独有的特点，即：每一个VB程序在运行时都会产生一个隐藏的父窗口。该父窗口的标题就是
' 你在生成EXE文件时所输入的程序名。VB程序员很少改变这些字符，并且用户看不到该父窗口。
'
' 输入：inhwnd -- 被叫窗口的窗口句柄
' 输出：如果窗口被找到则为真，否则为假。
' outhwnd -- 0 或设为另一个窗体的父窗口的hwnd
'
' ------------------------------------------------------------------------------------
'
Public Function get_other_instance (ByVal inhwnd As Integer, outhwnd As Integer) As Integer
Dim parent%, nlen%, ptext$, nexthwnd%, wtext$

get_other_instance = False
outhwnd = 0

If Not app.PrevInstance Then Exit Function

parent% = GetWindowWord(inhwnd, GWW_HWNDPARENT)
nlen% = GetWindowTextLength(parent%) + 2
ptext$ = Space$(nlen%)
nlen% = GetWindowText(parent%, ptext$, nlen%)
ptext$ = Left$(ptext$, nlen%)
nexthwnd% = GetWindow(parent%, GW_HWNDFIRST) ' get the first window in the window list

Do While nexthwnd% > 0
nlen% = GetWindowTextLength(nexthwnd%) + 2
wtext$ = Space$(nlen%)
nlen% = GetWindowText(nexthwnd%, wtext$, nlen%)
wtext$ = Left$(wtext$, nlen%)

If wtext$ = ptext$ And nexthwnd% <> parent% Then
get_other_instance = True
outhwnd = nexthwnd%
Exit Do
End If

nexthwnd% = GetWindow(nexthwnd%, GW_HWNDNEXT)

Loop

End Function

将下述代码放在窗体的Load事件中

Sub Form_Load()
Dim otherhwnd%

If Get_Other_Instance(Hwnd, otherhwnd%) then
MsgBox "Application is already running. Switching to existing Application"
SetFocusAPI otherhwnd%
End
End If

End Sub

查看GetWindow,GetWindowWord,GetWindowText,GetWindowTextLength,SetFocusAPI的用法