怎样能将每一个地块的相关内容保存到一个单独的excel

按字段地块号区分，每个地块单独成一个excel，相关内容是该行地块号为空的那几行记录，谢谢大佬

所有字段

所有字段

大佬这个做完每个excel里还是有好几个地块的，能不能再按村字段分开啊

我再研究下

萌新还在研究

CLOSE DATABASES ALL
SET SAFETY OFF
SET DEFAULT TO C:\Users\xqb\Desktop\世行程序
SELECT *,0000 标记 FROM clf INTO TABLE Test

    ALTER TABLE Test add 村1 c(10)
cDkh = ""
ncun = ""
SCAN
    IF NOT EMPTY(地块号)
        REPLACE 标记 WITH VAL(地块号)
        replace 村1 WITH 村
        cDkh = 地块号
        ncun = 村
    ELSE
        REPLACE 标记 WITH VAL(cDkh)
        REPLACE 村1 WITH ncun
    ENDIF
ENDSCAN
SELECT clf
cZdm = ""
FOR nCnt = 1 TO AFIELDS(Azdm)
    cZdm = cZdm + "," + Azdm[nCnt, 1]
ENDFOR
cZdm = SUBSTR(cZdm, 2)
SELECT DISTINCT 标记,村 FROM Test INTO CURSOR T_dist
SCAN
    SELECT Test
    COPY TO ("标段" + T_dist.村 + PADL(T_dist.标记, 4, "0")) TYPE XL5 FIELDS &cZdm FOR 标记 = T_dist.标记 AND 村1 = T_dist.村
ENDSCAN
USE IN Test
ERASE Test.Dbf
版主我这样运行完除了697个表外，还会出现多余的空表，这是怎么回事啊

搞定了，谢谢版主，不过COPY TO ( 建设年度 + 标段 + "标段" + T_dist.村1 + PADL(T_dist.标记, 4, "0") + "号地块") TYPE XL5 FIELDS &cZdm FOR 标记 = T_dist.标记 AND 村1 = T_dist.村1
这个生成的文件名怎么建设年度和标段都没有呢

CLOSE DATABASES ALL
SET SAFETY OFF
SET DEFAULT TO C:\Users\xqb\Desktop\世行程序
SELECT *,0000 标记,SPACE(10) 村1,SPACE(10) 建设年度1,SPACE(10) 标段1 FROM clf INTO TABLE Test
cDkh = ""
ncun = ""
njsnd = ""
nbdh = ""
SCAN
    IF NOT EMPTY(地块号)
        REPLACE 标记 WITH VAL(地块号)
        replace 村1 WITH 村
        replace 建设年度1 WITH 建设年度
        replace 标段1 WITH 标段
        cDkh = 地块号
        ncun = 村
        njsnd = 建设年度
        nbdh = 标段
    ELSE
        REPLACE 标记 WITH VAL(cDkh)
        REPLACE 村1 WITH ncun
        replace 建设年度1 WITH njsnd
        replace 标段1 WITH nbdh
    ENDIF
ENDSCAN
SELECT clf
cZdm = ""
FOR nCnt = 1 TO AFIELDS(Azdm)
    cZdm = cZdm + "," + Azdm[nCnt, 1]
ENDFOR
cZdm = SUBSTR(cZdm, 2)
SELECT DISTINCT 标记,村1,建设年度1,标段1 FROM Test INTO CURSOR T_dist
SCAN
    SELECT Test
    COPY TO ( ALLTRIM(T_dist.建设年度1) + "年-" + ALLTRIM(T_dist.标段1) + "标段" + ALLTRIM(T_dist.村1) + PADL(T_dist.标记, 4, "0") + "号地块") TYPE XL5 FIELDS &cZdm FOR 标记 = T_dist.标记 AND 村1 = T_dist.村1
ENDSCAN
USE IN Test
ERASE Test.Dbf
最终改成这样达到了我的预期，谢谢版主的帮助

[此贴子已经被作者于2018-9-17 18:52编辑过]