最近一直在看这方面的东西.

大家都这方面都有什么建议没?

如何更好的封装数据库的低层操作,如何处理错误等等.

这有一个链接,感觉写的不错,但不是很完善,大家可以看一下!

http://dev.csdn.net/develop/article/54/54679.shtm

记得踊跃发言哦^o^

那斑斑一般做东西的时候,是怎么优化系统的?

写函数么?

<%
'==============================================
'用 途：执行SQL语句:insert,delete,update
'返回值：成功:返回影响的行数
' 失败:返回Null
'说 明：可用IsNumeric()作用返回结果，即可知道SQL语句执行过程中是否有误
'==============================================
Function Exec(ByVal sql)
Dim Rows
On Error Resume Next
Call Conn.Execute(sql,Rows,&h0001)
if Err then
Err.Clear()
Exec = Null
else
Exec = Rows
end if
End Function

'================================================
'用 途：用于得到符合条件的记录的数目
'返回值：成功:返回记录集数目
' 失败:返回Null
'说 明：可用IsNumeric()作用返回结果，即可知道SQL语句执行过程中是否有误
'================================================
Function GetColumn(ByVal sql)
Dim Column
On Error Resume Next
Column = Conn.Execute(sql,,&h0001)(0)
if Err then
Err.Clear()
GetColumn = Null
else
GetColumn = Column
end if
End Function

'=============================================
'用 途：用于得到符合条件的记录
'返回值：成功:返回二维数组
' 失败:返回Null
'说 明：可用IsArray()作用返回结果，即可知道SQL语句执行过程中是否有误
'=============================================
Function Query(ByVal sql)
Dim TempArray,Record
On Error Resume Next
Set Record = Conn.Execute(sql,,&h0001)
if Err then
Err.Clear()
TempArray = Null
else
if Record.Eof then
Record.Close()
TempArray = Null
else
TempArray = Record.getRows()
Record.Close()
end if
end if
Query = TempArray
End Function
%>

这是我一般做东西的时候,常用的一些数据库操作的函数

由于是自己琢磨东西,所以感觉不知道是不是规范.是不是合理.

大家给点意见!

恩，斑斑谈一下您写东西的时候，都是如何做的？

写一个Conn.asp，然后写函数（偶尔用到一些类，例如：分页）

生成页面么？

呵呵，谢谢楼上的赞赏

是准备望ＪＳＰ方向发展了

但ＡＳＰ和ＪＳＰ比起来很"小巧"，不知道用这个词合适不合适．

一般的站点ＡＳＰ就绝对够用了

所以想知道ＡＳＰ系统优化一些东西．呵呵

[此贴子已经被作者于2006-11-1 10:44:26编辑过]

<%
'======================
'@描述：数据库操作类
'@类名：db
'@日期：2006-10-31
'@作者：NqIceCoffee
'======================
Class cls_db
Private Conn '数据库连接(Connection)
Private Rs '数据集(RecordSet)
Private DbName '数据库名称(String)
Public IsErr '执行过程中是否出现错误(Boolen)
Public ErrMessage '执行过程中的错误消息(String)

Private Sub Class_Initialize()
Set Conn = Server.CreateObject("Adodb.Connection")
Set Rs = Server.CreateObject("Adodb.RecordSet")
IsErr = False
ErrMessage = ""
End Sub

Private Sub Class_Terminate()
Conn.Close()
End Sub

Public Property Let setDataBaseName(str)
DbName = str
End Property

Public Sub OpenConn()
On Error Resume Next
Conn.Open "Provider=Microsoft.Jet.Oledb.4.0;Data Source=" & Server.MapPath(DbName)
If Err Then
IsErr = True
ErrMessage = ErrMessage & "<li><b>错误代码</b>：" & Err.Number & "。<b>描述</b>：" & Err.Description & "</li>"
Err.Clear()
End If
End Sub

Public Function Exec(sql)
Dim RowsAffect
On Error Resume Next
Call Conn.Execute(sql,RowsAffect,&h0001)
If Err Then
IsErr = True
ErrMessage = ErrMessage & "<li><b>错误代码</b>：" & Err.Number & "。<b>描述</b>：" & Err.Description & "</li>"
Err.Clear()
RowsAffect = Null
End If
Exec = RowsAffect
End Function

Public Function GetColumn(sql)
Dim returnValue
On Error Resume Next
returnValue = Conn.Execute(sql,,&h0001)(0)
If Err Then
IsErr = True
ErrMessage = ErrMessage & "<li><b>错误代码</b>：" & Err.Number & "。<b>描述</b>：" & Err.Description & "</li>"
Err.Clear()
returnValue = Null
End If
GetColumn = returnValue
End Function

Public Function Query(sql,dataStart,recordNum)
Dim QueryArray
On Error Resume Next
Rs.Open sql,Conn,1,1,&h0001
If Err Then
IsErr = True
ErrMessage = ErrMessage & "<li><b>错误代码</b>：" & Err.Number & "。<b>描述</b>：" & Err.Description & "</li>"
Err.Clear()
Query = Null
Exit Function
Else
If Rs.Eof Then
Rs.Close()
Query = Null
Exit Function
Else
Rs.AbsolutePosition = Int(dataStart)
Query = Rs.getRows(recordNum)
Rs.Close()
End If
End If
End Function

End Class

%>

这个是我的数据库操作类

刚完成,呵呵,如果不用在大一点的项目中,感觉它是鸡肋.

呵呵,偶还没真正的接触过大型的项目

所以还未曾体会!