CLEAR ALL 

SET PATH TO "MyTools"
SET PROCEDURE TO "MyForm" ADDITIVE 
SET PROCEDURE TO "MyComboBox" ADDITIVE

Main()

CLOSE PROCEDURES
CLEAR ALL 
RETURN 

PROCEDURE Main()
    LOCAL loForm
    loForm = CREATEOBJECT("_Form")
    WITH loForm
        .Caption = "test MyComboBox"
        .ShowTips = .T.
        .Show
    ENDWITH 
    READ EVENTS
ENDPROC 

DEFINE CLASS _Form AS MyForm

    ADD OBJECT Combo1 AS MyComboBox WITH Top = 5, Left = 5, Height = 100, Width = 120
    
    PROCEDURE Combo1.Init
        WITH This.lstList
            .Clear
            .AddItem("One")
            .AddItem("Two")
            .AddItem("Three")
            .AddItem("Fourth")
            .AddItem("Five")
            .AddItem("Six")
            .ListIndex = 1
        ENDWITH 
    ENDPROC 
    
ENDDEFINE 

MyForm.PRG

DEFINE CLASS MyForm AS Form

    PROCEDURE Arrange
        FOR EACH obj IN This.Controls FOXOBJECT 
            IF (VARTYPE(obj.CanArrange) == "L") .AND. obj.CanArrange
                obj.Arrange
            ENDIF 
        NEXT 
    ENDPROC 
    
    PROCEDURE Activate
        This.Arrange
    ENDPROC 
    
    PROCEDURE Resize
        This.Arrange
    ENDPROC 
    
    PROCEDURE Destroy
        CLEAR EVENTS
    ENDPROC 
    
ENDDEFINE 

MyComboBox.PRG

DEFINE CLASS MyComboBox AS Container

    BorderWidth = 0
    
    CanArrange = .T.

    ADD OBJECT txtInput AS TextBox WITH Height = 25, ToolTipText = "按TAB选定当前列表项"
    ADD OBJECT lstList  AS ListBox WITH ToolTipText = "鼠标滚动选项"
    
    PROCEDURE Arrange
        WITH This.txtInput
            .Top = 0
            .Left = 0
            .Width = This.Width
        ENDWITH 
        WITH This.lstList
            .Top = This.txtInput.Top + This.txtInput.Height + 2
            .Left = 0
            .Height = This.Height - .Top
            .Width = This.Width
        ENDWITH 
    ENDPROC 
    
    PROCEDURE txtInput.InteractiveChange
        LOCAL lnIndex
        WITH This.Parent
            FOR lnIndex = 1 TO .lstList.ListCount
                IF ALLTRIM(This.Value) $ .lstList.ListItem(lnIndex)
                    .lstList.ListIndex = lnIndex
                    EXIT 
                ENDIF 
            NEXT 
            IF lnIndex > .lstList.ListCount
                .lstList.ListIndex = 1
            ENDIF 
        ENDWITH 
    ENDPROC 
    
    #define K_TAB      9
    PROCEDURE txtInput.KeyPress(tnKeyCode, tnShiftAltCtrl)
        IF tnKeyCode == K_TAB
            This.Value = This.Parent.lstList.Value
        ENDIF 
    ENDPROC 
    
    PROCEDURE lstList.MouseWheel(tnDirection, tnShift, tnXCoord, tnYCoord)
        WITH This
            IF tnDirection < 0
                IF .ListIndex < .ListCount
                    .ListIndex = .ListIndex + 1
                ENDIF 
            ELSE
                IF .ListIndex > 1
                    .ListIndex = .ListIndex - 1
                ENDIF 
            ENDIF 
        ENDWITH 
    ENDPROC 
    
    PROCEDURE lstList.Click
        This.Parent.txtInput.Value = This.Value
    ENDPROC 
    
ENDDEFINE 

运行画面

[此贴子已经被作者于2015-11-30 01:52编辑过]

我这个就是光标在文本框中、光带在列表框中的啊。焦点不需要进入列表框中就可以操作，为什么要按两次？

我本来就没设计让光标进入列表框，那是漏了封掉这个入口。移动列表框中选择项，是用鼠标滚轮，不用键盘。

用过的都知道原生那个有什么问题，也知道需要怎样才好用。

如果要使用键盘上下键，我也不会让焦点进入列表框，而是直接在文本框中翻滚文本。

我操作只要一次。如果按TAB要两次，我是不会发放出来的。

[此贴子已经被作者于2015-11-30 11:04编辑过]

不是，原生ComboBox是当在输入框中键入列表框中没有的文本时会发生数据偏差，界面上，它也不能渐进搜索。下拉的体验其实不是那么好的，需要的动作多，更主要的是信息量少。我这个，要把列表框收放起来也很容易，就是为了显示更多的信息加速用户选定数据，才不那样做的。现在我这个是搜索项定位，也可以改为筛选过滤。反正源代码在这里，想怎么改都可以，那些已经不是问题了。

[此贴子已经被作者于2015-11-30 11:21编辑过]

我发这个的主要目的，其实不是控件本身，而是对先前所发如何写和使用类的补充。

改一下，滚动之后把焦点定回TextBox即可，在MouseWheel事件中，最后用SetFocus把焦点设回去。ListBox响应了鼠标事件，那么表明它已获得焦点，这个时候需要主动把焦点交还TextBox才好——在此情况下第一次按键盘被TextBox接管焦点应属于Bug。

[此贴子已经被作者于2015-11-30 13:02编辑过]

你把这些代码分别填在SCX/VCX的对应条目中也是一样的啊。