以下是引用mywisdom88在2016-3-14 16:40:12的发言：

你的程序没问题，只是少2张图片
up.bmp 和dowm.bmp

以下是引用liuxingang28在2016-3-14 16:49:27的发言：

针对楼主的第一个问题，解决方案如下：
1. 你没有将 up.bmp 和 down.bmp 两个文件放置到项目文件下，因此，单击列标题后虽然已排序，但列标题没有任何变化，不直观
2. 你是根据记录号来使奇偶行显示不同颜色的。在排序方式下应该做如下修改：
   第一步：为表添加一个新字段 FLAG (L)，并执行如下代码给Flag字段赋初值：
      LOCAL lFlag
      SCAN
          REPLACE flag with lFlag
          lFlag = !lFlag
      ENDSCAN
   第二步：修改 Grid1.Init 中的代码为：This.SetAll("DynamicBackColor","IIF(Flag,RGB(255,255,255),RGB(192,192,192))","Column")
   第三步：修改 MyProc.prg,在 GO TOP 之前添加如下代码：
      LOCAL lFlag
      SCAN
          REPLACE flag with lFlag
          lFlag = !lFlag
      ENDSCAN

以下是引用liuxingang28在2016-3-14 16:57:16的发言：

针对第二个问题，解决方案如下：

修改 MyProc.prg，在 THISFORM.Refresh 之后添加一行：THIS.Parent.SetFocus

以下是引用liuxingang28在2016-3-14 17:01:19的发言：

针对第三个问题，我们可以修改表格的 SelectedItemBackColor 和 SelectedItemForeColor 以改变选定单元格的字体颜色和背景色，但字体、字号无法修改。

以下是引用mywisdom88在2016-3-14 17:06:52的发言：


有点小问题，能定位到列了，但行记录，将会跳来跳去
是要把THIS.Parent.SetFocus放在GO TOP的上面
THIS.Parent.SetFocus
GO TOP
THISFORM.Refresh

以下是引用liuxingang28在2016-3-15 08:48:50的发言：

我的原话是：“在 THISFORM.Refresh 之后添加一行：THIS.Parent.SetFocus”，修改后的完整代码如下：

DEFINE CLASS MyHeader as Header
    name = 'Header1'
    PROCEDURE Click
        LOCAL nSelect,cFldName,cAlias,nNum_Tag
        cAlias = JUSTFNAME(THIS.Parent.ControlSource)    && 表名
        cFldName = JUSTEXT(THIS.Parent.ControlSource)    && 字段名
        cOldPict = JUSTSTEM(THIS.Picture)        && 当前图片
        THIS.Parent.Parent.SetAll('Picture','')        && 先去除所有图片
        nSelect = SELECT()
        SELECT (cAlias)
        nNum_Tag = ATAGINFO(aTag)
        DO CASE
        CASE ATC('up',cOldPict) > 0                && 升序时降序
            THIS.Picture = 'dowm.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0 && 若索引标记存在，则激活之
               SET ORDER TO &cFldName DESCENDING
            ELSE
                INDEX ON &cFldName TAG (cFldName) DESCENDING   && 索引标记不存在，新建之
            ENDIF
        CASE ATC('down',cOldPict) > 0            && 降序时无序
            SET ORDER TO
        OTHERWISE                                && 无序时升序
            THIS.Picture = 'up.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0
                SET ORDER TO &cFldName
            ELSE
                INDEX ON &cFldName TAG (cFldName)
            ENDIF
        ENDCASE
        lFlag = .f.
        SCAN
            REPLACE flag WITH lFlag
            lFlag = !lFlag
        ENDSCAN
        GO TOP
        THISFORM.Refresh
        THIS.Parent.SetFocus

        SELECT (nSelect)
    ENDPROC
ENDDEFINE

行记录不是“跳来跳去”，每次单击列标题后跳转到“第一条”记录，这也是大多数人的需要。如果你想单击列标题后保留原记录，也很简单，代码稍作修改如下：
DEFINE CLASS MyHeader as Header
    name = 'Header1'
    PROCEDURE Click
        LOCAL nSelect,cFldName,cAlias,nNum_Tag
        cAlias = JUSTFNAME(THIS.Parent.ControlSource)    && 表名
        cFldName = JUSTEXT(THIS.Parent.ControlSource)    && 字段名
        cOldPict = JUSTSTEM(THIS.Picture)        && 当前图片
        THIS.Parent.Parent.SetAll('Picture','')        && 先去除所有图片
        nSelect = SELECT()
        SELECT (cAlias)
        nRec = IIF(EOF(),0,RECNO())
        nNum_Tag = ATAGINFO(aTag)
        DO CASE
        CASE ATC('up',cOldPict) > 0                && 升序时降序
            THIS.Picture = 'dowm.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0 && 若索引标记存在，则激活之
               SET ORDER TO &cFldName DESCENDING
            ELSE
                INDEX ON &cFldName TAG (cFldName) DESCENDING   && 索引标记不存在，新建之
            ENDIF
        CASE ATC('down',cOldPict) > 0            && 降序时无序
            SET ORDER TO
        OTHERWISE                                && 无序时升序
            THIS.Picture = 'up.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0
                SET ORDER TO &cFldName
            ELSE
                INDEX ON &cFldName TAG (cFldName)
            ENDIF
        ENDCASE
        lFlag = .f.
        SCAN
            REPLACE flag WITH lFlag
            lFlag = !lFlag
        ENDSCAN
*        GO TOP
        IF nRec # 0
           GO nRec
        ENDIF
        THISFORM.Refresh
        THIS.Parent.SetFocus
        SELECT (nSelect)
    ENDPROC
ENDDEFINE

“师父领进门，修行在个人”。如果自己没有独立思考能力，单靠他人指导是不行的。

以下是引用liuxingang28在2016-3-16 16:09:26的发言：

回复 14 楼问题：

关于有些行颜色显示错乱，这不是我提供的代码有问题，而是你的初始索引文件有问题，需要 Reindex。因为在我的代码中，若该字段已建立了索引，则直接激活该索引，并没有重新建立。