我覺得你問這個問題很可笑, (VB 中的類具體是怎麽應用的?)

其實你使用 VB 的時候一直在使用類,
例如 App 是一個類, 你會用...
CheckBox, Clipboard, Control........... 等等, 都是 VB 的類啊

有些類不需要你親自實例化, 例如 App,
而有些類則需要你實例化才可以使用, 例如 Collection
-----------------------------------------------------------------------------------
你可能要問怎麽編寫一個類吧 (猜想的)

就在工程浏览器直接右击工程，选新建->类模块，在出现的框中点确定即可，然后重命名这个类的名，再编代码。

簡單的示例:
-------------------------
新建一個類, 在屬性窗口自己定義類的名字 (這裏定義爲 MyCar)
在類模組窗口編寫類的代碼:
------------------------------------------
Option Explicit

'聲明一些類成員(私有爲例):
Private m_Color As OLE_COLOR
Private m_Name As String


'聲明一些事件:
Public Event OnDrive()
Public Event OnStop()


'構造函數, 初始化某些成員
Private Sub Class_Initialize()
m_Color = vbRed
m_Name = "AFX"
End Sub


'定義類的一些屬性(以公有的爲例):
' 以下的屬性僅顯示簡單的功能, 這樣的屬性可以設置爲公有,
' 但有時在寫屬性時, 會對屬性進行必要的修改, 因此寫成以下的形式
Public Property Get Color() As OLE_COLOR ' 可讀屬性
Color = m_Color
End Property
Public Property Let Color(ByVal dwColor As OLE_COLOR) ' 可寫屬性
m_Color = dwColor
End Property

Public Property Get Name() As String
Name = m_Name
End Property
Public Property Let Name(ByVal lpszName As String)
m_Name = lpszName
End Property


' 定義一些類的方法(公有爲例):
Public Sub Drive()
Debug.Print "Running....."
RaiseEvent OnDrive () ' 引發一個事件
End Sub

Public Sub Shutdown()
Debug.Print "Stopped...."
RaiseEvent OnStop() '引發一個事件
End Sub
'--------------------------------------------------------------------------------------================================================


這樣就可以在你的專案裏使用 MyCar 這個類了

Dim WithEvents car As MyCar ' 聲明一個類作爲 Form 模組的成
' 員可以使用類的事件

Private Sub Command1_Click()

Set car = New MyCar ' 實例化
car.Color = vbGreen ' 設置類成員
car.Name = "Benz"

car.Drive ' 調用方法, 會引發一個 OnDrive 事件
car.Shutdown ' 會引發一個 OnStop 事件

Set car = Nothing ' 釋放類實例
End Sub

' 處理事件
Private Sub car_OnDrive()
Debug.Print "Pay attention...."
End Sub

Private Sub car_OnStop()
Debug.Print "You are safe now..."
End Sub

Let 是用來傳值用的, Set 是傳遞引用的, 例如

Private m_CObject As Object

Public Property Set CObject(pObject As Object)
Set m_CObject = pObject
End Property

Public Property Get CObject() As Object
Set CObject = m_CObject
End Property


----------------------------
在引用的時候就要用 Set 傳遞屬性:
'設置引用
Set myClass.CObject = pObject
'或者得到一個引用
Set pObject = myClass.CObject

''''''''''''''''''''''''''''''''''''''''''''
一個很好的例子就是 ADO.Command 物件的 ActiveConnection 屬性
Set hCmd.ActiveConnection = hConn

Set hConn2 = hCmd.ActiveConnection