请教：webborows控件与VFP交互
请教webborows控件与VFP交互，比如我点了网页里的一个值，把这个值传到VFP的text1上面来，这个要如何实现
WebBrowser 好像没有与用户交互的消息事件。
如果简单使用可以通过 TitleChange 事件处理。
例如：
程序代码：
TEXT TO c_html TEXTMERGE NOSHOW PRETEXT 15
<!DOCTYPE html>
<html>
<body>
<div id="click_test">
<input type="text" id="text1" value="123"><br>
<input type="text" id="text2" value="456"><br>
<input type="text" id="text3" value="789">
</div>
<script>
document.getElementById("click_test").addEventListener("click", function(e){
document.title = "click_data: " + e.target.value;
});
</script>
</body>
</html>
ENDTEXT
of = CREATEOBJECT("form1")
of.show(1)
CLEAR ALL
RETURN
DEFINE CLASS form1 AS Form
ADD OBJECT txt AS textbox WITH Top=10,Left=10,width=150,height=22
ADD OBJECT wb AS Olecontrol WITH Top=40,Left=0,Width=this.width,Height=this.height,;
OleClass="Shell.Explorer.2",Anchor=15,Visible=1
PROCEDURE Init
this.wb.Silent = .T.
thisform.wb.Navigate("about:" + c_html)
ENDPROC
PROCEDURE wb.TitleChange(c_str)
IF LEFT(c_str, AT(":", c_str)-1) == "click_data"
thisform.txt.value = c_str
ENDIF
ENDPROC
ENDDEFINE