如何在原表中生成序号字段并根据lbdm填充序号，例如：01生成071201001至代码01结束，02生成071202001至代码02结束，以此类推。求助大师帮忙，十分感谢！

REPLACE ALL XH WITH "0712"+ALLTRIM(LBDM)+"001"

估计是我没有表达清楚意思，就是代码01有几个人生成几个连续号码。例如：01代码的生成071201001、071201002……071201006.怎么实现不同类别的流水编号。

[此贴子已经被作者于2024-6-8 20:41编辑过]

CREATE CURSOR test (lbdm c(10), xh c(9))
INSERT INTO test (lbdm) VALUES ("01")
INSERT INTO test (lbdm) VALUES ("01")
INSERT INTO test (lbdm) VALUES ("01")
INSERT INTO test (lbdm) VALUES ("02")
INSERT INTO test (lbdm) VALUES ("02")
INSERT INTO test (lbdm) VALUES ("02")
INSERT INTO test (lbdm) VALUES ("02")
INSERT INTO test (lbdm) VALUES ("03")
INSERT INTO test (lbdm) VALUES ("03")
lcdm = SPACE(0)
lcxh = "071201"
SCAN 
    IF lbdm == lcdm
        lnxh = lnxh + 1
    ELSE
        lcdm = lbdm
        lnxh = 1
    ENDIF
    REPLACE xh WITH lcxh + PADL(lnxh,3,"0") 
ENDSCAN
BROWSE 

有没有简单点的命令，直接在原表中生成序号字段填充流水号

[此贴子已经被作者于2024-6-8 21:04编辑过]

我感觉他是比如01有6个，生成：01001至01006，02有9个，生成02001至02009，前缀共用0712

lcdm = SPACE(0)
lcxh = "0712"
SCAN 
    IF lbdm == lcdm
        lnxh = lnxh + 1
    ELSE
        lcdm = lbdm
        lnxh = 1
    ENDIF
    REPLACE xh WITH lcxh +ALLTRIM(LBDM) +PADL(lnxh,3,"0") &&&此处稍微修改一下
ENDSCAN
BROWSE 

[此贴子已经被作者于2024-6-9 16:33编辑过]

Select lbdm,Count(*) rs From ceshi Group By 1 Into Array alcxh&&&ceshi为原表名
Select ceshi
Blank Fields xh All&&&增加测试用

Go Top
For i=1 To Alen(alcxh,1)
    For j=1 To alcxh[i,2]
        Replace xh With  "0712"+Alltrim(lbdm)+Padl(j,3,"0")
        If Not Eof()
            Skip 1
        Else
            Exit
        Endif
    Endfor
Endfor
Browse

[此贴子已经被作者于2024-6-9 05:48编辑过]

4楼已经给出代码啦，是这样的吗？
哈哈，与你的6楼的一样哈。

[此贴子已经被作者于2024-6-9 06:34编辑过]

select recno() as rec, * from 你的表 into cursor temp
select a.xm, a.xb, a.lbdm, '0712'+a.lbdm+padl(1+a.rec-b.beg,3,'0') as 序号 from temp a ;
    inner join (select lbdm, min(rec) as beg from temp group by lbdm) b on a.lbdm = b.lbdm ;
    into dbf 结果表

[此贴子已经被作者于2024-6-9 06:55编辑过]

我就是完全复制的4楼的，就是替换那个地方lcxh = "071201"换成了lcxh = "0712"