请教win7打开软件命令这样为什么不能打开来
run("C:\Windows\System32\osk.exe")

run是什么函数？

请问，有什么好方法可以调出软键盘吗？
RUN  "C:\Windows\System32\osk.exe" 也调不出来，怪事

[此贴子已经被作者于2023-12-15 14:15编辑过]

试一下 这样打开

DECLARE INTEGER ShellExecute IN shell32 INTEGER hWindow, STRING lpOperation, STRING lpFile, STRING lpParameters, STRING lpDirectory, INTEGER nShowCmd
  = ShellExecute(0, "open", "osk.exe", "", "", 1)
  CLEAR DLLS 

你好，试了下也不行

CLEAR
Declare long ShellExecute IN "shell32" LONG,STRING,STRING,STRING,STRING,LONG
Declare long Wow64DisableWow64FsRedirection IN "kernel32" long @
Declare long Wow64RevertWow64FsRedirection IN "kernel32" long
Declare long LoadLibrary IN "kernel32" string
Declare long FreeLibrary IN "kernel32" long
Declare long GetProcAddress IN "kernel32" long,string
*!*  32位进程在64位系统中shell要预判断，64位进程不用考虑
IF is64()==1
   LOCAL fsRedirect
   STORE 0 TO m.fsRedirect
   m.fsRedirect=Wow64DisableWow64FsRedirection(@m.fsRedirect)
   IF m.fsRedirect>0  
      ShellExecute(0,"open","osk.exe","","c:\windows\system32",1)
      Wow64RevertWow64FsRedirection(m.fsRedirect)
   ENDIF
ENDIF

FUNCTION is64() as long
    LOCAL hMod,lPA1,lPA2
    STORE 0 TO m.hMod,m.lPA1,m.lPA2
    m.hMod = LoadLibrary("Kernel32")
    If m.hMod >0
        m.lPA1 = GetProcAddress(m.hMod, "Wow64DisableWow64FsRedirection")
        m.lPA2 = GetProcAddress(m.hMod, "Wow64RevertWow64FsRedirection")
        FreeLibrary(m.hMod)
    ENDIF
    IF m.lPA1>0 AND m.lPA2>0
       RETURN 1
    ELSE
       RETURN 0
    ENDIF
ENDFUNC

[此贴子已经被作者于2023-12-16 00:33编辑过]

学习学习！