继续请教下，具体怎么加CloseHandle？

是注册API，然后CloseHandle(0)?

意思大概是这样：

Declare Long CreateMutex in win32api String, Long, String
Declare Long GetLastError in win32api
Declare Long CloseHandle in win32api Long

Local hMutex

m.hMutex = CreateMutex(Null, 1, 'mytest')
If (m.hMutex != 0) and (GetLastError() == 183)
    CloseHandle(m.hMutex)
    MessageBox('重复运行')
    Quit
Else
    MessageBox('首次运行' + 0h0d0a0d0a + '别关闭我，再次运行试试')
EndIf

我也不确定15楼说的是不是这一步？如果是，则并非必要，加上它仅仅是出于遵循良好的编程习惯
重复运行时，CreateMutex 得到的句柄副本也属于系统资源，操作系统会自动清理任何被终止进程未释放的资源。这个api多用于多线程间的同步/互锁，如果是用于线程，是需要主动关闭以避免引用计数混乱的，但这里是用于进程

学习了。之前测试时加不加CloseHandle都能判断重复运动。

学习，多谢！

public mmtitle,hfile
mmtitle="随便起个名字吧"
if IsRunAgain()
    MESSAGEBOX("程序已经在运行，请检查！",64+4096,"温馨提示")
    quit
ENDIF
return

Function IsRunAgain
Declare Long OpenFileMapping In WIN32API Long, Long, String
Declare Long CreateFileMapping In WIN32API Long, Long, Long, Long, Long, String
DECLARE INTEGER CloseHandle IN kernel32.DLL INTEGER hObject
cPID = mmtitle
hFile = OpenFileMapping(4, 0, cPID)
If hFile=0
    hFile = CreateFileMapping(-1, 0, 4, 0, 1+Len(cPID), cPID+Chr(0))
    Return .F.
Else
    =CloseHandle(hFile)
    Return .T.
Endif
Endfunc

不错，不错，多谢！

简单的文件互斥，也可以解决问题

很简单，程序启动时，任意建立一个文件，可以为空，程序结束时删除它。

每次程序启动时，检查这个文件是否存在，如果存在，说明是非正常退出。

至于程序是否已运行，用findwidow就可以了。。。

*main.prg
*-防止程序重复运行的代码
_screen.Visible = .f.
_screen.windowstate=1
DECLARE integer FindWindow in Win32Api String, String
wclass=0
winname="水表（流量计）远程数据采集系统"
apphand = FindWindow(wclass ,winname)
IF apphand<>0
    Messagebox("程序已经运行！",48,"系统信息")
    QUIT
ENDIF
MODIFY WINDOW screen TITLE "水表（流量计）远程数据采集系统"

*系统设置