有同事工作中碰到这么个问题：
要判断EXCEL表中的单元格C2 中有没有图片，如果有，则把这个图片更新到另一个excel表中的C20中（C20如有图片要先清除）
这个vfp代码能做得到吗？

[此贴子已经被作者于2022-8-27 22:32编辑过]

给个文件来测试

样表

cDefPath = ADDBS(JUSTPATH(SYS(16)))
SET DEFAULT TO (cDefPath)
上报表 = cDefPath + "马头所上报表.xlsx"
汇总表 = cDefPath + "汇总表.xlsx"
oExcel = CREATEOBJECT("Excel.Application")
she1 = oExcel.WorkBooks.Open(上报表).Sheets("Sheet1")
she2 = oExcel.WorkBooks.Open(汇总表).Sheets("Sheet99")
IF picCopy(she1,"$C$2")
    picPaste(she2,"$C$20")
ENDIF
oExcel.Visible = 1
*oExcel.WorkBooks.Close
*oExcel.Quit
CLEAR ALL 
RETURN

FUNCTION picCopy(she,rg)
    FOR EACH sp IN she.Shapes
        IF sp.TopLeftCell.Address==rg
            sp.CopyPicture
            RETURN .t.
        ENDIF
    ENDFOR
    RETURN .f.
ENDFUNC

FUNCTION picPaste(she,rg)
    FOR EACH sp IN she.Shapes
        IF sp.TopLeftCell.Address==rg
            sp.Delete
        ENDIF
    ENDFOR
    she.Range(rg).Select
    she.Paste
ENDFUNC

[此贴子已经被作者于2022-8-29 15:21编辑过]

收到的鲜花

• zhken 于 2022-09-01 22:35 送鲜花  1朵   附言：实在厉害。

学习啦，谢谢！

吹版 威武，学习了！

因两周去帮扶农户原因, 回来发现问题已了结，还是专家的厉害！
4楼吹水佬的方法简单精辟, 完全达到目的, 在此给予迟来的感谢