ON ERROR DO errHandler WITH ;
   ERROR( ), MESSAGE( ), MESSAGE(1), PROGRAM( ), LINENO( )
USE nodatabase  
ON ERROR  && 恢复系统错误处理程序.

PROCEDURE errHandler
   PARAMETER merror, mess, mess1, mprog, mlineno
   CLEAR
   ? '错误编号: ' + LTRIM(STR(merror))
   ? '错误信息: ' + mess
   ? '错误的代码行: ' + mess1
   ? '错误的行号: ' + LTRIM(STR(mlineno))
   ? '错误的程序: ' + mprog
ENDPROC

如果错误在表单内，怎么获取调用表单名称？

有查找当前窗口的函数，函数名忘记了，可到帮助文件中查。

api?

VFP的内部函数。

SYS(1271)试试

PARAMETERS nError,cMessage,cMessage1,cProgram,nLineno
SET TEXTMERGE DELIMITERS TO
SET TEXTMERGE ON
SET TEXTMERGE TO ErrorLog.txt ADDITIVE NOSHOW
\---------------------------------------------------------------------
\<<DATE( )>> <<TIME( )>> 错误记录
\程序标题: <<_Screen.Caption>>
\程序开发版本: <<VERSION(1)>>
DO CASE
CASE _Screen.WindowState=0
        \窗口状态: 普通
CASE _Screen.WindowState=1
        \窗口状态: 最小化
CASE _Screen.WindowState=2
        \窗口状态: 最大化
ENDCASE
\窗口集合数: <<_Screen.FormCount>>
\网络机器信息: <<SYS(0)>>
\
\执行程序: <<JUSTFNAME(SYS(16,1))>>
\执行程序所在目录: <<JUSTPATH(SYS(16,1))>>
\执行程序所在目录磁盘空间: <<DISKSPACE(JUSTDRIVE(SYS(16,1)))>>
\
\默认目录: <<SYS(5)>><<SYS(2003)>>
\默认目录磁盘空间: <<DISKSPACE(SYS(5))>>
\文件搜寻路径: <<SET("PATH")>>
\
\系统临时目录: <<SYS(2023)>>
\虚拟内存池大小: <<SYS(1001)>>
\
\正在使用的工作区: <<ALIAS()>>
\活动字段: <<VARREAD()>>
\
IF TYPE("_Screen.ActiveForm.Name")="C"
    \活动表单: <<_Screen.ActiveForm.Name>>
    \表单标题: <<_Screen.ActiveForm.Caption>>
    \表单基类: <<_Screen.ActiveForm.BaseClass>>
    \表单派生: <<_Screen.ActiveForm.Class>>
    \表单派生库: <<_Screen.ActiveForm.ClassLibrary>>
    \表单位置: <<SYS(1271, _Screen.ActiveForm)>>
ELSE
    \无活动表单
ENDIF
IF TYPE("_Screen.ActiveForm.ActiveControl") = "O"
    \活动控制: <<_Screen.ActiveForm.ActiveControl.Name>>
    IF TYPE("_Screen.ActiveForm.ActiveControl.Caption")="C"
        \控制标题: <<_Screen.ActiveForm.ActiveControl.Caption>>
    ENDIF
    \控件基类: <<_Screen.ActiveForm.ActiveControl.BaseClass>>
    \控件派生: <<_Screen.ActiveForm.ActiveControl.Class>>
    \控件派生库: <<_Screen.ActiveForm.ActiveControl.ClassLibrary>>
    \控件位置: <<SYS(1271, _Screen.ActiveForm.ActiveControl)>>
ELSE
    \无活动控制
ENDIF
\
\错误代号: <<nError>>
\错误信息: <<cMessage>>
\产生错误的位置: <<cProgram>>
\所在行号: <<nLineno>>
\产生错误的代码: <<cMessage1>>
\
\输出内存使用情况 -> MemoryLog.txt
\输出工作环境到 -> StatusLog.txt
*DISPLAY MEMORY NOCONSOLE TO FILE MemoryLog.txt
*DISPLAY STATUS NOCONSOLE TO FILE StatusLog.txt
\
\---------------------------------------------------------------------
SET TEXTMERGE TO
*nValue=
MESSAGEBOX("【程序发生错误！详细信息如下】："+CHR(13)+CHR(13)+;
    "【错误代号】: "+LTRIM(STR(nError))+CHR(13)+;
    "【错误行号】: "+LTRIM(STR(nLineno))+CHR(13)+;
    "【错误信息】: "+cMessage+CHR(13)+;
    "【错误代码】: "+cMessage1+CHR(13)+;
    "【错误位置】: "+cProgram+CHR(13)+CHR(13)+;
    "【该错误已经记录到指定文件中。】"+CHR(13)+CHR(13)+;
    "【系统将立刻关闭！如果重启后还不能使用，请联系系统开发人员！】";
    , 0+16 , "错误提示信息")
CLOSE all
Clear Events
ON SHUTDOWN
CLOSE Database All &&关闭所有数据库

[此贴子已经被作者于2022-7-26 08:59编辑过]

感谢各位。