| 网站首页 | 业界新闻 | 小组 | 威客 | 人才 | 下载频道 | 博客 | 代码贴 | 在线编程 | 编程论坛
共有 329 人关注过本帖
标题:大佬们这段VB如何转化成VFP
只看楼主 加入收藏
liunis
Rank: 1
等 级:新手上路
帖 子:49
专家分:0
注 册:2021-9-25
结帖率:69.23%
收藏
已结贴  问题点数:10 回复次数:12 
大佬们这段VB如何转化成VFP
引用:使用()
注意:该方法需要一个StringCollection对象。下面的代码可以被正确执行。要保证复制的文件存在。
Dim path As New System.Collections.Specialized.StringCollection
path.Add("D:\aaaa.xml")
(path)
搜索更多相关主题的帖子: VFP Computer VB 转化 path 
2022-06-20 13:15
吹水佬
Rank: 20Rank: 20Rank: 20Rank: 20Rank: 20
等 级:版主
威 望:362
帖 子:8990
专家分:39026
注 册:2014-5-20
收藏
得分:0 
VFP可以使用VB控件吗
2022-06-20 14:12
liunis
Rank: 1
等 级:新手上路
帖 子:49
专家分:0
注 册:2021-9-25
收藏
得分:0 
回复 2楼 吹水佬
不大懂,求教复制文件的方法
2022-06-20 14:23
吹水佬
Rank: 20Rank: 20Rank: 20Rank: 20Rank: 20
等 级:版主
威 望:362
帖 子:8990
专家分:39026
注 册:2014-5-20
收藏
得分:0 
以下是引用liunis在2022-6-20 14:23:19的发言:

不大懂,求教复制文件的方法

复制文件形式多样,具体说说复制过程
2022-06-20 14:31
liunis
Rank: 1
等 级:新手上路
帖 子:49
专家分:0
注 册:2021-9-25
收藏
得分:0 
复制C:\abc.zip  (引用或路径,好比鼠标右键对此文件复制)到剪贴板,后可以在QQ或微信 粘贴文件给人
2022-06-20 14:39
吹水佬
Rank: 20Rank: 20Rank: 20Rank: 20Rank: 20
等 级:版主
威 望:362
帖 子:8990
专家分:39026
注 册:2014-5-20
收藏(1)
得分:10 
回复 5楼 liunis
给个示例代码看有无帮助
程序代码:
**
** 剪贴板在不同应用中复制粘贴文件
** 参考:https://msdn./en-us/library/windows/desktop/ff468802(v=vs.85).aspx
** 

**
** 示例1
** 先在资源管理器选择“复制”,然后运行本代码。
**
DECLARE LONG IsClipboardFormatAvailable IN user32 LONG
DECLARE LONG OpenClipboard IN user32 LONG
DECLARE LONG CloseClipboard IN user32
DECLARE LONG GetClipboardData IN user32 LONG
DECLARE LONG DragQueryFile IN shell32 LONG, LONG, STRING@, LONG

#DEFINE CF_HDROP  15

DIMENSION aFiles[1]
IF _GetClipFiles(@aFiles)
    FOR i=1 TO ALEN(aFiles)
        ?aFiles[i]
    ENDFOR
ENDIF
CLEAR DLLS
RETURN

FUNCTION _GetClipFiles(aFiles)
    IF IsClipboardFormatAvailable(CF_HDROP) == 0
        RETURN .F.
    ENDIF
    IF OpenClipboard(0) == 0
        RETURN .F.
    ENDIF
    LOCAL hDrop
    hDrop = GetClipboardData(CF_HDROP)
    IF hDrop == 0
        CloseClipboard()
        RETURN .F.
    ENDIF
    LOCAL i, nFiles, sBuf, nBufSize
    nFiles = DragQueryFile(hDrop, -1, NULL, 0)
    DIMENSION aFiles[nFiles]
    FOR i=0 TO nFiles-1
        nBufSize = DragQueryFile(hDrop, i, NULL, 0) + 1
        sBuf = SPACE(nBufSize)
        DragQueryFile(hDrop, i, @sBuf, nBufSize)
        aFiles[i+1] = RTRIM(sBuf, 0h00)
    ENDFOR
    CloseClipboard()
    RETURN .T.
ENDFUNC

**
** 示例2
** 假设要复制 C:\TEMP\test1.txt和C:\TEMP\test2.txt文件
** 先运行本代码,然后在资源管理器选择“粘贴”
**
DECLARE LONG OpenClipboard IN user32 LONG
DECLARE LONG EmptyClipboard IN user32
DECLARE LONG CloseClipboard IN user32
DECLARE LONG SetClipboardData IN user32 LONG, LONG
DECLARE LONG GlobalAlloc IN kernel32 LONG, LONG
DECLARE LONG GlobalLock IN kernel32 LONG
DECLARE LONG GlobalUnlock IN kernel32 LONG

#DEFINE CF_HDROP  15
#DEFINE GHND  0x0042
sFiles = "C:\TEMP\test1.txt" + 0h00 + "C:\TEMP\test2.txt" + 0h0000
_SetClipFiles(sFiles)
CLEAR DLLS
RETURN

**    typedef struct _DROPFILES {
**        DWORD pFiles; // Offset of the list          4 Byte
**        POINT pt;     // Drop coordinates            8 Byte
**        BOOL fNC;     // Client or nonclient area    4 Byte
**        BOOL fWide;   // ANSI or Unicode text        4 Byte
**    } DROPFILES, FAR* LPDROPFILES;                      20 Byte

FUNCTION _SetClipFiles(sFiles)
    IF OpenClipboard(0) == 0
        RETURN .F.
    ENDIF
    LOCAL hDrop, pDrop, stDROPFILES
    EmptyClipboard()
    stDROPFILES = BINTOC(20, "4RS") + REPLICATE(0h00, 16) + sFiles
    hDrop = GlobalAlloc(GHND, LEN(stDROPFILES))
    pDrop = GlobalLock(hDrop)
    SYS(2600, pDrop, LEN(stDROPFILES), stDROPFILES)
    GlobalUnlock(hDrop)
    SetClipboardData(CF_HDROP, hDrop)
    CloseClipboard()
    RETURN .T.
ENDFUNC


2022-06-20 16:05
liunis
Rank: 1
等 级:新手上路
帖 子:49
专家分:0
注 册:2021-9-25
收藏
得分:0 
2022-06-20 16:20
liunis
Rank: 1
等 级:新手上路
帖 子:49
专家分:0
注 册:2021-9-25
收藏
得分:0 
回复 6楼 吹水佬
2022-06-20 16:21
sych
Rank: 3Rank: 3
等 级:论坛游侠
威 望:4
帖 子:128
专家分:108
注 册:2019-10-11
收藏
得分:0 
这些应该设置成精华帖
2022-06-20 16:37
nbwww
Rank: 4
等 级:业余侠客
威 望:5
帖 子:114
专家分:279
注 册:2021-1-9
收藏
得分:0 
回复 6楼 吹水佬
这个必须收藏
2022-06-20 17:00
快速回复:大佬们这段VB如何转化成VFP
数据加载中...
 
   



关于我们 | 广告合作 | 编程中国 | 清除Cookies | TOP | 手机版

编程中国 版权所有,并保留所有权利。
Powered by Discuz, Processed in 0.120400 second(s), 8 queries.
Copyright©2004-2022, BCCN.NET, All Rights Reserved