试试增加延时
INKEY(2)  && 要延时

多谢吹版，OK

谢谢 ！！

http://www.chinatax.
能不能帮着分析下  这个页面上的数据如何获取
具体内容试了好几种办法都没有  

IE控件可以打开吧，速度可能慢点，但使用简单。

是不是要这些数据

oie = CREATEOBJECT("internetexplorer.application")
lurl="http://www.chinatax.
oie.Navigate(lurl)
DO WHILE oie.Busy OR oie.ReadyState!=4
    INKEY(2)
    ?? " 请稍候......",TIME()+0h0D
ENDDO
bError = .F.
TRY
    lctext = oie.document.body.innerHTML
CATCH
    bError = .T.
    MESSAGEBOX("网页打开错误",0+16,"出错了")
ENDTRY

?lctext
 _CLIPTEXT =lctext

[此贴子已经被作者于2021-9-7 17:00编辑过]

是这些数据   第一页的搞下来了   第二页没有链接   直接运行javascript吗？  

获取数据是用POST请求
请求地址：http://www.chinatax.
Send()数据格式：timeOption=0&page=页号&pageSize=每页行数&keyPlace=1&sort=dateDesc&qt=*
得到的数据是一个JS对象类型：{name1:value1, name2:value2, name3:[{},{},{}...]}
还发现标题长度超过DBF字符型长度限制，改用备注类型。

CREATE CURSOR 税收政策库 (title M, DOCNOVAL C(160), url C(160))
cUrl = "http://www.chinatax./api/query?siteCode=bm29000fgk&tab=all&key=9A9C42392D397C5CA6C1BF07E2E0AA6F"
wh = CREATEOBJECT("WinHttp.WinHttpRequest.5.1") 
sc = CREATEOBJECT("ScriptControl")
sc.Language = "JavaScript"
? "每页100行"+0h0D0A
UrlToTable(cUrl)
SELECT * FROM 税收政策库
CLEAR ALL 
RETURN

FUNCTION UrlToTable(cUrl)
    LOCAL nPage,cData,jsCode,i,err
    nPage = 1
    DO WHILE .T.
        cData = UrlToData(cUrl, nPage)
        cData = LOWER(cData)    && VFP解释时只认小写???
        TEXT TO jsCode TEXTMERGE NOSHOW PRETEXT 15
            var data=<<cData>>
        ENDTEXT
        err = .F.
        TRY 
            sc.AddCode(jsCode)
        CATCH
            err = .T.
        ENDTRY
        IF err
            ? "获取数据失败"
            EXIT 
        ENDIF
        IF sc.CodeObject.data.resultList.length == 0  && 没有数据
            EXIT 
        ENDIF
        FOR EACH oList IN sc.CodeObject.data.resultList
            INSERT INTO 税收政策库 VALUES (oList.title, oList.customHs.DOCNOVAL, oList.url)
        ENDFOR
        ?? "第 "+TRANSFORM(nPage)+" 页" + 0h0D
        nPage = nPage + 1
    ENDDO
ENDFUNC

FUNCTION UrlToData(cUrl, nPage)
    wh.Open("POST", cUrl, 0)
    wh.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded; charset=UTF-8")
    wh.Send("timeOption=0&page="+TRANSFORM(nPage)+"&pageSize=100&keyPlace=1&sort=dateDesc&qt=*")
    RETURN wh.ResponseText
ENDFUNC

[此贴子已经被作者于2021-9-7 17:20编辑过]

谢谢     我消化下