麻烦各位老师指点一下，红色部分不弹出窗口，是什么原因？虽然不弹出窗口，但能正常运行。

思路是预约信息（时间和预约人）提交后，
先查询库里有没有和时间重复的，如果有就弹出窗口，重新录入
如果没有，再查询库里有没有重名的，如果有就弹出窗口，重新录入
如果都没有重复的，就把提交的信息保存到数据库里。

<%
riqi=Replace(Request.Form("riqi"),"'","''")
lifashi=Replace(Request.Form("lifashi"),"'","''")
shijianduan=Replace(Request.Form("shijianduan"),"'","''")
username=Session("username")
address3 = request.servervariables("REMOTE_ADDR")      
date2=now()
set conn=server.createobject("adodb.connection")
conn.open "driver={microsoft access driver (*.mdb)};dbq="&server.mappath("ip.mdb")
    set rs = conn.execute("select * from ip where riqi=#"&riqi&"#  and shijianduan like '%"&shijianduan&"%' and lifashi like '%"&lifashi&"%'")
     if not rs.eof then
         Response.Write "<script>alert('该时间段已被预约！请约其他时间段！');window.window.location.href='main.asp';</script>"
                 rs.close:set rs = nothing
else
set rs1 = conn.execute("select * from ip where riqi=#"&riqi&"#  and username like '%"&username&"%' and username not like '星辉' and username not like '戈松'")
     if not rs1.eof then

         Response.Write "<script>alert('一天只能预约一次！请先取消今天的预约');window.window.location.href='main.asp';</script>"


                 rs1.close:set rs1 = nothing
         else        
         sql="insert into ip (address3,date2,shijianduan,lifashi,riqi,username,mobile,bumen)values('"&address3&"','"&date2&"','"&shijianduan&"','"&lifashi&"','"&riqi&"','"&Session("username")&"','"&session("mobile")&"','"&session("bumen")&"')"
         conn.execute sql
         conn.close
End If
response.Redirect("main.asp")
rs.close:set rs = nothing
conn.Close:set conn = nothing
End If
%>

没有老师帮忙看一下吗🙏🙏🙏

<%
sub conn_open(conn,path)
    set conn=server.createobject("adodb.connection")
    conn.connectionstring="Provider = Microsoft.Jet.OLEDB.4.0;Data Source="&server.mappath(path)
    conn.open
end sub
sub conn_close(conn)
    conn.close
    set conn=nothing
end sub
sub rs_open1(rs,sql)
    set rs = server.createobject("adodb.recordset")
    rs.open sql,conn,1,1
end sub
sub rs_open3(rs,sql)
    set rs = server.createobject("adodb.recordset")
    rs.open sql,conn,1,3
end sub
sub rs_close(rs)
    rs.close
    set rs=nothing
end sub
sub goback(str)
    response.write "<script>alert("""&str&""");window.history.back();</script>"
end sub
%>
<!----------------------------------------------------------------------------------------------------------->
<%
riqi=Replace(Request.Form("riqi"),"'","''")
lifashi=Replace(Request.Form("lifashi"),"'","''")
shijianduan=Replace(Request.Form("shijianduan"),"'","''")
username=Session("username")
address3 = request.servervariables("REMOTE_ADDR")      
date2=now()

if address3<>"" and date2<>"" and shijianduan<>"" and lifashi<>"" and riqi<>"" and Session("username")<>"" and  session("mobile")<>"" and session("bumen")<>"" then
'必须所有数据不能为空，然后才开始搞，如果有数据为空，说明不完整，返回历史重新搞。
'1，判断用户选择的理发师在用户选择的那个时段是否已经预约，如果已经预约说明不能继续预约这个时段的这个理发师。
    call conn_open(conn,"ip.mdb")
    sql="select * from ip where shijianduan="&""""&shijianduan&""""&" and lifashi="&""""&lifashi&""""
    call rs_open1(rs,sql)
    if not rs.eof and not rs.bof then
        call rs_close(rs)
        call conn_close(conn)
        call goback("该时间段已被预约！请约其他时间段！")
        response.end
    end if
    call rs_close(rs)
'2，判断是否重复预约。
    sql="select * from ip where username="&""""&username&""""&" and riqi="&""""&riqi&""""
    call rs_open1(rs,sql)
    if not rs.eof and not rs.bof then
        call rs_close(rs)
        call conn_close(conn)
        call goback("一天只能预约一次！请先取消今天的预约")
        response.end
    end if
    call rs_close(rs)
'时段判断完毕，用户名当天是否重复预约判断完毕。下面就是正式录入数据资料。
    sql="select * from ip"
    call rs_open3(rs,sql)
        rs.addnew
            rs("address3")=address3
            rs("date2")=date2
            rs("shijianduan")=shijianduan
            rs("lifashi")=lifashi
            rs("riqi")=riqi
            rs("username")=Session("username")
            rs("mobile")=session("mobile")
            rs("bumen")=session("bumen")
        rs.update
    call rs_close(rs)
    call conn_close(conn)
    call tt("预约成功！","main.asp")
    response.end
else
    call goback("内容提交不完整，请重新输入")
end if
%>
<!--不知道你的access里面的字段都是什么类型。以上字段全部都是长文本类型。-->

[此贴子已经被作者于2021-2-16 21:35编辑过]

为什么是window.window.location.href='main.asp"
我一般写成location.href='xxx.asp';