请问哪位有数量化理论运算程序，或者能帮忙看看的，先谢了。
我因为毕业论文需要用数量化理论进行计算，但没有相应的计算程序，只找到很老的用BASIC语言编写的一段源代码，功能也不够齐全，所以来到此地求助各位高手，谁有数量化理论的计算程序，或者懂这方面的知识，能够帮一把的，小弟我感激不尽啊！
我的QQ是：41687816
下面是数量化理论1的BASIC程序：
（缺点：不能在WINDOWS下很好运行，当自变量太多时不能运算出结果；目的：用另外的语言进行编写，或者在此基础上修改完善。）

10 SCREEN 2,O
12 PRINT "多对多数量化模型 I 名:BSLHX"
14 PRINT " 本程序用于多个自变量对多个因变量的回归分析(即多对多), 其中自变量可以是定性的,亦可以是定量的,或两者兼有的回归模型"
16 PRINT "注意:对定性因子,程序删除最后 1 个级别"
20 INPUT "数据文件名";DA$
21 INPUT "样本数=",N
22 OPEN "I",1,DA$
23 INPUT "定性的自变量因子数=";P1
24 INPUT "定量的自变量因子数=";P2
25 INPUT "定量的因变量因子数=";Q
26 NI=P1+P2:NK=NI+Q
27 DIM CK(NK),ND(NI),XR(NI+1,NI+1)
28 FOR I=1 TO P1
30 PRINT TAB(4)"第(";I;")定性因子的等级数=";
32 INPUT ND(I):ND(I)=ND(I)-1
34 NEXT I
38 FOR I=1 TO P2
40 ND(P1+I)=1:NEXT I
42 NI=P1+P2:P=0
44 FOR I=1 TO NI
46 P=P+ND(I)
48 NEXT I
54 DIM X(P+Q),U(P+Q),V(P+Q),W(P+Q),C(P+Q,P+Q),B(P,Q)
90 FOR L=1 TO N
96 FOR I=1 TO P
98 X(I)=0:NEXT I
100 FOR I1=1 TO NI
106 INPUT #1,CK(I1)
110 IF I1<=P1 AND CK(I1)>ND(I1) THEN 126
112 IF I1<=P1 THEN J1=CK(I1) ELSE J1=1
114 II=0
116 FOR J=1 TO I1-1
118 II=II+ND(J)
120 NEXT J
122 II=II+J1
124 IF I1<=P1 THEN LET X(II)=1 ELSE LET X(II)=CK(I1)
126 NEXT I1
128 X(0)=1
130 FOR I=1 TO Q
132 INPUT #1,X(P+I):NEXT I
134 FOR J=0 TO P+Q
136 FOR K=0 TO P+Q
138 C(J,K)=C(J,K)+X(J)*X(K):NEXT K
140 V(J)=V(J)+X(J)
142 NEXT J
146 NEXT L
150 CLOSE #1
160 WIDTH "LPT1:",78
240 print TAB(25)"****正规方程*******"
242 print TAB(12)"--- 系数矩阵 --- ---- 右端项 ---"
250 FOR I=0 TO P
260 FOR J=0 TO P+Q
270 print USING "#########.###";C(I,J);
280 NEXT J
290 print ""
295 NEXT I
310 FOR I=0 TO P+Q
320 U(I)=0:V(I)=0:NEXT I
330 N0=0:N9=P:E2=9.999999E-21:GOSUB 800
340 print TAB(8)"*** 回归系数 ****"
350 print " 系数 ";
360 FOR K=1 TO Q
362 print "Y(";K;") ";
370 FOR I=0 TO P
380 FOR J=0 TO P
390 B(I,K)=B(I,K)+C(I,J)*C(J,P+K):NEXT J:NEXT I
400 NEXT K:print " "
402 print "B( 0 )=";:FOR K=1 TO Q:print USING "########.#####";B(0,K);:NEXT K:print " "
403 II=0
404 FOR I=1 TO P1
405 FOR J=1 TO ND(I)
406 print "B("+MID$(STR$(I),2)+"-"+MID$(STR$(J),2)+")=";:II=II+1
407 FOR K=1 TO Q
408 print USING "########.#####";B(II,K);
409 NEXT K:print " ":NEXT J
410 print "B("+MID$(STR$(I),2)+"-"+MID$(STR$(ND(I)+1),2)+")=";
411 FOR K=1 TO Q:print USING "########.#####";0;:NEXT K:print " "
412 NEXT I
413 FOR I=1 TO P2
414 print "B(";NI-P2+I;")=";:II=II+1
415 FOR K=1 TO Q:print USING "########.#####";B(II,K);:NEXT K:print " ":NEXT I
416 FOR WA=1 TO Q
417 print TAB(8) "**** X.. 对 Y(";WA;")的相关分析****"
418 OPEN "I",#1,DA$
419 FOR I=0 TO NI+1
420 FOR J=0 TO NI+1
421 XR(I,J)=0:NEXT J
422 V(I)=0:NEXT I
423 FOR L=1 TO N
424 FOR I=1 TO NK
426 INPUT #1,CK(I)
428 X(I)=0:NEXT I
430 R1=0
431 FOR I=1 TO NI
433 IF I<=P1 AND CK(I)>ND(I) THEN 437
434 IF I<=P1 THEN X(I)=X(I)+B(R1+CK(I),WA):GOTO 437
435 X(I)=X(I)+CK(I)
437 R1=R1+ND(I)
438 NEXT I
440 X(0)=1
442 X(NI+1)=CK(NI+WA)
444 FOR I=0 TO NI+1
446 FOR J=0 TO NI+1
448 XR(I,J)=XR(I,J)+X(I)*X(J):NEXT J
450 V(I)=V(I)+X(I)
452 NEXT I
454 NEXT L:CLOSE #1
456 FOR J=1 TO NI+1
458 FOR K=1 TO NI+1
460 XR(J,K)=XR(J,K)/N-V(J)*V(K)/N/N
462 NEXT K:NEXT J
463 QQ=XR(NI+1,NI+1)
464 print TAB(12)"-----相关矩阵------"
466 print " "
468 FOR J=1 TO NI+1
470 FOR K=1 TO NI+1
472 C(J,K)=XR(J,K)/SQR(XR(J,J)*XR(K,K))
474 print USING "####.####";C(J,K);
476 NEXT K:print " "
478 NEXT J :print " "
480 FOR I=0 TO NI+1
482 U(I)=0:V(I)=0:W(I)=0:NEXT I
484 N9=NI+1:N0=1:GOSUB 800
486 print TAB(12)"----偏相关系数-----"
488 print " "
490 FOR I=1 TO NI
492 RP=-C(I,NI+1)/SQR(C(I,I)*C(NI+1,NI+1))
494 print "X(";I;")=";RP
496 NEXT I:print " "
498 RR=SQR(1-1/C(NI+1,NI+1))
500 print "Y-方差=";QQ;" 剩余方差=";QQ*(1-RR*RR);
501 print "复相关系数=";RR:print " "
502 NEXT WA
504 END
800 REM 最大主元消去法求逆
802 D9=1
804 FOR J=N0 TO N9
806 W(J)=J:NEXT J
808 FOR I=N0 TO N9
810 K=I:Y9=C(I,I)
812 FOR J=I TO N9
814 IF I=J THEN 820
816 IF ABS (C(I,J))<=ABS (Y9) GOTO 820
818 K=J:Y9=C(I,J)
820 NEXT J
822 D9=D9*Y9
824 IF ABS (Y9)<=E2 GOTO 894
826 Y9=1/Y9
828 FOR J=N0 TO N9
830 V(J)=C(J,K)
832 C(J,K)=C(J,I)
834 C(J,I)=-V(J)*Y9
836 U(J)=C(I,J)*Y9
838 C(I,J)=U(J)
840 NEXT J
842 C(I,I)=Y9
844 J9=W(I)
846 W(I)=W(K):W(K)=J9
848 FOR K=N0 TO N9
850 FOR J=N0 TO N9
852 IF K=I GOTO 860
854 IF J=I GOTO 858
856 C(K,J)=C(K,J)-U(J)*V(K)
858 NEXT J
860 NEXT K
862 NEXT I
864 FOR I=N0 TO N9
866 K=W(I)
868 IF K=I GOTO 890
870 FOR J=N0 TO N9
872 J9=C(I,J)
874 C(I,J)=C(K,J)
876 C(K,J)=J9
878 NEXT J
880 T9=W(I)
882 W(I)=W(K)
884 W(K)=T9
886 D9=-D9
888 GOTO 866
890 NEXT I
892 GOTO 898
894 print "最大主元素 <1E-20"
896 STOP
898 RETURN