VFP如何读取OFFICE 2010版本里的excel表格里的数据
在OFFICE低版本里，可以打开 ，但是在2010以后，就无法使用了，谁有经验，分享一下

     oleapp=CREATEOBJECT("Excel.application")
     oleapp.workbooks.open("C:\库存资料.XLS")
     I=2   
     II=1
       WAIT "正在导入数据:"+ALLT(STR(II)) WINDOWS NOWAIT
      **************编码 ***************************
       BM=oleapp.cells(I,1).VALUE

现在用不了，请高手指导下

给个XLS文件看看

TKS

Win10 + EXCEL2007 未见异常

oleapp=CREATEOBJECT("Excel.application")
oleapp.workbooks.open("C:\TEMP\库存资料\库存资料.xls")
FOR i=1 TO oleapp.ActiveSheet.UsedRange.Rows.Count
    ?
    FOR ii=1 TO oleapp.ActiveSheet.UsedRange.Columns.Count
        WAIT "正在导入数据:"+ALLT(STR(II)) WINDOWS NOWAIT
        IF VARTYPE(oleapp.Cells[i,ii].Value)=="N"
            ?? " ",PADR(TRANSFORM(oleapp.Cells[i,ii].Value,"###.##"),6," ")
        ELSE
            ?? " ",PADR(oleapp.Cells[i,ii].Value,6," ")
        ENDIF
    ENDFOR
ENDFOR
oleapp.WorkBooks.Close
oleapp.Quit
CLEAR ALL

谢谢，是用2010打开的吗，PADR是个什么函数，没用过。非常感谢

测试用EXCEL2007，PADR()是显示格式用的。
如果是EXCEL版本问题，可试试用ADO获取EXCEL表数据，如：

SET DEFAULT TO ADDBS(JUSTPATH(SYS(16)))                 
CLEAR
SET SAFETY OFF
cExcel = "C:\TEMP\库存资料\库存资料.xls"
cHDR = "YES"   
cSheet = "[Sheet1$A:R]"
cSQL = "SELECT * FROM " + cSheet
cConn = "Provider=Microsoft.ACE.OLEDB.12.0;";
        + "Extended Properties='Excel 12.0;HDR="+cHDR+";IMEX=1';";
        + "Data Source=" + cExcel
**    * EXCEL2003及之前版本
**    cConn = "Provider=Microsoft.Jet.OLEDB.4.0;";
**           + "Extended Properties='Excel 8.0;HDR="+cHDR+";IMEX=1';";
**           + "Data Source=" + cExcel
oConn = CREATEOBJECT("ADODB.Connection")
oConn.Open(cConn)
oRs = CREATEOBJECT("ADODB.Recordset")
oRs.Open(cSQL, oConn, 1, 3, 1)
oRs.MoveFirst
CREATE CURSOR tt (编码 C(6),名称 C(10),车型 C(10),数量 I,单位 C(2),成本价 N(6,2),;
    销售价 N(6,2),批发价 N(6,2),产地 C(4),备注 C(6),免税价 N(6,2),仓位 C(2),;
    编码一 C(4),编码二 C(4),分类 C(4),规格 C(4),供应商 C(4),最低库存 N(6,2))
cStr = oRs.GetString()
STRTOFILE(cStr, "tmp.txt")
SELECT tt
APPEND FROM tmp.txt DELIMITED WITH TAB
SELECT * FROM tt
oRs.Close
oConn.Close
CLEAR ALL
RETURN

[此贴子已经被作者于2020-3-8 11:08编辑过]

好久没用VFP操作EXCEL

非常感谢，我试试，多学了好多东西

有可能是你的office2010安装有问题，重新完全安装一下。我曾遇到过

重装一下，有些能解决