CREATE CURSOR T (A N(2),B N(2))
FOR I=1 TO 10
    INSERT INTO T (A) VALUES (I)
ENDFOR
SELECT A,RECNO()+1 JLH FROM T WHERE RECNO()<RECCOUNT() INTO CURSOR TT
SCAN
   UPDATE T SET B=A-TT.A WHERE RECNO([T])=TT.JLH
ENDSCAN
SELECT T
BROWSE

表记录超15万，这样处理太慢了，添加到数组下标也超限了，在线求解？

没说清楚
是不是下一记录减上一记录：

CREATE CURSOR T (A I, B I)
FOR I=1 TO 100000
    INSERT INTO T (A) VALUES (I*3%7)
ENDFOR
GO TOP
nA = T.A
REPLACE T.B WITH fun() ALL IN "T"
GO TOP
BROWSE
RETURN

FUNCTION fun()
    LOCAL nB
    nB = T.A - nA
    nA = T.A
    RETURN nB
ENDFUNC

CREATE CURSOR T (A I, B I)
FOR I=1 TO 5000000
    INSERT INTO T (A) VALUES (I * 3 % 9)
ENDFOR
COPY TO ARRAY aa FIELDS a
SCAN FOR RECNO() > 1
    REPLACE b WITH a - aa[RECNO() - 1]
ENDSCAN
BROWSE

CREATE  cursor T (A I, B I)
FOR I=1 TO 150000
    INSERT INTO T (A) VALUES (I+INT(i*RAND()))
ENDFOR
REPLACE b WITH RECNO() all
SELECT a ,b FROM t INTO CURSOR tt WHERE RECNO()>1 READWRITE 
SELECT tt
REPLACE b WITH RECNO() all
SELECT a.a,b.b FROM t a LEFT JOIN tt b ON a.b=b.b INTO CURSOR t3 READWRITE 
REPLACE b WITH a-b all

最后一条记录，根据你自已想法单独处理一下就可以了，结果在 t3 中。
时间没到2秒。

150000条记录用2秒可能慢了点
优化一下，破机器上15W条记录0.2秒，试试。
CREATE CURSOR T (A I, B I)
FOR I=1 TO 150000
    INSERT INTO T (A) VALUES (I+INT(i*RAND()))
ENDFOR
GO TOP
t1 = SECONDS()
nA = T.A
nB = 0
REPLACE T.B WITH fun() ALL IN "T"
? SECONDS() - t1
GO TOP
BROWSE
RETURN

FUNCTION fun()
    nB = T.A - nA
    nA = T.A
    RETURN nB
ENDFUNC

都是高手！