怎样提取一个不太规则的TXT文件里的信息到规定格式的数据表文件里的数据？

CLOSE DATABASES 
USE 考生成绩 IN 0
ZAP 
CREATE CURSOR tt (cName C(254))
APPEND FROM 考试成绩.TXT SDF 
SELECT cName FROM tt WHERE NOT EMPTY(cName) INTO CURSOR tt
SELECT cName FROM tt WHERE INLIST(RECNO()%12, 3, 5, 6, 7, 8, 9) INTO CURSOR tt
FOR i =1 TO _Tally/6 
    COPY TO ARRAY a_6 FOR BETWEEN(RECNO(), (i - 1)*6 + 1, i*6)
    nRows = OCCURS("准考证号:",a_6[1])
    LOCAL aCj[nRows, 8]
    FOR ii = 1 TO 6
        DO CASE 
            CASE "准考证号:"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "准考证号:", "姓名:")
                FOR iii = 1 TO nRows
                    nRow = CEILING(iii/2)
                    IF iii%2 = 1
                        aCj[nRow, 1] = aName[iii]
                    ELSE
                        aCj[nRow, 2] = aName[iii]
                    ENDIF 
                ENDFOR
            CASE "语    文"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "语    文")
                FOR iii = 1 TO nRows
                    aCj[iii, 3] = VAL(aName[iii])
                ENDFOR
            CASE "数    学"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "数    学")
                FOR iii = 1 TO nRows
                    aCj[iii, 4] = VAL(aName[iii])
                ENDFOR
            CASE "外    语"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "外    语")
                FOR iii = 1 TO nRows
                    aCj[iii, 5] = VAL(aName[iii])
                ENDFOR
            CASE "综合"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "综合")
                FOR iii = 2 TO nRows
                    aCj[iii-1, 6] = VAL(aName[iii])
                ENDFOR
            CASE "量化成绩"$a_6[ii]
                nRows = ALINES(aName, a_6[ii], 1+4, "量化成绩", "总成绩")
                FOR iii = 1 TO nRows
                    nRow = CEILING(iii/2)
                    IF iii%2 = 1
                        aCj[nRow, 7] = VAL(aName[iii])
                    ELSE
                        aCj[nRow, 8] = aName[iii]
                    ENDIF 
                ENDFOR
        ENDCASE 
    ENDFOR 
    INSERT INTO 考生成绩 FROM ARRAY aCj
ENDFOR 
SELECT 考生成绩
BROWSE 

谢谢，程序可行，运行速度快！

看了摇头！数据的来源本身存在很大问题。
估计也就是二楼的朋友回应了你啊。

俗话说：只有想不到，没有做不到。主要是一般人所下的功夫不到，所付出的不多，所以水平达不到。二楼的朋友所付出的功夫不是一般人所能达到的，所以水平也让一般人难望其项背。我虽然也做了一个，也勉强能达到要求，但是思路跟他的相比，却甩出几十条街。他的程序看后让人有醍醐灌顶之感，再次表示感谢！

高！