怎么把“3号休假，4号休假，5号休假，6号休假，10号休假”变成“3-6号休假，10号休假”。
每月日期不固定，把连续的天数用“－”连接。
谢谢！！

先说说“3号休假，4号休假，5号休假，6号休假，10号休假”这串是怎样产生的

一个每月休假情况表，字段：姓名，A1，A2......A31(月天数）

姓名  A1    A2    A3    A4      A5   ......
张三             休假   休假     休假

已处理成：张三  3号休假，4号休假，5号休假，6号休假，10号休假

现想直接打印成：张三： 3-6号休假，10号休假

谢谢关注！！

直接从“休假情况表”生成就可以，不用转来转去。
如：A2、A3、A4字段值为休假则是：2-4号休假，A6、A8字段值为休假则是：6号休假，8号休假

上传相关数据表

ＶＦＰ９环境下运行：

CLOSE DATABASES 
CREATE CURSOR Temp (nValue N(2))
USE Jia IN 0
SELECT Jia
SCAN 
    ZAP IN Temp
    FOR i = 3 TO FCOUNT()
        IF NOT EMPTY(EVALUATE(FIELD(i)))
            INSERT INTO Temp VALUES (VAL(SUBSTR(FIELD(i, "Jia"), 2)))
        ENDIF 
    ENDFOR
    SELECT MIN(nValue) nMin, ;
        MAX(nValue) nMax, nId, ;
        IIF(MIN(nValue) = MAX(nValue), ;
        TRANSFORM(MIN(nValue)), ;
        TRANSFORM(MIN(nValue)) + "-" + TRANSFORM(MAX(nValue))) + "号休假" + SPACE(10) 结果 ;
        FROM (SELECT nValue, nValue - RECNO() nId FROM Temp) cA GROUP BY nId
ENDSCAN
USE IN Temp

jia表好象少了一个a11字段，先补上测试

USE jia
SCAN
    SCATTER TO arr
    ? arr[1], arr[2], " "
    n开始 = 0
    n结束 = 0
    FOR i=3 TO ALEN(arr)
        IF !EMPTY(arr[i])
            IF n开始 > 0
                IF i > n结束+1
                    ?? TRANSFORM(n开始-2)+IIF(n开始<n结束,"-"+TRANSFORM(n结束-2),"")+"号休假", " "
                    n开始 = i
                    n结束 = i
                ELSE
                    n结束 = i
                ENDIF
            ELSE
                n开始 = i
                n结束 = i
            ENDIF
        ENDIF
    ENDFOR
    IF n开始 > 0
        ?? TRANSFORM(n开始-2)+IIF(n开始<n结束,"-"+TRANSFORM(n结束-2),"")+"号休假", " "
    ENDIF
ENDSCAN

[此贴子已经被作者于2018-10-11 08:29编辑过]