图有几个列表，我想统计各列表字段“每个数值“有多少个，
比如第一个字段里，3有多少个？？1有多少个，
第二字段，3 有多少个，2有多少个，
sele 怎么写？？
请帮帮，，谢谢了。。

select xz1,count(xz1) as SumXz1,xz2,count(xz2) as SumXz2,xz3,count(xz3) as SumXz3 from 你表名称 group by xz1,xz2,xz3
brow
如果要保存到表上，就这样
select xz1,count(xz1) as SumXz1,xz2,count(xz2) as SumXz2,xz3,count(xz3) as SumXz3 from 你表名称 group by xz1,xz2,xz3 into table d:\你表名称_统计

没有数据无法写代码

[此贴子已经被作者于2018-8-31 19:14编辑过]

贴图能快速解决问题吗

统计结果见下图

分数段表是需要的样式，表里的分0，分1，分2，。。。。。。等等对应DBF表里的各段值，
sx.dbf 是数据表，
按照上位那位高人的指点，结果不理想，
请帮忙。谢谢。

只有 0 --- 9 ，可用数组累计，再 GATHER FROM array

CREATE CURSOR 分数段表 (分0 I,分1 I,分2 I,分3 I,分4 I,分5 I,分6 I,分7 I,分8 I,分9 I,参考人数 I,实考人数 I,题名 C(10))
USE sx ALIAS sx IN 0
SELECT sx
nCount = FCOUNT()
DIMENSION arr[nCount,13]
FOR i=1 TO nCount
    FOR j=1 TO 12
        arr[i,j] = 0
    ENDFOR
    arr[i,13] = FIELD(i)
ENDFOR
SCAN
    FOR i=1 TO nCount
        j = VAL(EVALUATE(arr[i,13])) + 1
        arr[i,j] = arr[i,j] + 1
    ENDFOR
ENDSCAN
SELECT 分数段表
APPEND FROM ARRAY arr
SELECT * FROM 分数段表

CLOSE DATABASES ALL
Start_Time=SECONDS()
cField="题名 C(10),应考人数 N(6),实考人数 N(6)"
FOR i=0 To 9
    cField=cField+",F"+STR(i,1)+" N(6)"
ENDFOR
CREATE CURSOR Data_Stat (&cField)
LOCAL ArrayCnt[1,FCOUNT()]
ArrayCnt=0
USE Sx IN 0
SELECT Sx
FOR i=1 TO FCOUNT()
    ArrayCnt[1,1]=FIELD(i)
    ArrayCnt[1,3]=RECCOUNT()
    SCAN
        ArrayCnt[1,VAL(EVALUATE(FIELD(i)))+1+3]=ArrayCnt[1,VAL(EVALUATE(FIELD(i)))+1+3]+1
    ENDSCAN
    INSERT INTO Data_Stat FROM ARRAY ArrayCnt
    ArrayCnt=0
ENDFOR
MESSAGEBOX(TRANSFORM(SECONDS()-Start_Time,"9.999"))
SELECT Data_Stat
FOR i=2 TO FCOUNT()
    BLANK FIELDS (FIELD(I)) FOR EVALUATE(FIELD(I))=0
ENDFOR
GO TOP
BROWSE