一表M中有a,b,c，d,e,f共6个字段，如何再新增一字段N，其值为a,b,c，d,e,f字段中值<10的个数？

用Min函数可搞定

看错了，以为是找到最小值。

给点数据看看

一表M中有a,b,c，d,e,f共6个字段，如何再新增一字段N，其值为a,b,c，d,e,f字段中值<10的个数？
表M如下：
a b c d e f
01 05 10 15 20 21
02 08 14 21 28 33
03 06 07 11 19 22

增加字段N后:
a b c d e f N
01 05 10 15 20 21 2
02 08 14 21 28 33 2
03 06 07 11 19 22 3

CREATE CURSOR tt (a I, b I, c I, d I, e I, f I)
INSERT INTO tt VALUES (01, 05, 10, 15, 20, 21)
INSERT INTO tt VALUES (02, 08, 14, 21, 28, 33)
INSERT INTO tt VALUES (03, 06, 07, 11, 19, 22)
SELECT *, _calc("tt") as N FROM tt

FUNCTION _calc(cAlias)
    LOCAL i, n
    n = 0
    FOR i=1 TO FCOUNT(cAlias)
        IF EVALUATE(FIELD(i,cAlias)) < 10
            n = n + 1
        ENDIF
    ENDFOR
    RETURN n
ENDFUNC

CREATE CURSOR tt (a C(2), b C(2), c C(2), d C(2), e C(2), f C(2),NN N(1))
INSERT INTO tt VALUES ("01", "05", "10", "15", "20", "21",0)
SCAN
    N1=0
    FOR I=1 TO FCOUNT()-1
        IF BETWEEN(EVALUATE(FIELD(I)),"01","09")
            N1=N1+1
        ENDIF
    ENDFOR
    REPLACE NN WITH N1
ENDSCAN
BROWSE

以上2位斑竹,1个用的是数值字段,1个用的是字符字段...

双色球数据常规情况下是用字符字段的，因为最大数为33，不足两位的要补 0

Create Cursor tt (a C(2), b C(2), c C(2), d C(2), e C(2), f C(2))
Insert Into tt Values ("01", "05", "10","15","20","21")
Insert Into tt Values ("02","08","14","21","28","33")
Insert Into tt Values ("03","06","07","11","19","22")
Select *,Iif(Val(a)<10,1,0)+Iif(Val(b)<10,1,0)+Iif(Val(c)<10,1,0)+Iif(Val(d)<10,1,0)+Iif(Val(e)<10,1,0)+Iif(Val(f)<10,1,0) As N From tt