如题，我在命令按钮的click事件里修改了控件的属性（caption的内容），但是，退出（release thisform）该表单后，重新打开，该控件的属性还是原来的内容。我该怎么保存修改后的控件属性呢？

运行时，修改时改变的是内存数据，关闭应用后就释放了。
或者想想怎样做，关闭应用程序后，再重新运行时，打开表单时的状态是之前关闭前的状态。也就是说，怎样保存表单的某些数据，需要时可恢复使用这些数据。

难道要创建一个数据库表，修改后，把数据填入表，运行时再把表数据修改到属性中？

是的，代码运行在内存，数据保存在外存。

直接在属性窗口修改caption就可以了

用注册表记住,程序装载时恢复

如何用注册表记住？

用DBF也可以，更方便操作。

我的方法如下:
1,在Destroy事件中记入注册表
#DEFINE HKEY_CLASSES_ROOT 2147483648 && 0x80000000，或用负数: -2147483648
#DEFINE HKEY_CURRENT_USER 2147483649 && 0x80000001，-2147483647
#DEFINE HKEY_LOCAL_MACHINE 2147483650 && 0x80000002，-2147483646
#DEFINE HKEY_USERS 2147483651 && 0x80000003，-2147483645
#DEFINE HKEY_PERFORMANCE_DATA 2147483652 && 0x80000004，-2147483644
#DEFINE HKEY_CURRENT_CONFIG 2147483653 && 0x80000005，-2147483643
#DEFINE HKEY_DYN_DATA 2147483654 && 0x80000006，-2147483642
cMyRegPath    =    "Software\VFP\"+JUSTSTEM(SYS(1271,THIS))
THIS.串口控制.Registry.Setregkey("Top",ALLTRIM(STR(THIS.Top)),cMyRegPath,HKEY_CURRENT_USER,.T.)
THIS.串口控制.Registry.Setregkey("Left",ALLTRIM(STR(THIS.Left)),cMyRegPath,HKEY_CURRENT_USER,.T.)
THIS.串口控制.Registry.Setregkey("记录时长",ALLTRIM(STR(THIS.串口控制.记录时长)),cMyRegPath,HKEY_CURRENT_USER,.T.)
IF !EMPTY(THIS.串口控制.可用串口.Value)
    THIS.串口控制.Registry.Setregkey("最后串口",THIS.串口控制.可用串口.Value,cMyRegPath,HKEY_CURRENT_USER,.T.)
ENDIF
IF !EMPTY(THIS.串口控制.位置_nmea)
    THIS.串口控制.Registry.Setregkey("Path_Nmea",THIS.串口控制.位置_nmea,cMyRegPath,HKEY_CURRENT_USER,.T.)
ENDIF

2,在Iint事件中恢复
#DEFINE HKEY_CLASSES_ROOT 2147483648 && 0x80000000，或用负数: -2147483648
#DEFINE HKEY_CURRENT_USER 2147483649 && 0x80000001，-2147483647
#DEFINE HKEY_LOCAL_MACHINE 2147483650 && 0x80000002，-2147483646
#DEFINE HKEY_USERS 2147483651 && 0x80000003，-2147483645
#DEFINE HKEY_PERFORMANCE_DATA 2147483652 && 0x80000004，-2147483644
#DEFINE HKEY_CURRENT_CONFIG 2147483653 && 0x80000005，-2147483643
#DEFINE HKEY_DYN_DATA 2147483654 && 0x80000006，-2147483642

*!*    注册表位置
cMyRegPath    =    "Software\VFP\"+JUSTSTEM(SYS(1271,THIS))
*!*    设置用户窗口位置顶部
cTop    =    ""
THIS.串口控制.Registry.GetRegKey("Top",@cTop,cMyRegPath,HKEY_CURRENT_USER)
IF ISDIGIT(cTop)
    THIS.Top    =    VAL(cTop)
ENDIF
*!*    设置用户窗口位置左边
cLeft    =    ""
THIS.串口控制.Registry.GetRegKey("Left",@cLeft,cMyRegPath,HKEY_CURRENT_USER)
IF ISDIGIT(cLeft)
    THIS.Left    =    VAL(cLeft)
ENDIF
*!*    设置用户原定记录时长
记录时长    =    ""
THIS.串口控制.Registry.GetRegKey("记录时长",@记录时长,cMyRegPath,HKEY_CURRENT_USER)
IF ISDIGIT(记录时长)
    THIS.串口控制.记录时长    =    INT(VAL(记录时长))
    THIS.串口控制.时长.Comment    =    记录时长
ENDIF
*!*    设置用户最后使用的串口
最后串口    =    ""
THIS.串口控制.Registry.GetRegKey("最后串口",@最后串口,cMyRegPath,HKEY_CURRENT_USER)
IF !EMPTY(最后串口)
    THIS.串口控制.可用串口.Comment    =    最后串口
ENDIF
*!*    设置文件存放位置
Path_Nmea    =    ""
THIS.串口控制.Registry.GetRegKey("Path_Nmea",@Path_Nmea,cMyRegPath,HKEY_CURRENT_USER)
IF !EMPTY(Path_Nmea)
    THIS.串口控制.位置_nmea    =    ADDBS(Path_Nmea)
ENDIF

3,注册表位置:
HKEY_CURRENT_USER\Software\VFP\gps仪表