请老师指点 我在网上找的下面这段代码怎么使用
Function saveimage2(openfile as String,savefile as string)
lqEncoderClsID_BMP=0h00F47C55041AD3119A730000F81EF32E &&BMP
lqEncoderClsID_JPG=0h01F47C55041AD3119A730000F81EF32E &&JPG
lqEncoderClsID_GIF=0h02F47C55041AD3119A730000F81EF32E &&GIF
lqEncoderClsID_TIF=0h05F47C55041AD3119A730000F81EF32E &&TIF
lqEncoderClsID_PNG=0h06F47C55041AD3119A730000F81EF32E &&PNG
DECLARE Long GdipLoadImageFromFile IN Gdiplus.dll String cFile, Long @ nativeImage
DECLARE Long GdipSaveImageToFile IN Gdiplus.dll Long nativeImage, String cFile, ;
         String EncoderClsID, String EncoderParameters
DECLARE Long GdipDisposeImage IN Gdiplus.dll Long nativeImage
lcInputFile=STRCONV(openfile+CHR(0),5)
lcOutputFile=STRCONV(savefile+CHR(0),5)
lnImage=0
GdipLoadImageFromFile(lcInputFile,@lnImage)
GdipSaveImageToFile(lnImage, lcOutputFile, EVALUATE('lqEncoderClsID_'+UPPER(JUSTEXT(savefile))), NULL)
GdipDisposeImage(lnImage)
ERASE &openfile
Endfunc

简单示例：
DECLARE LONG GdipLoadImageFromFile IN Gdiplus.dll STRING@, LONG@
DECLARE LONG GdipSaveImageToFile IN Gdiplus.dll LONG, STRING@, STRING@, STRING@
DECLARE LONG GdipDisposeImage IN Gdiplus.dll LONG

inFile  = "C:\TEMP\test.bmp"
outFile = "C:\TEMP\test.jpg"
*outFile = "C:\TEMP\test.gif"
*outFile = "C:\TEMP\test.tif"
*outFile = "C:\TEMP\test.png"
IF _tran(inFile, outFile)
    of = CREATEOBJECT("form")
    of.caption = outFile
    of.addobject("image1", "image")
    of.image1.picture = outFile
    of.image1.visible = .T.
    of.show(1)
ENDIF
RETURN

FUNCTION _tran(inFile, outFile)
    LOCAL hBitmap
    hBitmap = 0
    GdipLoadImageFromFile(STRCONV(inFile+0h00,5), @hBitmap)
    IF hBitmap < 1
        MESSAGEBOX("载入图片 " + inFile + " 失败", "提示")
        RETURN .F.
    ENDIF
    LOCAL cExtName, CLSID
    cExtName = LOWER(JUSTEXT(outFile))
    cCLSID = ICASE(;
        cExtName=="jpg", 0h01,;
        cExtName=="gif", 0h02, ;
        cExtName=="tif", 0h05, ;
        cExtName=="png", 0h06,;
        0h00) + 0hF47C55041AD3119A730000F81EF32E
    GdipSaveImageToFile(hBitmap, STRCONV(outFile+0h00,5), cCLSID, NULL)
    GdipDisposeImage(hBitmap)
    RETURN .T.
ENDFUNC

@吹版，学习啦，谢谢！