VFP  GRID滚动条拖到低部时在数据尾部时多出许多空白行，怎么不显示这些空白?

GRID好象是保留有空白区，因在编辑状态下，空白区才能响应GRID的一些事件。这一点有点象Windows的窗口事件，如一些鼠标右键菜单只能在空白区点击才有效。

GRID好象没有设置空白区的属性和方法。
有需要的可以自己写代码去处理。
思路：
1、获取表格行数、检测最底行是否空白区。参考GridHitTest方法，要确定或计算底行空白区检测点（x,y）。
2、确定顶行显示的数据记录号n。参考RECCOUNT()和表格行数。
3、将n记录自动显示在顶行。参考ActivateCell和DoScroll方法。
注意：
某些事件（如滚动条事件Scrolled）可能要用异步消息来处理。
自定义一个消息号（如：0x401）并绑定一个自定义方法（如：_BlankRows）：
DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG

    PROCEDURE init
        BINDEVENT(this.hWnd, 0x401, this, "_BlankRows")
    ENDPROC

    FUNCTION _BlankRows(hWnd, Msg, wParam, lParam)
        ** 在这时处理空白行问题
    ENDFUNC

    PROCEDURE grid1.Scrolled(nDirection)
        IF INLIST(nDirection, 1,3)
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

    PROCEDURE grid1.MouseWheel(nDirection, nShift, nXCoord, nYCoord)
        IF nDirection < 0
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

这样的结果

参考示例，不知能否满足要求。
DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG
CREATE CURSOR tt (f1 C(4), f2 I)
FOR i = 1 TO 100
    INSERT INTO tt VALUES (PADL(i, 4, "0"), i)
ENDFOR
GO TOP
of = CREATEOBJECT("form1")
of.show(1)

DEFINE CLASS form1 as Form
    ADD OBJECT grid1 as _grid
ENDDEFINE

DEFINE CLASS _grid as grid
    Visible = .T.
   
    PROCEDURE init
        BINDEVENT(thisform.hWnd, 0x401, this, "_BlankRows")
    ENDPROC
   
    PROCEDURE Scrolled(nDirection)
        IF INLIST(nDirection, 1,3)
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC
   
    PROCEDURE MouseWheel(nDirection, nShift, nXCoord, nYCoord)
        IF nDirection < 0
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

    PROCEDURE AfterRowColChange(nColIndex)
        IF this.RowColChange != 2
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

    FUNCTION _SetCell(nRow, nCol, nRecno)
        IF nRow <= nRecno
            GO nRecno
            this.SetFocus
            this.ActivateCell(nRow, nCol)
            DO WHILE RECNO() != nRecno
                this.DoScroll(IIF(RECNO() < nRecno, 1, 0))
                this.SetFocus
                this.ActivateCell(nRow, nCol)
            ENDDO
        ENDIF
    ENDFUNC

    FUNCTION _BlankRows(hWnd, Msg, wParam, lParam)
        LOCAL nRow, nCol, nX, nY, nWhere, nRelRow, nRelCol, nRecno
        nCol = this.ActiveColumn
            * 示例假设最底行第一格内的座标（nX, nY）（按实际情况确定或通过算计取得）
        nX = 25
        nY = this.top + this.height - 25
        STORE 0 TO nWhere, nRelRow, nRelCol
        this.GridHitTest(nX, nY, @nWhere, @nRelRow, @nRelCol)
        IF nWhere==0 AND RECCOUNT()>=nRelRow   && 空白行
            thisform.LockScreen = .T.
            this._SetCell(1, nCol, RECCOUNT()-nRelRow+1)
            this.ActivateCell(nRelRow, nCol)
            thisform.LockScreen = .F.
        ENDIF
    ENDPROC
ENDDEFINE

炊版的功夫了得啊
有个小问题，当向下拖拉垂直滚动条到最后时，会显示无数据空白区域，松开鼠标空白区域就不显示了，最好是不让空白区域显示出来，这个功能就完美了，是否提示到文件尾无关紧要。

呵呵

玩个性的可以重载键盘鼠标事件和自己设计滚动条

非常感谢朋友的帮助，向您学习！

查看了VFP的帮助，没找到返回GRID表格行数的属性或方法？
改了一下算法，看似简单点。
DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG
CREATE CURSOR tt (f1 C(4), f2 I)
FOR i = 1 TO 100
    INSERT INTO tt VALUES (PADL(i, 4, "0"), i)
ENDFOR
GO TOP
of = CREATEOBJECT("form1")
of.show(1)  
CLOSE DATABASES ALL
CLEAR ALL
RETURN

DEFINE CLASS form1 as Form
    ADD OBJECT grid1 as _grid

    PROCEDURE Activate
        this.grid1._InitVal()
    ENDPROC
ENDDEFINE

DEFINE CLASS _grid as grid
    Visible = .T.
    nRows = 1    && 表格行数
    nRect = 1    && 表格顶行记录号
   
    PROCEDURE init
        BINDEVENT(thisform.hWnd, 0x401, this, "_BlankRows")
    ENDPROC
   
    PROCEDURE Scrolled(nDirection)
        IF INLIST(nDirection, 1,3)
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC
   
    PROCEDURE MouseWheel(nDirection, nShift, nXCoord, nYCoord)
        IF nDirection < 0
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

    PROCEDURE AfterRowColChange(nColIndex)
        IF this.RowColChange != 2
            PostMessage(thisform.hWnd, 0x401, 0, 0)
        ENDIF
    ENDPROC

    FUNCTION _InitVal()
        this.nRows = 1
        this.ActivateCell(this.nRows, 1)
        this.setfocus
        DO WHILE this.RelativeRow == this.nRows
            this.nRows = this.nRows+1
            this.ActivateCell(this.nRows, 1)
            this.setfocus
        ENDDO
        this.ActivateCell(1, 1)
        this.nRows = this.nRows-1
        this.nRect = RECCOUNT()-this.nRows+1
    ENDFUNC

    FUNCTION _SetCell(nRow, nCol, nRecno)
        IF nRow <= nRecno
            GO nRecno
            this.SetFocus
            this.ActivateCell(nRow, nCol)
            DO WHILE RECNO() != nRecno
                this.DoScroll(IIF(RECNO() < nRecno, 1, 0))
                this.SetFocus
                this.ActivateCell(nRow, nCol)
            ENDDO
        ENDIF
    ENDFUNC

    FUNCTION _BlankRows(hWnd, Msg, wParam, lParam)
        LOCAL nRow, nCol
        nRow = this.RelativeRow
        nCol = this.RelativeColumn
        **nCol = this.ActiveColumn
        this.SetFocus
        IF (RECNO()-nRow+1) > this.nRect
            thisform.LockScreen = .T.
            this._SetCell(1, nCol, this.nRect)
            this.ActivateCell(this.nRows, nCol)
            thisform.LockScreen = .F.
        ENDIF
    ENDPROC
ENDDEFINE

[此贴子已经被作者于2017-10-31 10:14编辑过]