我有一个程序，是在播放PPT的同时显示VFP表单的内容，需要在PPT和VFP表单之间来回切换，但由于PPT和VFP表单均未显示窗口标题栏，所以有时候不知道哪个窗口处于激活状态，各位可有什么好办法检测VFP窗口当前是否处于激活状态呢？（在VFP环境下两个VFP表单哪个是激活的知道，但在系统环境下利用ALT+TAB切换窗口时表单中的响应事件ACTIVATE没有反应）

这问题,吹斑竹知道,我记得他以前在这个论坛上说过,好像是用API函数处理的.

可惜的是我不知道怎么联系他，您记得当时的题目内容吗？我搜一下。

VFP 可以 PPT 自动化的，可以直接嵌入和播放 PPT 文档的

** test.prg
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
_SCREEN.Visible = .F.
of = CREATEOBJECT("myForm")
of.show
READ EVENTS
RETURN

DEFINE CLASS myForm As Form
    ShowWindow = 2
   
    PROCEDURE UnLoad
        CLEAR EVENTS
    ENDPROC

    PROCEDURE Init
        BINDEVENT(this.hWnd, 7, this, "_SetFocus")
        BINDEVENT(this.hWnd, 8, this, "_KillFocus")
    ENDPROC
   
    FUNCTION _SetFocus(hWnd, nMsg, wParam, lParam)
        this.Caption = this.name + "窗口获得焦点"
        SendMessage(hWnd, nMsg, wParam, lParam)
    ENDFUNC

    FUNCTION _KillFocus(hWnd, nMsg, wParam, lParam)
        this.Caption = this.name + "窗口失去焦点"
        SendMessage(hWnd, nMsg, wParam, lParam)
    ENDFUNC
ENDDEFINE

非常感谢！

不好意思，我是菜鸟，我再请教一下，在我的表单中如何利用您教给我的功能呢？
是否将：
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
_SCREEN.Visible = .F.

BINDEVENT(this.hWnd, 7, this, "_SetFocus")
BINDEVENT(this.hWnd, 8, this, "_KillFocus")

以上代码放入表单的INIT事件中，
然后剩下的部分：
    FUNCTION _SetFocus(hWnd, nMsg, wParam, lParam)
        this.Caption = this.name + "窗口获得焦点"
        SendMessage(hWnd, nMsg, wParam, lParam)
    ENDFUNC

    FUNCTION _KillFocus(hWnd, nMsg, wParam, lParam)
        this.Caption = this.name + "窗口失去焦点"
        SendMessage(hWnd, nMsg, wParam, lParam)
    ENDFUNC
如何在表单中调用呢？
也就是说我运行我的表单，然后用您的办法来实现，但我不知道如何在表单中实现，还请赐教，非常感谢！

_SetFocus和_KillFocus是自定义表单的方法，在“菜单--表单--新建方法程序”定义。
入口参数：
LPARAMETERS hWnd, nMsg, wParam, lParam

谢谢，我试试，弄不明白的地方再请教您！

测试成功了！非常非常的感谢！