* 建立1个表单，表单的 ShowWindow = 2,WindowState = 2
* 在表单建立1个定时器 Timer1,Interval=10,Enabled=.f.


* 表单 init 中
DECLARE Long CreateRectRgn IN WIN32API Long, Long, Long, Long
DECLARE Long GetWindowRgn IN WIN32API Long, Long @
DECLARE Long SetWindowRgn IN WIN32API Long, Long, Long

This.AddProperty( 'cw', 0 )
This.AddProperty( 'hRgn', 0 )

m.hRgn = 0
GetWindowRgn( This.hWnd, @ m.hRgn )
This.hRgn = m.hRgn

m.hRgn = CreateRectRgn( 0, 0, 1, 1 )
SetWindowRgn( This.hWnd, m.hRgn, 1 )

* 表单 show 中
This.Timer1.Enabled = .T.

* 定时器 Timer1.Timer 中

WITH Thisform
   IF ( .cw < SYSMETRIC(1)/2 ) OR ( .cw < SYSMETRIC(2)/2 )
     .cw = .cw + 10
     m.hRgn = CreateRectRgn( SYSMETRIC(1)/2-.cw, SYSMETRIC(2)/2-.cw,SYSMETRIC(1)/2+.cw, SYSMETRIC(2)/2+.cw )
     SetWindowRgn( .hWnd, m.hRgn, 1 )
   ELSE
     This.Interval = 0
     This.Enabled = .F.
     SetWindowRgn( .hWnd, .hRgn, 1 )
   ENDIF
ENDWITH

由CreateRectRgn()返回的区域句柄（hRgn），不用时要用DeleteObject(hRgn)删除。

这是不是有点麻烦了，直接写在处事的事件里即可以了。

你可以写1个看看，效果。
我是看到了，转发给大家看。

土法上马

建二个表单，第一个表单上二个计时器，一个获取表单最大化下的宽与高，存入变量中，另一个计时器用于退出表单。然后

启动第二个表单（主窗口）实现慢慢变大的效果，代码写在表单的RESIZE中，即可实现

我更喜欢一点击就直接弹开！

为了工作一点就打开，是最好的。

这贴，只是个技术讨论

我开始，也大概是这样，慢慢变大，结果，屏幕很难看的，有马赛克

DOS时代流行的画风。

建立表单，表单的 ShowWindow = 2，
在表单的activate中写如下代码：

Thisform.timer1.Interval = 10
Thisform.timer1.Enabled = .t.

在表单上添加timer1控件，在此控件的timer事件中写如下代码：

IF ( thisform.width < SYSMETRIC(1) ) .or. ( thisform.height < SYSMETRIC(2) )
   thisform.width =  iif(thisform.width > SYSMETRIC(1) , SYSMETRIC(1) ,thisform.width + 10)
   thisform.height =  iif(thisform.height > SYSMETRIC(2) , SYSMETRIC(2) , thisform.height + 10)
ELSE
   Thisform.timer1.Interval = 0
   Thisform.timer1.Enabled = .F.
   thisform.WindowState = 2
ENDIF
thisform.autocenter=.t.
thisform.refresh

这样，虽然看起来效果不如API函数的动画效果，但节约因API函数定义而占的内存，同时也简单易懂。
请版主见谅。