DO CASE
   CASE thisform.list2.listindex>0 .and. thisform.list2.ListCount>0
      thisform.list2.ListIndex=1
   CASE thisform.list2.ListIndex=0 .and.thisform.list2.listcount>0
      thisform.list2.ListIndex=1
   CASE thisform.list2.listindex=0 .and.thisform.list2.listcount=0
      thisform.list2.ListIndex=0
ENDCASE
IF thisform.list2.listindex>0
   thisform.list3.AddItem(ALLTRIM(thisform.list2.value))&&在list3中增加一个字段，在list2删除一个字段
   thisform.list3.refresh
   thisform.list2.removeitem(thisform.list2.ListIndex)
   thisform.list2.refresh
ELSE
   thisform.cmdremover.Enabled= .T.
   thisform.cmdremoverall.Enabled= .T.
   thisform.cmdadd.Enabled= .f.
   thisform.cmdaddall.Enabled= .f.
ENDIF
发现list2中选定的结果无法现在list3上
      

试试将 Refresh 改为 Requery

是还不行

补充一点thisform.list2.value的值是正确的。这段程序是cmdadd按钮的程序。整体意识是：把目录中的dbf文件显示在list1中。选择其中一个文中，将他的字段现在list2中
 然后有4个按钮控制字段移动。

试了一下主要代码好象没问题
** test.prg
of = CREATEOBJECT("myform")
of.show(1)

DEFINE CLASS myform as Form
    ADD OBJECT list2 as listbox WITH top=10,left=10
    ADD OBJECT list3 as listbox WITH top=10,left=120
    ADD OBJECT cmd1 as commandbutton WITH top=10,left=230
   
    PROCEDURE Init
        this.list2.AddItem("list2_1")
        this.list2.AddItem("list2_2")
        this.list2.AddItem("list2_3")
        this.list3.AddItem("list3_1")
        this.list3.AddItem("list3_2")
        this.list3.AddItem("list3_3")
    ENDPROC
   
    PROCEDURE cmd1.click
        DO CASE
        CASE thisform.list2.listindex>0 and thisform.list2.ListCount>0
            thisform.list2.ListIndex=1
        CASE thisform.list2.ListIndex=0 AND thisform.list2.listcount>0
            thisform.list2.ListIndex=1
        CASE thisform.list2.listindex=0 AND thisform.list2.listcount=0
            thisform.list2.ListIndex=0
        ENDCASE
        IF thisform.list2.listindex>0
           thisform.list3.AddItem(ALLTRIM(thisform.list2.value))
           *thisform.list3.refresh
           thisform.list2.removeitem(thisform.list2.ListIndex)
           *thisform.list2.refresh
        ENDIF
    ENDPROC
ENDDEFINE

是我自己马虎了，把list3的属性改动了，谢谢大家程序改好了。适当时间发出来和大家分享。

吹版，有办法获取列表框中指定内容的顺序号吗？比如说我知道列表框中有一项目的名称是“姓名”，现在想把“姓名”的顺序号赋值给变成I1。谢谢。

列表项目名称可以都一样，不可能用项目的名称来定位。
但各项目可设置唯一ID，用ID来表达想要的项目名。
参考：
AddListItem 方法
ItemIDToIndex 方法
IndexToItemID 方法
ListItemID 属性

不知道是不是我没描述清楚，有没有办法获得列表框中指定内容的初始序号？比如说，LIST1初始有10个项目，分别是A1...A10，现在把其中某些指定的项目复制到了LIST2中，比如说复制了A2,A3,A5,A7，有没有办法获得LIST2这些项目在LIST1的初始顺序号？（这里是有规律，但现实中不一定有规律，对吧。
我目前使用的办法是先用
FOR I=1 TO THISFORM.LIST2.LISTCOUNT
    A1=THISFORM.LIST2.LISTITEM(I)
    THISFORM.LIST1.VALUE=A1
    J=THISFORM.LIST1.LISTINDEX
ENDFOR
不知道还有没有其他更好的办法。

** test.prg
of = CREATEOBJECT("myform")
of.show(1)

DEFINE CLASS myform as Form
    ADD OBJECT list1 as listbox WITH top=10,left=10
    ADD OBJECT list2 as listbox WITH top=10,left=120
   
    PROCEDURE Init
        this.list1.AddListItem("list1_1", 11)
        this.list1.AddListItem("list1_2", 12)
        this.list1.AddListItem("list1_3", 13)
    ENDPROC
   
    PROCEDURE list1.dblclick
        IF this.listindex > 0
            thisform.list2.AddListItem(this.ListItem(this.ListItemID), this.ListItemID)
        ENDIF
    ENDPROC

    PROCEDURE list2.click
        IF this.listindex > 0
            thisform.list1.SelectedID(this.ListItemID) = .T.
        ENDIF
    ENDPROC
ENDDEFINE

要用到Index时可转换：
ItemIDToIndex
IndexToItemID