对对对，我运行了我仿制的程序一下，都变成了35元。

[此贴子已经被作者于2016-12-24 23:37编辑过]

close databases all
use jmb in 0
cstr=""
scan
    cstr=cstr+alltrim(jm)+" N(10,2),"
endscan
cstr=left(cstr,len(cstr)-1)
create cursor jjtj (ny n(6),num n(4),xm c(8),bm c(15),hj n(12,2),&cstr)
append from jjd fields num,xm,bm
index on num tag num
use jj in 0
select jj
set relation to num into jjtj
scan
    replace (alltrim(jj.奖名)) with jj.金额 in jjtj
endscan
set relation to
* 行小计
select jjtj
cstr=""
for i=6 to fcount()
    cstr=cstr+"+"+field(i)
endfor 
replace all hj with evaluate(cstr)
browse

真牛。
运行结果表中 1、相同的NUM记录不能重复出现，即有NUM、XM的没有金额的记录不能出现在JJTJ表中；
             2、若同一奖名，出现二次金额以上的情况，应考虑累计成一个奖名和总金额。
  这二点能做到吗？

[此贴子已经被作者于2016-12-25 00:16编辑过]

收到的鲜花

• 梦幻倩影 于 2016-12-25 10:36 送鲜花  10朵   附言：我很赞同

close databases all
select distinct num,xm,bm from jj where 金额>0 into array anum
use jmb in 0
select jmb
cstr=""
scan
    cstr=cstr+alltrim(jm)+" N(10,2),"
endscan
cstr=left(cstr,len(cstr)-1)
create cursor jjtj (ny n(6),num n(4),xm c(8),bm c(15),hj n(12,2),&cstr)
append from array anum fields num,xm,bm
index on num tag num
select jj
set relation to num into jjtj
scan for 金额>0
    replace (jj.奖名) with evaluate(jj.奖名)+jj.金额 in jjtj
endscan
set relation to
* 行小计
select jjtj
cstr=""
for i=6 to fcount()
    cstr=cstr+"+"+field(i)
endfor 
replace all hj with evaluate(cstr)
browse

[此贴子已经被作者于2016-12-25 01:48编辑过]

谢谢。
我的想法是
先把同一个人的同奖名的金额相加后再运行程序。还是你的厉害。
SELE NUM,XM,奖名,SUM(金额) AS 金额 FROM JJ1 GROUP BY NUM,奖名 INTO TABL JJ

多写多练，自然就会熟练的。两年前我写的代码，现在再重新看，也不怎么样的。

谢谢！
当有人说我统计工作做的很快的时候，
我心里就：老想你了。

你很敬业，让人佩服！