FSIZE() 好像对于大文件返回值不是正确的，如大于4G的文件

VFP本身是32位编译，单个文件大小限制也只是2G吧？

api 搞不懂是什么意思，搜到一些说法，但是一堆东西看不懂，我业余编的

文件操作的API有不少
如：
*方法一
DECLARE LONG CreateFile IN Kernel32 STRING@, LONG, LONG, LONG, LONG, LONG, LONG
DECLARE LONG GetFileSize IN Kernel32 LONG, LONG
DECLARE LONG CloseHandle IN Kernel32 LONG

hFile = CreateFile("C:\TEMP\test.txt", 8, 1, 0, 3, 0, 0)
IF (hFIle != -1)
    nSize = GetFileSize(hFile, 0)
    ? nSize
    CloseHandle(hFile)
ENDIF


*方法二
DECLARE LONG FindFirstFile IN Kernel32 STRING@, STRING@
DECLARE LONG FindClose IN Kernel32 LONG

stFI = REPLICATE(0h00, 320)
hFile = FindFirstFile("C:\TEMP\test.txt" , @stFI)
IF (hFIle != -1)
    nSize = CTOBIN(SUBSTR(stFI,33,4), "4RS")
    ? nSize
    FindClose(hFile)
ENDIF

非常感谢，应该可以解决了，我也查过一下一些API，但实在不知道这几个 LONG LONG LONG 代表什么东西，然后你是怎么知道括号里的几个数字该怎么用的呢？

两个方法貌似对大于2G的文件也不准确？

[此贴子已经被作者于2016-9-21 20:56编辑过]

之前不是说了吗？VFP是32位编译的，整数的最大值0x7FFFFFFF（2,147,483,647），VFP的数值类型不能处理超过这个限制。
可试试用字符串表示形式来处理超大数值。
上面提到的方法二，文件大小是分高位（32位）低位（32位）存放的，示例只取低位。
试试高低位都取出来看看。
 nHSize = CTOBIN(SUBSTR(stFI,29,4), "4RS")
 nLSize = CTOBIN(SUBSTR(stFI,33,4), "4RS")

Declare Long FindFirstFile In Kernel32 String@, String@
Declare Long FindClose In Kernel32 Long

stFI = Replicate(0h00, 320)
hFile = FindFirstFile("E:\test.rar" , @stFI)

If (hFIle != -1)
    nLSize = CToBin(Substr(stFI,33,4), "4RS")
    nHSize = CToBin(Substr(stFI,29,4), "4RS")
    size_real=((nHSize*4*1024*1024*1024)+IIF(nLSize>=0,nLSize,4*1024*1024*1024+nLSize))/1024/1024
    ? size_real && 单位 M
    FindClose(hFile)
Endif

搞定了！非常感谢

Declare Long FindFirstFile In Kernel32 String@, String@
Declare Long FindClose In Kernel32 Long

stFI = Replicate(0h00, 320)
hFile = FindFirstFile("E:\test.rar" , @stFI)

If (hFIle != -1)
    nLSize = CToBin(Substr(stFI,33,4), "4RS")
    nHSize = CToBin(Substr(stFI,29,4), "4RS")
    size_real=((nHSize*4*1024*1024*1024)+IIF(nLSize>=0,nLSize,4*1024*1024*1024+nLSize))/1024/1024
    ? size_real && 单位 M
    FindClose(hFile)
Endif

按微软的说法，这个高低位数值是：
_INT64 RealSize = ((__INT64)nFileSizeHigh * (MAXDWORD+1)) + (__INT64)nFileSizeLow
其中：MAXDWORD 是 0x0ffffffff
也就是说：size_real = nHSize*0x100000000 + nLSize