请问“不拖动标题栏，而是通过在表单上按下鼠标左键来移动表单”这段代码为啥报错？

源代码见附件



通过在表单或表单内的控件上按下鼠标左键来移动窗口
*（而不是通过在标题栏上按下鼠标左键来移动窗口）

*-----------------------------------------------
*表单的Init事件代码：
Declare Long ReleaseCapture In "user32"
Declare Long SendMessageA In "user32" Long HWnd,Long wMsg,Long wParam,String Lparam
This.MySetMouseDown(Thisform)


*表单的MouseDown事件代码：
Lparameters nButton, nShift, nXCoord, nYCoord
ReleaseCapture()
SendMessageA(This.HWnd,0xA1,2,0)


*为表单新建一方法 MySetMouseDown，其代码为：
Lparameters toControl
If Pemstatus(toControl,"MouseDown",5) And toControl<>Thisform
    Bindevent(toControl,"MouseDown",Thisform,"MouseDown")
Endif
If Type("toControl.objects[1]")="O"
    Local loI
    For Each loI In toControl.Objects
        This.MySetMouseDown(loI)
    Endfor
Endif

报错提示是什么

_screen.Visible = .F.
#define WM_SYSCOMMAND       0x0112
#define WM_NCLBUTTONDOWN    0x00A1
#define SC_MOVE             0xF010
#define HTCAPTION           0x0002
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
of = CREATEOBJECT("form1")
of.show
READ EVENTS

DEFINE CLASS form1 as Form
    ShowWindow = 2
    Desktop = .T.
    AutoCenter = .T.
    BorderStyle = 1
    TitleBar = 0
    MousePointer = 5
    
    ADD OBJECT cmd as commandbutton WITH top=20,left=20,caption="exit"    
    
    PROCEDURE cmd.click
        thisform.Release
    ENDPROC
    
    PROCEDURE Init
        this.Show
        ?
        ?
        ? "    在窗口空白区按住左键拖动"
    ENDPROC
    
    PROCEDURE Unload
        CLEAR EVENTS
    ENDPROC
    
    PROCEDURE MouseDown(nButton, nShift, nXCoord, nYCoord)
        IF (nButton == 1)
                * 方法一
            SendMessage(this.hWnd, WM_NCLBUTTONDOWN, HTCAPTION, 0)
                * 方法二
            *SendMessage(this.hWnd, WM_SYSCOMMAND, SC_MOVE + HTCAPTION, 0)
        ENDIF
    ENDPROC
ENDDEFINE

我这里，好像不报错误。9.0 SP1