Button控件，本人愚钝没找到，请明显，好像VF6.0没有啊，是在VF9.0中新设的吗？

笔误，明示。

Button 控件 94 Command Button 控件，按钮控件/命令按钮控件，本人一直使用 FoxPro，在 FoxPro 中是称为 Button 的。

扫泪。

[此贴子已经被作者于2016-7-7 11:22编辑过]

表单设计控件里面有 按钮

就是Command Button 控件吗，在我的问题中布局720个命令按纽，也挺麻烦的，还有其他优选方案。

用不同的图形文件也行。

1. 表单的 Init 方式中增加下面的代码
*!* Thisform.Init
For ln_row = 1 To 18
    For ln_col = 1 To 10
        lc_name = "按钮" + Ltrim(Str(m.ln_row)) + Ltrim(Str(m.ln_col))
        Thisform.AddObject(m.lc_name, "CommandButton")
        lo_button = Getpem(Thisform, m.lc_name)
        With m.lo_button
            .Left = m.ln_col * 60 - 59
            .Top = m.ln_row * 28 - 27
            .Width = 50
            .Height = 28
            .Caption = Transform(m.ln_row*m.ln_col, "@L 999")
            .Visible = .T.
        Endwith
        Bindevent(m.lo_button, "Click", Thisform, "OnClick")
    Endfor
Endfor

2. 表单中增加 OnClick 方式，代码如下：
*!* create this method in your form
*!* Thisform.OnClick
If Aevents(la_event, 0) > 0
    lo_button = m.la_event[1]
    If Vartype(m.lo_button) == "O"
        Do Case
        Case m.lo_button.Name == "按钮1"
        *!* put your first button code here
        Case m.lo_button.Name == "按钮12"
        *!* put your second button code here
        Endcase
    Endif
Endif

只做了 18X10，具体值、宽度、高度、间距、Caption、颜色、字体、式样葫芦画瓢。

如果 Button 是复杂的，建议做一个 Button 的类，封装调用。

十分感谢无私奉献，好好学习，认真消化。