如果想运行一段程序期间弹出写有“请稍等”的表单，运行完成后“请稍等”自动消失，怎么写？

（1）在主表单，点击按钮，Click触发一个prg.

（2）prg运行的开始阶段，弹出一个表单，上面写“请等候”

（3）继续运行 prg的程序主体

（4）程序主体运行完成后，“请等候”表单自动消失，回到主表单。

[此贴子已经被作者于2016-3-30 20:36编辑过]

不需表单，用wait指令

WAIT WINDOWS "正在处理,请等待......"  AT 20,50 TIMEOUT 60  &&等待60秒

用 Wait 好像不是最理想：

1. 如果用 TimeOut 子句的，时间系数不是定长，而且 TimeOut 是同步方式；
2. 如果用 NoWaitt 子句的，虽然是异步方式，但一旦动一下鼠标或键盘，提示会消失。

[此贴子已经被作者于2016-3-30 22:46编辑过]

wait window nowait
继续执行
wait clear 取消提示

prg运行的开始阶段，加一语句thisform.label.caption=“请等候”

 继续运行 prg的程序主体

 程序主体运行完成后，语句改为thisform.label.caption=“已完成”或thisform.label.caption=“”

用表单，玩个性、玩创意，还可以显示进度条，用“非模式”或“顶层”表单可以。

示例

** test.prg
of = CREATEOBJECT("form1")
of.show
READ EVENTS
CLEAR ALL 
RETURN

DEFINE CLASS form1 as Form
    ShowWindow = 2
    Top = 200
    Left = 300
    
    ADD OBJECT cmd1 as commandbutton WITH top=10,left=10,caption="Test"
    ADD OBJECT edit1 as editbox WITH top=40,left=10,height=200
    
    PROCEDURE cmd1.click
        LOCAL of2
        of2 = CREATEOBJECT("form2")
        of2.show
        FOR i = 1 TO 10
            of2.ddProgress = i/10
            thisform.edit1.SelText = TRANSFORM(i)+0h0D0A
            INKEY(1)
        ENDFOR
        *IF VARTYPE(of2) == "O"
        *    of2.release
        *ENDIF
    ENDPROC

    PROCEDURE Unload
        CLEAR EVENTS 
    ENDPROC
ENDDEFINE

DEFINE CLASS form2 as Form
    ShowWindow = 1
    DeskTop = .T.
    AutoCenter = .T.
    Width = 300
    Height = 100
    
    ddProgress = 0
    
    ADD OBJECT label1 as label WITH top=20,left=20,autosize=.T.,caption="请稍等......"
    ADD OBJECT Shape1 AS Shape WITH top=50,left=20,height=25,width=this.Width-40
    ADD OBJECT Shape2 AS Shape WITH top=50,left=20,height=25,Width=0,BackColor=0xFA9632,BorderStyle=0
    
    FUNCTION ddProgress_Assign(vNewVal)
        IF BETWEEN(vNewVal, 0, 1)
            this.Shape2.Width = this.Shape1.Width * vNewVal
        ENDIF
    ENDFUNC
ENDDEFINE

1. 设计一个表单 ProgressBar.scx，属性如下：
   AlwaysOnTop = .t.  && 位于顶层，防止被其他窗口遮挡
   AutoCenter = .t.   && 自动居中
   BorderStyle = 1    && 单线边框
   DeskTop = .t.      && 不受 Screen 大小限制，可位于 Screen 之外
   TitleBar = 0       && 无标题栏
   Height = 36
   Width = 372
2. 在表单上添加一个标签 lblPrompt，用于显示提示信息
3. 在 Form.Init 事件中设置标签属性：
   LPARAMETERS tcPrompt    && 显示字符串
   IF EMPTY(tcPrompt)
    tcPrompt = '正在处理，请稍候……'
   ENDIF
   WITH THIS.lblPrompt
        .Caption = tcPrompt
        .Left = 0
        .Width = THIS.Width
        .Alignment = 2
        .Top = (THIS.Height - .Height)/2
   ENDWITH
4. 定义一个全局变量 goProgress
5. 显示提示窗口：
   DO FORM ProgressBar WITH "正在计算工资，请稍候……" NAME goProgress
6. 关闭提示窗口：
   goProgress.Release

如果再复杂一点，还可以在窗口上显示动画、标签支持多行文本、单击表单手动关闭提示窗口……
   

Clear
=WaitBox()
lcText = "█"
@ 10, 10 Say "-->"
For I = 1 To 10  && 长时间的循环/运算/备份/下载等的操作
    =Inkey(1)
    ?? lcText
Endfor
? "结束。"
Release Window Wparent


Function WaitBox
    Define Window Wparent ;
        FROM 0, 0 To 5, 50 ;
        Font "宋体", 12 Style "BT" ;
        DOUBLE Color Scheme 7
    Move Window Wparent Center
    Activate Window Wparent
    @ 2, 2 Say "正在处理数据，请稍等片刻......"
    Activate Screen
Endfunc